Interesting Problem with X and Y Values...

Blitz3D Forums/Blitz3D Beginners Area/Interesting Problem with X and Y Values...

OwlEpicurus

(Posted 2009) [#1]

When I try to use the same variables for drawing two different images on the screen, the images appear in different places. I have not changed the handles, and the images are being drawn one after the other with no other code in between. What are the possible reasons for this?

Andy	(Posted 2009) [#2]

Can you post some code?

OwlEpicurus

(Posted 2009) [#3]

I'm not sure which part of the code could be causing the problem, and I don't want to post the whole 15 KB program. The code that draws the images on screen is:

DrawImage pathcorner4\image,x,y
DrawImage pathcorner2\image,x,y

The error probably is not there, though. Should I post the rest of the code?

OwlEpicurus

(Posted 2009) [#4]

After rewriting some of the code, I have managed to get everything where it is supposed to be. However, I do not know why I had to add something to the x and y values in certain instances. Here is the function:

Function DrawForestPath()

	door1\x = STARTX+ImageWidth(door1\image)
	door1\y = STARTY+200
	
	x = door1\x-100
	y = door1\y-ImageHeight(door1\image)

	SetBuffer BackBuffer()
	
	TileBlock ForestFloorImage
	DrawImage background,StartX,StartY
	
	DrawImage door1\image,door1\x,door1\y
	DrawImage pathsegmentH\image,x,y
	x = x+ImageWidth(pathsegmentH\image)-10
	DrawImage pathcorner1\image,x,y
	y = y+ImageHeight(pathcorner1\image)-5
	x = x+ImageWidth(pathcorner1\image)
	DrawImage pathsegmentV\image,x,y
	y = y+ImageHeight(pathsegmentV\image)-5
	DrawImage pathsegmentV\image,x,y
	y = y+ImageHeight(pathsegmentV\image)+ImageHeight(pathcorner1\image)-5
	DrawImage pathcorner3\image,x,y
	y = y-ImageHeight(pathsegmentH\image)+1
	DrawImage pathsegmentH\image,x,y
	x = x+ImageWidth(pathsegmentH\image)+ImageWidth(pathcorner4\image)
	DrawImage pathcorner2\image,x,y
	x = x-ImageWidth(pathcorner4\image)
	DrawImage pathcorner4\image,x,y
	x = x+ImageWidth(pathcorner4\image)
	y = y-ImageHeight(pathsegmentH\image)
	DrawImage pathsegmentH\image,x,y
	x = x+ImageWidth(pathsegmentH\image)
	DrawImage pathcorner1\image,x,y
	
	DrawImage player\image,player\x,player\y,player\frame

End Function

The line

DrawImage pathcorner1\image,x,y

is drawn correctly without the adjustments to the x and y values the others seemed to need.

On the other hand, in the lines

DrawImage pathcorner1\image,x,y
	y = y+ImageHeight(pathcorner1\image)-5
	x = x+ImageWidth(pathcorner1\image)
	DrawImage pathsegmentV\image,x,y

pathcorner1\image is supposed to have the same x value as pathsegmentV\image, yet they do not appear on screen with the same x value unless ImageWidth(pathcorner1\image) is added to x.

Pongo

(Posted 2009) [#5]

Are you sure you haven't used ImageHandle() or midhandle() somewhere in your code?

OwlEpicurus

(Posted 2009) [#6]

I'm positive.

Pongo

(Posted 2009) [#7]

I don't see anything when looking through quickly. It would help to have a fully working example if you could. If you post just the code, you can just state the image sizes and I can plug in something of my own.

Edited the post above to ask about midhandle() as well.

OwlEpicurus

(Posted 2009) [#8]

Here's the code in full:

Const SCREENWIDTH = 1440, SCREENHEIGHT = 900


Const RIGHTKEY = 205, LEFTKEY = 203
Const UPKEY = 200, DOWNKEY = 208

Const ENTERKEY = 28

Const ESCKEY = 1


Graphics SCREENWIDTH,SCREENHEIGHT


Type Character
	Field x,y
	Field image
	Field frame
End Type

Type Scenery
	Field x,y
	Field x1,y1,x2,y2,x3,y3,x4,y4 ; for additional instances of the scenery
	Field image
	Field frame
End Type

Type Room
	Field number
	Field name$
	Field maxX,maxY
End Type

Type Door
	Field x,y
	Field width,height
	Field frame
	Field number
	Field image
	Field destination
End Type


ChangeDir "C:\Users\Mariah\Documents\Programming\Keala\2D Small\Graphics"

Global player.character = New Character
player\image = LoadAnimImage("Keala_Animation_LBlue.bmp",166,97,0,4)

Global HouseExterior.room = New Room
HouseExterior\number = 0
HouseExterior\name$ = "House Exterior"
HouseExterior\maxX = 2000
HouseExterior\maxY = 1000

Global HouseInterior.room = New Room
HouseInterior\number = 1
HouseInterior\name$ = "House Interior"
HouseInterior\maxX = 1000
HouseInterior\maxY = 600

Global ForestPath.room = New Room
ForestPath\number = 2
ForestPath\name$ = "Forest Path"
ForestPath\maxX = 5000
ForestPath\maxY = 2500


Global tree.scenery = New Scenery
tree\image = LoadImage("Tree.bmp")

Global house.scenery = New Scenery
house\image = LoadImage("House.bmp")

Global pathsegmentH.scenery = New Scenery
pathsegmentH\image = LoadImage("PathSegment.bmp")

Global pathsegmentV.scenery = New Scenery
pathsegmentV\image = LoadImage("PathSegment.bmp")
RotateImage pathsegmentV\image,90

Global shortpathsegmentH.scenery = New Scenery
shortpathsegmentH\image = LoadImage("PathSegmentShort.bmp")

Global shortpathsegmentV.scenery = New Scenery
shortpathsegmentV\image = LoadImage("PathSegmentShort.bmp")
RotateImage shortpathsegmentV\image,90

Global pathcorner1.scenery = New Scenery
pathcorner1\image = LoadImage("PathCorner.bmp")

Global pathcorner2.scenery = New Scenery
pathcorner2\image = LoadImage("PathCorner.bmp") 
RotateImage pathcorner2\image,90

Global pathcorner3.scenery = New Scenery
pathcorner3\image = LoadImage("PathCorner.bmp")
RotateImage pathcorner3\image,180

Global pathcorner4.scenery = New Scenery
pathcorner4\image = LoadImage("PathCorner.bmp")
RotateImage pathcorner4\image,270


Global door1.door = New Door

Global door2.door = New Door

Global door3.door = New Door

Global door4.door = New Door

Global door5.Door = New Door


Global GrassImage = LoadImage("Grass.bmp")
ScaleImage GrassImage,.25,.25

Global ForestFloorImage = LoadImage("ForestBackground.bmp")

Global WoodenFloorImage = LoadImage("WoodenFloor.bmp")


Global PlayerRoom = 1
Global background

Global StartX,StartY
Global MarginX, MarginY
Global MaxX, MaxY
Global DrawX, DrawY

Global CurrentX,CurrentY
Global CurrentDrawX,CurrentDrawY


LoadRoom(PlayerRoom)

DrawX = MaxX
DrawY = MaxY

player\x = DrawX-MaxX+MarginX
player\y = DrawY-MaxY+MarginY
	
	
While Not KeyHit(ESCKEY)
				
	UpdateVariables()
	
	DrawGraphics()
	CheckInput()
		
	CheckCollisions()
		
	Flip
	Cls
	
Wend

End


Function UpdateVariables()

	StartX = DrawX-MaxX+MarginX
	StartY = DrawY-MaxY+MarginY
	CurrentX = player\x
	CurrentY = player\y
	CurrentDrawX = DrawX
	CurrentDrawY = DrawY
	
End Function

Function CheckInput()

	;--if the left arrow is pressed, move left--
	If KeyDown(LEFTKEY)
	
		player\x = player\x - 20 ;move object left 20 pixels
		player\frame = 2
		
		If player\x <= MarginX ;if object is off screen,
			player\x = MarginX
			
			If MaxX > SCREENWIDTH-2*MarginX
				DrawX = DrawX + 20
				
				If DrawX > MaxX
					DrawX = MaxX
				EndIf
				
			EndIf
		EndIf
		
	EndIf
	
	;--if the up arrow is pressed, move up--
	If KeyDown(UPKEY)
		
		player\y = player\y - 20 ;move object up 20 pixels
		player\frame = 1
		
		If player\y <= MarginY ;if object is off screen,
			player\y = MarginY
			
			If MaxY > SCREENHEIGHT-2*MarginY
				DrawY = DrawY + 20 
				
				If DrawY > MaxY
					DrawY = MaxY
				EndIf
				
			EndIf
			
		EndIf
		
	EndIf
	
	;--if the right arrow is pressed, move right--
	If KeyDown(RIGHTKEY)
		
		player\x = player\x + 20 ;move object right 20 pixels
		player\frame = 0
		
		If player\x >= SCREENWIDTH-ImageWidth(player\image)-MarginX;if the object is off screen,
			player\x = SCREENWIDTH-ImageWidth(player\image)-MarginX
			
			If MaxX > SCREENWIDTH-2*MarginX
				DrawX = DrawX - 20
				
				If DrawX < SCREENWIDTH
					DrawX = SCREENWIDTH
				EndIf
				
			EndIf
			
		EndIf
		
	EndIf
	
	;--if the down arrow is pressed, move down--
	If KeyDown(DOWNKEY)
		
		player\y = player\y + 20 ;move down 20 pixels
		player\frame = 3
		
		If player\y >= SCREENHEIGHT-ImageHeight(player\image)-MarginY;if the object is off screen,
			player\y = SCREENHEIGHT-ImageHeight(player\image)-MarginY
			
			If MaxY > SCREENHEIGHT-2*MarginY
				DrawY = DrawY - 20
				
				If DrawY < SCREENHEIGHT
					DrawY = SCREENHEIGHT
				EndIf
				
			EndIf
		EndIf
		
	EndIf

End Function

Function DrawGraphics()

	Select PlayerRoom
	
		Case HouseExterior\number
			DrawHouseExterior()
			
		Case HouseInterior\number
			DrawHouseInterior()
			
		Case ForestPath\number
			DrawForestPath()
			
	End Select

	DrawHUD()
	
End Function

Function DrawHouseExterior()
			
	tree\x = 500+StartX
	tree\y = 400+StartY

	house\x = StartX
	house\y = StartY
	
	door1\x = house\x+106
	door1\y = house\y+102
	
	door2\x = StartX+MaxX-2*MarginX-ImageWidth(door2\image)
	door2\y = StartY+(MaxY-2*MarginY)/2
				
	SetBuffer BackBuffer()
	
	TileBlock ForestFloorImage
	DrawImage background,StartX,StartY
	
	DrawImage house\image,house\x,house\y	
	DrawImage door1\image,door1\x,door1\y
	
	DrawImage door2\image,door2\x,door2\y
	
	DrawImage player\image,player\x,player\y,player\frame
	
	DrawImage tree\image,tree\x,tree\y
		
End Function

Function DrawHouseInterior()

	door1\x = (SCREENWIDTH/2)-(ImageWidth(door1\image)/2)
	door1\y = MaxY+MarginY
	
	SetBuffer BackBuffer()

	DrawImage background,StartX,StartY
	
	DrawImage door1\image,door1\x,door1\y
	
	DrawImage player\image,player\x,player\y,player\frame

End Function

Function DrawForestPath()

	door1\x = StartX+ImageWidth(door1\image)
	door1\y = StartY+200
	
	x = door1\x-100
	y = door1\y-ImageHeight(door1\image)
	
	tree\x = StartX+100
	tree\y = StartY+300
	
	tree\x1 = StartX+700
	tree\y1 = StartY+700

	SetBuffer BackBuffer()
	
	TileBlock ForestFloorImage
	DrawImage background,StartX,StartY
	
	DrawImage door1\image,door1\x,door1\y
	DrawImage pathsegmentH\image,x,y
	x = x+ImageWidth(pathsegmentH\image)-10
	DrawImage pathcorner1\image,x,y
	y = y+ImageHeight(pathcorner1\image)-5
	x = x+ImageWidth(pathcorner1\image)
	DrawImage pathsegmentV\image,x,y
	y = y+ImageHeight(pathsegmentV\image)-5
	DrawImage pathsegmentV\image,x,y
	y = y+ImageHeight(pathsegmentV\image)+ImageHeight(pathcorner1\image)-5
	DrawImage pathcorner3\image,x,y
	y = y-ImageHeight(pathsegmentH\image)+1
	DrawImage pathsegmentH\image,x,y
	x = x+ImageWidth(pathsegmentH\image)+ImageWidth(pathcorner4\image)
	DrawImage pathcorner2\image,x,y
	x = x-ImageWidth(pathcorner4\image)
	DrawImage pathcorner4\image,x,y
	x = x+ImageWidth(pathcorner4\image)
	y = y-ImageHeight(pathsegmentH\image)
	DrawImage pathsegmentH\image,x,y
	x = x+ImageWidth(pathsegmentH\image)-5
	DrawImage pathcorner1\image,x,y
	x = x+ImageWidth(pathcorner1\image)
	y = y+ImageHeight(pathcorner1\image)
	DrawImage pathsegmentV\image,x,y
	y = y+ImageHeight(pathsegmentV\image)-5
	DrawImage pathsegmentV\image,x,y
	y = y+ImageHeight(pathsegmentV\image)-5
	
	door2\x = x
	door2\y = StartY+MaxY-2*MarginY-ImageHeight(door2\image)
	DrawImage door2\image,door2\x,door2\y
	
	DrawImage shortpathsegmentV\image,x,y
	
	DrawImage player\image,player\x,player\y,player\frame
	
	DrawImage tree\image,tree\x,tree\y
	
	DrawImage tree\image,tree\x1,tree\y1

End Function

Function DrawHUD()
	
	row = 14
	
	HUD = CreateImage(90,4*row)
	SetBuffer ImageBuffer(HUD)
	
	Color 193,252,255
	Rect 0,0,ImageWidth(HUD),ImageHeight(HUD),1
	
	Color 256,256,256
	Text 0,0,"x: " + player\x
	Text 0,12,"y: " + player\y
	Text 0,24,"DrawX: " + DrawX
	Text 0,36,"DrawY: " + DrawY
	
	SetBuffer BackBuffer()
	DrawImage HUD,0,0
	
End Function

Function LoadRoom(room)

	Select room
	
		Case HouseExterior\number	
		
			MaxX = HouseExterior\maxX
			MaxY = HouseExterior\maxY
										
			MarginX = 100
			MarginY = 50
			
			backimage = GrassImage
			
			door1\image = LoadImage("Door.bmp")
			door1\width = ImageWidth(door1\image)
			door1\height = ImageHeight(door1\image)+100		
			door1\destination = HouseInterior\number
			
			door2\image = LoadImage("PathBeginning.bmp")
			door2\width = ImageWidth(door2\image)
			door2\height = ImageHeight(door2\image)
			door2\destination = ForestPath\number
			
		Case HouseInterior\number
		
			MaxX = HouseInterior\maxX
			MaxY = HouseInterior\maxY
						
			MarginX = 220
			MarginY = 150
								
			DrawX = MaxX
			DrawY = MaxY
			
			backimage = WoodenFloorImage
			
			door1\image = LoadImage("Interior_Door.bmp")
			door1\height = ImageHeight(door1\image)+100
			door1\width = ImageWidth(door1\image)
			door1\destination = HouseExterior\number
			
		Case ForestPath\number
		
			MaxX = ForestPath\maxX
			MaxY = ForestPath\maxY
			
			MarginX = 100
			MarginY = 50
			
			backimage = GrassImage
			
			door1\image = LoadImage("PathBeginning.bmp")
			RotateImage door1\image,180
			door1\width = ImageWidth(door1\image)
			door1\height = ImageHeight(door1\image)
			door1\destination = HouseExterior\number
			
			door2\image = LoadImage("PathBeginning.bmp")
			RotateImage door2\image,90
			door2\width = ImageWidth(door2\image)
			door2\height = ImageHeight(door2\image)
			door2\destination = 3
			
	End Select
	
	If MaxX > SCREENWIDTH
		bx = MaxX-(2*MarginX)
	Else
		bx = MaxX
	EndIf
	
	If MaxY > SCREENHEIGHT
		by = MaxY-(2*MarginY)
	Else
		by = MaxY
	EndIf
	
	background = CreateImage(bx,by)
			
	SetBuffer ImageBuffer(background)
	TileBlock backimage
	
	SetBuffer BackBuffer()
	DrawImage background,StartX,StartY
					
	UpdateVariables()
	
End Function

Function CheckCollisions()
	
	Select PlayerRoom
		
		Case HouseExterior\number
			HouseExteriorCollisions()
			
		Case HouseInterior\number
			HouseInteriorCollisions()
			
		Case ForestPath\number
			ForestPathCollisions()
			
	End Select
	
End Function

Function HouseExteriorCollisions()
	
	If ImagesOverlap(player\image,player\x,player\y,house\image,house\x,house\y) 
		
		player\x = CurrentX
		player\y = CurrentY
		
		DrawX = CurrentDrawX
		DrawY = CurrentDrawY
		
	EndIf
	
	If ImageRectOverlap(player\image,player\x,player\y,tree\x+70,tree\y+2*(ImageHeight(tree\image)/3)+25,ImageWidth(tree\image)-160,ImageHeight(tree\image)/3-25)
	
		player\x = CurrentX
		player\y = CurrentY
		
		DrawX = CurrentDrawX
		DrawY = CurrentDrawY
		
	EndIf
	
	If ImageRectOverlap(player\image,player\x,player\y,door1\x,door1\y,door1\width,door1\height)
		
		CreateTextBox(door1\x,door1\y,"Enter " + HouseInterior\name$ + "?",0)
		
		If KeyHit(ENTERKEY)
		
			ChangeRoom(door1\destination,PlayerRoom,0)
			
		EndIf
	
	EndIf
	
	If ImageRectOverlap(player\image,player\x,player\y,door2\x,door2\y,door2\width,door2\height)
		
		CreateTextBox(door2\x,door2\y,"Go To " + ForestPath\name$ + "?",0)
		
		If KeyHit(ENTERKEY)
		
			ChangeRoom(door2\destination,PlayerRoom,0)
			
		EndIf
	
	EndIf

End Function

Function HouseInteriorCollisions()

	If ImageRectOverlap(player\image,player\x,player\y,door1\x,door1\y-100,door1\width,door1\height)
	
		CreateTextBox(door1\x,door1\y,"Exit " + HouseInterior\name$ + "?",0)
		
		If KeyHit(ENTERKEY)

			ChangeRoom(door1\destination,PlayerRoom,0)
			
		EndIf
	
	EndIf

End Function

Function ForestPathCollisions()
	
	If ImageRectOverlap(player\image,player\x,player\y,tree\x+70,tree\y+2*(ImageHeight(tree\image)/3)+25,ImageWidth(tree\image)-160,ImageHeight(tree\image)/3-25)
	
		player\x = CurrentX
		player\y = CurrentY
		
		DrawX = CurrentDrawX
		DrawY = CurrentDrawY
		
	EndIf
	
	If ImagesOverlap(player\image,player\x,player\y,door1\image,door1\x,door1\y)
	
		CreateTextBox(door1\x,door1\y,"Go to " + HouseExterior\name$ + "?",0)
		
		If KeyHit(ENTERKEY)

			ChangeRoom(door1\destination,PlayerRoom,0)
			
		EndIf
	
	EndIf 

End Function

Function ChangeRoom(destination,room,door)

	Select room
	
		Case HouseExterior\number
		
			Select destination
			
				Case HouseInterior\number
					
					PlayerRoom = HouseInterior\number
					LoadRoom(PlayerRoom)
					
					player\x = (SCREENWIDTH/2)-(ImageWidth(door1\image)/2)
					player\y = MaxY+MarginY-ImageHeight(player\image)
					player\frame = 1
					
				Case ForestPath\number
					
					PlayerRoom = ForestPath\number
					LoadRoom(PlayerRoom)
					
					DrawX = MaxX
					DrawY = MaxY
									
					UpdateVariables()
					
					player\x = StartX
					player\y = StartY+ImageHeight(door1\image)/2
					player\frame = 0
					
			End Select
			
		Case HouseInterior\number
		
			PlayerRoom = HouseExterior\number
			LoadRoom(PlayerRoom)
			
			player\x = MarginX+106
			player\y = MarginY+ImageHeight(house\image)
			player\frame = 3
			
			DrawX = MaxX
			DrawY = MaxY
			
		Case ForestPath\number
		
			Select destination
				
				Case HouseExterior\number
				
					PlayerRoom = HouseExterior\number
					LoadRoom(PlayerRoom)
					
					DrawX = SCREENWIDTH
					DrawY = SCREENHEIGHT
					
					player\x = DrawX-ImageWidth(player\image)-MarginX
					player\y = DrawY/2-ImageHeight(door2\image)/2
					player\frame = 2
				
			End Select
			
	End Select

End Function

Function CreateTextBox(x,y,message$,category)

		textbox = CreateImage(600,150)
		
		boxy = y - StringHeight(message$) - 8
		boxx = x
		
		If Len(message$) > 41 And Len(message$) <= 81
			boxheight = 2*StringHeight(message$)+12
			boxwidth = StringWidth(Left(message$,Instr(message$," ",40)))+8 
			
		ElseIf Len(message$) > 81 And Len(message$) <= 121
			boxheight = 3*StringHeight(message$)+16
			
			If Instr(message$," ",40) < Instr(message$," ",80)-Instr(message$," ",40)
				boxwidth = StringWidth(Mid$(message$,Instr(message$," ",40),Instr(message$," ",80)-Instr(message$," ",40)))
			Else 
				boxwidth = StringWidth(Left(message$,Instr(message$," ",40)))+8
			EndIf
			
		Else
			boxheight = StringHeight(message$) + 8
			boxwidth = StringWidth(message$) + 8
		EndIf
							
		SetBuffer ImageBuffer(textbox)
		
		Select category 
			Case 0
				Color 95,235,183
			Case 1	
				Color 185,239,255
			Case 2
				Color 197,213,250
				
		End Select
		Rect 0,0,boxwidth,boxheight
			
		Color 256,256,256
		
		If Len(message$) > 41 

			oldline = Instr(message$," ",40)
			x = 4
			For i = 1 To oldline
				Text x+(i-1)*StringWidth(Mid$(message$,i,1)),4,Mid$(message$,i,1)
			Next
			
			If Len(message$) < 81
				newline1 = Len(message$)
			Else
				newline1 = Instr(message$," ",80)
			EndIf
			
			For i = oldline To newline1
				Text 4+(i-oldline-1)*StringWidth(Mid$(message$,i,1)),18,Mid$(message$,i,1)
			Next
			
			If Len(message$) > 81
				newline2 = Len(message$)
				;newline2 = Instr(message$," ",120)
				For i = newline1 To newline2
					Text 4+(i-newline1-1)*StringWidth(Mid$(message$,i,1)),32,Mid$(message$,i,1)
				Next
			EndIf
			
		Else
		
			Text 4,4,message$
			
		EndIf
		
		SetBuffer BackBuffer()	
		
		If category = 1 ;Or category = 2
								
			;If category = 2
				;PauseChannel music
			
				;PlaySound sObtainItem\sound
				;Delay 1500
				
				;ResumeChannel music
			
			;EndIf
			
			FlushKeys()
			While Not KeyHit(ENTERKEY)
			
				Cls
				DrawGraphics()
			
				DrawImage textbox,boxx,boxy
			
				Flip
			
			Wend
			
			SetBuffer ImageBuffer(textbox)
			Cls
		
		EndIf
		
		If category = 0
			
			DrawImage textbox,boxx,boxy
			
		EndIf

End Function

Sizes for the images in question are:

pathsegmentH\image 480 X 131
pathcorner1\image 130 X 132

The other images are 90 degree rotations of these two.

And no, I did not use midhandle() either.

Stevie G

(Posted 2009) [#9]

The other images are 90 degree rotations of these two.

I suspect that this is your issue. AFAIK using rotateimage will rotate the imagehandle also. If so, you will need to reset it to be top left after rotation.

Stevie

OwlEpicurus

(Posted 2009) [#10]

Thanks. That's probably where the problem is.