bullets in a gun

Blitz3D Forums/Blitz3D Programming/bullets in a gun

Captain Wicker (crazy hillbilly)

(Posted 2013) [#1]

	Graphics3D 800,600,32,2

	SetBuffer(BackBuffer())


	Global gun, cubes, plane, bullets

	HidePointer()


	Global cam=CreateCamera()



	Global light=CreateLight()

	CameraFogRange cam,10,100

	CameraFogMode cam,1

	EntityParent light,cam

	CameraFogColor cam,0,0,0

	plane=CreatePlane(4)
	ScaleEntity plane,200,200,200
	MoveEntity plane,0,-5,0
	EntityParent plane,cam



	Type TBULLETS

		Field X
		Field Y
		Field Z
	
	End Type



	MakeGunner()


	For c=1 To 100
		cubes=CreateCube()
		ScaleEntity cubes,Rnd(15),Rnd(15),Rnd(15)
		EntityColor cubes,Rnd(255),Rnd(255),Rnd(255)
		PositionEntity cubes,Rand(-255,255),Rnd(0),Rand(-255,255)
	Next 

	For b=1 To 100
		bullets=CreateSphere(24)
		ScaleEntity bullets,.2,.2,.2
		EntityColor bullets,255,255,0
	Next
	
	EntityShininess cubes,90
	EntityShininess bullets,90
	EntityShininess gun,90
	

	


	While Not KeyHit(1)



	MoveCammy()


	If KeyDown(57)
	
		For X=1 To 10
			For Y=1 To 10
				For Z=1 To 10
					bull.TBULLETS=New TBULLETS
					bull\x=EntityX(bullets)
					bull\y=EntityY(bullets)
					bull\z=EntityZ(bullets)
				Next
			Next
		Next
	
		For bull.TBULLETS = Each TBULLETS
			bull\x = bull\x + 1
		Next

		
	EndIf
	
		

	

	UpdateWorld()
	RenderWorld() 
	Flip(-1)


	Wend
	End 




	Function MakeGunner()
	
		gun=CreateCylinder(24)
	
		PositionEntity gun,EntityX(cam),-1,EntityZ(cam)+2
	
		ScaleEntity gun,.25,.5,.8
	
		RotateEntity gun,25,0,0
		
		EntityParent gun,cam


	End Function 




	Function MoveCammy()

		If KeyDown(203) Then TurnEntity cam,0,1,0
	
		If KeyDown(205) Then TurnEntity cam,0,-1,0
	
		If KeyDown(200) Then MoveEntity cam,0,0,1
	
		If KeyDown(208) Then MoveEntity cam,0,0,-1
	
	
	End Function

it's been a while since I fiddled with b3d. I am trying to make bullets shoot out of the cylinder when I press the space bar key. I successfully did this once in an fps I was doing, but forgot and lost the source. Lol. Anybody? :D

Rob the Great

(Posted 2013) [#2]

I feel like programming today, so don't be surprised if you see an abnormal amount of posts from me.

I took what you had posted and modified it to do what I think you were getting at. Most of it is unchanged, but I commented everything that I removed or added to make it work.

Good luck.

	Graphics3D 800,600,32,2

	SetBuffer(BackBuffer())


	Global gun, cubes, plane, bullets

	HidePointer()


	Global cam=CreateCamera()



	Global light=CreateLight()

	CameraFogRange cam,10,100

	CameraFogMode cam,1

	EntityParent light,cam

	CameraFogColor cam,0,0,0

	plane=CreatePlane(4)
	ScaleEntity plane,200,200,200
	MoveEntity plane,0,-5,0
	EntityParent plane,cam



	Type TBULLETS

		Field entity
		;Field X ;x,y,z can always be retreived with EntityX, EntityY, EntityZ
		;Field Y
		;Field Z
	
	End Type



	MakeGunner()


	For c=1 To 100
		cubes=CreateCube()
		ScaleEntity cubes,Rnd(15),Rnd(15),Rnd(15)
		EntityColor cubes,Rnd(255),Rnd(255),Rnd(255)
		PositionEntity cubes,Rand(-255,255),Rnd(0),Rand(-255,255)
	Next 

;	Don't make all of your bullets at once. Make one every time you hit the space bar.
;	For b=1 To 100
;		bullets=CreateSphere(24)
;		ScaleEntity bullets,.2,.2,.2
;		EntityColor bullets,255,255,0
;	Next

;	Make a master bullet to copy later
	bullets=CreateSphere(24)
	ScaleEntity bullets,.2,.2,.2
	EntityColor bullets,255,255,0
	HideEntity bullets ;Hide it so that you don't have a random bullet floating around.
	
	EntityShininess cubes,90
	EntityShininess bullets,90
	EntityShininess gun,90
	

	


	While Not KeyHit(1)



	MoveCammy()


	If KeyDown(57)
	
;		Unless you want the extreme shotgun effect, this isn't the right approach.
;		For X=1 To 10
;			For Y=1 To 10
;				For Z=1 To 10
;					bull.TBULLETS=New TBULLETS
;					bull\x=EntityX(bullets)
;					bull\y=EntityY(bullets)
;					bull\z=EntityZ(bullets)
;				Next
;			Next
;		Next

		bull.TBULLETS=New TBULLETS
		bull\entity = CopyEntity(bullets) ;copy the master bullet
		PositionEntity bull\entity,EntityX(cam),EntityY(cam),EntityZ(cam) ;position at the camera (or the gun)
		RotateEntity bull\entity,EntityPitch(cam),EntityYaw(cam),EntityRoll(cam) ;rotate the same direction
		
	
;		This is the right idea, but you want to update the bullets even if you don't hold down the space bar.
;		For bull.TBULLETS = Each TBULLETS
;			bull\x = bull\x + 1
;		Next

		
	EndIf
	
	;This will update each bullet every loop (note that it's not inside the If KeyDown(57) scope.
	;You should probably put this in its own function eventually
	For bull.TBULLETS = Each TBULLETS ;for every bullet made
		MoveEntity bull\entity,0,0,1 ;move it forward locally
		If EntityDistance(bull\entity,cam) > 100 ;if it's too far away
			FreeEntity bull\entity ;get rid of the bullet
			Delete bull ;get rid of the corresponding type
		EndIf
	Next
	
		

	

	UpdateWorld()
	RenderWorld() 
	Flip(-1)


	Wend
	End 




	Function MakeGunner()
	
		gun=CreateCylinder(24)
	
		PositionEntity gun,EntityX(cam),-1,EntityZ(cam)+2
	
		ScaleEntity gun,.25,.5,.8
	
		RotateEntity gun,25,0,0
		
		EntityParent gun,cam


	End Function 




	Function MoveCammy()

		If KeyDown(203) Then TurnEntity cam,0,1,0
	
		If KeyDown(205) Then TurnEntity cam,0,-1,0
	
		If KeyDown(200) Then MoveEntity cam,0,0,1
	
		If KeyDown(208) Then MoveEntity cam,0,0,-1
	
	
	End Function

Captain Wicker (crazy hillbilly)

(Posted 2013) [#3]

thanks Rob. much appreciated. :)