Set Mask Color for Loaded 3D Model Textures

Blitz3D Forums/Blitz3D Beginners Area/Set Mask Color for Loaded 3D Model Textures

RustyKristi

(Posted 2016) [#1]

So do I just use MaskImage command and this applies to 3D textures? I understand the default is black

Bobysait

(Posted 2016) [#2]

MaskImage is only for 2D Images created with LoadImage/CreateImage.

For textures, you need to enable the mask flag (4) on LoadTexture/CreateTexture
For a LoadTexture it will apply the mask only for Alpha pngs (it will split alpha : =>0.5 : Solid, <0.5 : not visible) or without alpha it will use the black (0,0,0) as mask.

Then, you can set the alpha of the pixel by hands using WritePixel/WritePixelFast on the TextureBuffer.
You can also create your own function to maniputale the pixels and apply your own color mask

Function MaskTexture (pTex, pR,pG,pB, pFrame%=0)
	Local l_Mask% = pR Shl(16) + pG Shl(8) + pB
	Local l_CurBuffer = GraphicsBuffer()
	Local l_TexBuffer = TextureBuffer(pTex, pFrame)
	Local l_W=TextureWidth(pTex)
	Local l_H=TextureHeight(pTex)
	SetBuffer l_TexBuffer
	LockBuffer()
		For j = 0 To l_H-1
		For i = 0 To l_W-1
			If ((ReadPixelFast(i,j) And $FFFFFF) = l_Mask) Then WritePixelFast(i,j, $00000000)
		Next
		Next
	UnlockBuffer()
	SetBuffer l_CurBuffer
End Function



Graphics3D 800,600,0,2
SetBuffer BackBuffer()

Local cam = CreateCamera()
CameraClsColor cam, 128,128,128
MoveEntity cam, 0,0,-2

Local Tex = LoadTexture("SomeTexture.png", 4 )
MaskTexture Tex, 255,255,255


Local q =	CreateMesh()
Local s =	CreateSurface(q)
			AddVertex s,-1, 1,0,0,0
			AddVertex s, 1, 1,0,1,0
			AddVertex s, 1,-1,0,1,1
			AddVertex s,-1,-1,0,0,1
			AddTriangle s, 0,1,2
			AddTriangle s, 0,2,3
			EntityFX q, 1+8
			EntityTexture q, Tex

RenderWorld()
Flip True

WaitKey()
End

RustyKristi

(Posted 2016) [#3]

Ok so this should be done per image, I thought there was a setting somewhere in b3d file. Anyway, this should get me started. thanks BobySait.