Using a mesh as Parent to Spotlight

Blitz3D Forums/Blitz3D Programming/Using a mesh as Parent to Spotlight

Imperium

(Posted 2013) [#1]

I'm trying to use 4 different meshes to help position a series of spot lights but its not working correctly. The lights won't position themselves at the parent objects location. The image above is the map inside maya showing the cubes as markers for the spot lights.

dummylight1=LoadMesh("ao_models/testmap/dummyl1.3ds")
;TurnEntity dummylight1,-90,0,0
ScaleEntity dummylight1,.9,.9,.9
PositionEntity dummylight1,24,.1,24,True
EntityAlpha dummylight1,0
	
dummylight2=LoadMesh("ao_models/testmap/dummyl2.3ds")
;TurnEntity dummylight2,-90,0,0
ScaleEntity dummylight2,.9,.9,.9
PositionEntity dummylight2,24,.1,24,True
EntityAlpha dummylight2,0
	
dummylight3=LoadMesh("ao_models/testmap/dummyl3.3ds")
;TurnEntity dummylight3,-90,0,0
ScaleEntity dummylight3,.9,.9,.9
PositionEntity dummylight3,24,.1,24,True
EntityAlpha dummylight3,0
	
dummylight4=LoadMesh("ao_models/testmap/dummyl4.3ds")
;TurnEntity dummylight4,-90,0,0
ScaleEntity dummylight4,.9,.9,.9
PositionEntity dummylight4,24,.1,24,True
EntityAlpha dummylight4,0


; Then I try this but it only shows on the wall and is being created at 0,0,0 instead.
greenlight2 = CreateLight (3,dummylight2)
LightColor greenlight2, 0, 100, 0
LightRange greenlight2, 8
LightConeAngles greenlight2,0,90
RotateEntity greenlight2,90,0,0

Kryzon

(Posted 2013) [#2]

From the documentation:

Specifying a parent entity will still result in the light being created at position 0,0,0 rather than at the parent entity's position.

Rather do the following:

greenLight2 = CreateLight( 3 )
EntityParent( greenLight2, dummyLight2, False ) ;The False parameter forces an 'alignment' of the child with the parent.

Imperium

(Posted 2013) [#3]

It won't face the floor and I've tried changing both YAW and PITCH. The light still doesn't seem to be attached to the parent either. It's only supposed to be a small green light on the ceiling.

I've set the light range to 8. Should I just make another object to point it to the floor? Something tells me this is not the best approach. I also think you can't Rotate a light but instead turn it.

Kryzon

(Posted 2013) [#4]

I would first make a mesh to represent the light. A cone primitive, for instance. This way I would have something visible to tune and see if it's positioned correctly etc.

Then after testing, I would replace the cone entity with the actual light.

Imperium

(Posted 2013) [#5]

I've already tried that with createsphere with a light attached. This redlight I tested earlier happily followed around the sphere when I moved it in real time. I'm taking a close look at it now.

edit:

redlight = createlight (3)
positionentity redlight,48,4.5,24,false
lightcolor redlight, 100,0,0
lightrange redlight, 10
lightconeangles redlight,0,80
rotateentity redlight,90,0,0

lightmarker = createsphere(4)
entityparent lightmarker,redlight,false
scaleentity lightmarker,.3,.3,.3

The above works fine but the greenlight below doesn't work properly. When it does appear its usually facing a wall instead of the floor. I switched dummy light 2 and 3 around because dummy light 2 wasn't in the right place.

greenlight = createlight (3)
lightcolor greenlight, 0,150,0
lightrange greenlight, 8
lightconeangles greenlight,0,90

entityparent (greenlight, dummylight3,false)
rotateentity greenlight,90,0,0

This is driving me crazy. In the original post I took out the Turnentity for the dummylights because I thought that may be affecting the positioning of the actual light.

Kryzon

(Posted 2013) [#6]

There's not much way to help without having the entire scene and code here.
In any case, a particular problem I had when dealing with Blitz3D and 3DS Max (I think Maya may be the same) was the axis convention: in 3DS the Z and Y axes are swapped.

RemiD

(Posted 2013) [#7]

I have not managed to find the right calculation to scale the "rayon" according to the lightcone angles.

But this will give you an idea on how to set an entity as a child of another entity, and give the child entity the same orientation and position :

Graphics3D(800,600,32,2)
SetBuffer(BackBuffer())
SeedRnd(MilliSecs())

Origine = CreateCube()
ScaleMesh(Origine,0.01/2,0.01/2,0.01/2)
EntityColor(Origine,255,000,000)

Camera = CreateCamera()
CameraRange(Camera,0.1,100)
CameraClsColor(Camera,000,000,000)
PositionEntity(Camera,5,1.6,-5)

SmallPartMesh = CreateMesh()
Surface = CreateSurface(SmallPartMesh)
AddVertex(Surface, 0.0, 0.0, 0.5)
AddVertex(Surface, 0.5, 0.0, 0.5)
AddVertex(Surface, 0.0, 0.0, 0.0)
AddVertex(Surface, 0.5, 0.0, 0.0)
AddTriangle(Surface,0,1,2)
AddTriangle(Surface,2,1,3)
GroundPartMesh = CreateMesh()
For GX% = 0 To 1
 For GZ% = 0 To 1
  TPart = CopyMesh(SmallPartMesh)
  PositionMesh(TPart,GX*0.5,0,GZ*0.5)
  AddMesh(TPart,GroundPartMesh)
  FreeEntity(TPart)
 Next
Next
FreeEntity(SmallPartMesh)
GroundMesh = CreateMesh()
For GX% = 0 To 9
 For GZ% = 0 To 9
  TPart = CopyMesh(GroundPartMesh)
  PositionMesh(TPart,GX,0,GZ)
  AddMesh(TPart,GroundMesh)
  FreeEntity(TPart)
 Next
Next
UpdateNormals(GroundMesh)
FreeEntity(GroundPartMesh)

R% = Rand(005,255)
G% = Rand(005,255)
B% = Rand(005,255)

SpotY# = 5
SpotAngle# = 67.5

SpotSource = CreatePivot()
PositionEntity(SpotSource,5,SpotY,5)
TurnEntity(SpotSource,90,0,0)
Debug_SpotSource = CreateCube()
ScaleMesh(Debug_SpotSource,0.01/2,0.01/2,0.01/2)
EntityColor(Debug_SpotSource,R,G,B)
PositionEntity(Debug_SpotSource,EntityX(SpotSource,True),EntityY(SpotSource,True),EntityZ(SpotSource,True))
RotateEntity(Debug_SpotSource,EntityPitch(SpotSource,True),EntityYaw(SpotSource,True),EntityRoll(SpotSource,True))
EntityParent(Debug_SpotSource,SpotSource,True)

SpotLight = CreateLight(3)
LightColor(SpotLight,R,G,B)
LightRange(SpotLight,SpotY)
LightConeAngles(SpotLight,0,SpotAngle)
PositionEntity(SpotLight,EntityX(SpotSource,True),EntityY(SpotSource,True),EntityZ(SpotSource,True))
RotateEntity(SpotLight,EntityPitch(SpotSource,True),EntityYaw(SpotSource,True),EntityRoll(SpotSource,True))
EntityParent(SpotLight,SpotSource,True)

SpotRayon = CreateCone(16)
ScaleMesh(SpotRayon,1.0/2,1.0/2,1.0/2)
PositionMesh(SpotRayon,0,-1.0/2,0)
RotateMesh(SpotRayon,-90,0,0)
EntityColor(SpotRayon,R,G,B)
EntityAlpha(SpotRayon,0.1)
EntityFX(SpotRayon,1)
PositionEntity(SpotRayon,EntityX(SpotSource,True),EntityY(SpotSource,True),EntityZ(SpotSource,True))
RotateEntity(SpotRayon,EntityPitch(SpotSource,True),EntityYaw(SpotSource,True),EntityRoll(SpotSource,True))
EntityParent(SpotRayon,SpotSource,True)
ScaleEntity(SpotRayon,SpotY*(1+(SpotAngle/360)),SpotY*(1+(SpotAngle/360)),SpotY)

DLight = CreateLight(1)
LightColor(DLight,050,050,050)
PositionEntity(DLight,0,1000,-1000)
RotateEntity(DLight,45,0,0)
HideEntity(DLight)

AmbientLight(015,015,015)

Repeat

 SetBuffer(BackBuffer())

 If(KeyDown(17)>0)
  MoveEntity(Camera,0,0,0.1)
 ElseIf(KeyDown(31)>0)
  MoveEntity(Camera,0,0,-0.1)	
 EndIf
 If(KeyDown(30)>0)
  TurnEntity(Camera,0,1,0)
 ElseIf(KeyDown(32)>0)
  TurnEntity(Camera,0,-1,0)
 EndIf

 If(KeyDown(2)>0)
  WireFrame(True)
 Else
  WireFrame(False)
 EndIf
	
 ClsColor(000,000,000)

 Cls()
	
 RenderWorld()
 
 Text(0,0,"Triangles = "+TrisRendered())
	
 Flip(1)

Until(KeyDown(1)>0)

End()