A note about linepick with a radius

Blitz3D Forums/Blitz3D Programming/A note about linepick with a radius

RemiD

(Posted 2015) [#1]

If you use linepick with a radius, the total length of the line seems to be vectorlength + radius.

I fixed a bug by taking this into account.

Maybe this will help somebody...

Rick Nasher

(Posted 2015) [#2]

interesting piece of knowledge indeed, thanks.

Kryzon

(Posted 2015) [#3]

In that case the line should look like an elongated capsule, with round extremities.

Yue	(Posted 2015) [#4]

I definitely learn best with images that translating from google.

Floyd

(Posted 2015) [#5]

If you use linepick with a radius, the total length of the line seems to be vectorlength + radius.

Coming from a mathematical background that is exactly what I assumed. There is a vector of the given length and a sphere centered at the head of the vector.

RemiD

(Posted 2015) [#6]

There was some witchcraft here, i can't see my first post... ?!

Floyd

(Posted 2015) [#7]

That's probably my fault. I am able delete or hide posts. The hide link is on the right edge of the screen and is easy to hit by accident on a tablet.

It's back now.

RemiD

(Posted 2015) [#8]

I think it looks like this :

RGR	(Posted 2015) [#9]

Here is a small example where you can test how LinePick (with and without Radius) and how EntityPick works.

;   Written in a patched PureBasicIDE with PBCode
;   Made with Roeske's Skydat-Precompile
;   31  03 2015 / 13:40:17

;Include "LinepickTestConst.bb"
Graphics3D(0, 0, 32, 1)

pivot=CreatePivot()

light=CreateLight()
PositionEntity(light, 0, 100, 0, 1)

cam=CreateCamera()
PositionEntity(cam, 10, 20, 0, 1)

sphere=CreateSphere(32)

cube=CreateCube(sphere)
EntityColor(cube, 0,255,0)
ScaleEntity(cube, 0.04, 0.04, 10.0, 1)

sphere3=CreateSphere(32,sphere)
PositionEntity(sphere3, 0, 0, 10, 1)
EntityAlpha(sphere3, 0.5)
EntityColor(sphere3, 255,255,0)

PositionEntity(sphere, -3.0, 0, 0, 1)

Radius#=0.2
sphere2=CreateSphere(32)
PositionEntity(sphere2, 10, 0, 0, 1)
EntityPickMode(sphere2, 1)
EntityColor(sphere2, 255, 0 ,0)
EntityAlpha(sphere2, 0.5)

PointEntity(sphere, sphere2)
TurnEntity(cam, 90,0,0)

While Not KeyHit(1)
	If KeyDown(31)
		Radius# = Radius# + 0.01
	EndIf
	If KeyDown(30)
		Radius# = Radius# - 0.01
		If Radius<0.0
			Radius=0.0
		EndIf
	EndIf
	If Radius>0
		ShowEntity(sphere3)
		ScaleEntity(sphere3, radius, radius, radius, True)
	Else
		HideEntity(sphere3)
	EndIf
	EntityPick(sphere, 10.0)
	PEnt=PickedEntity()
	xD#=EntityX(sphere3, True)-EntityX(sphere, True)
	yD#=EntityY(sphere3, True)-EntityY(sphere, True)
	zD#=EntityZ(sphere3, True)-EntityZ(sphere, True)
	LinePick(EntityX(sphere, 1),EntityY(sphere, 1),EntityZ(sphere, 1),xD, yD, zD, Radius)
	PEnt2=PickedEntity()
	If KeyDown(203)
		TranslateEntity(sphere, -0.01, 0, 0, True)
	ElseIf KeyDown(205)
		TranslateEntity(sphere, 0.01, 0, 0, True)
	EndIf
	
	If KeyDown(200)
		TurnEntity(sphere, 0, 0.2, 0, True)
	EndIf
	If KeyDown(208)
		TurnEntity(sphere, 0, -0.2, 0, True)
	EndIf
	
	UpdateWorld()
	RenderWorld()
	
	
	x=10
	y=15
	Text(x, y, "Green Line is 10 units long each side. Shows where/when LinePick / EntityPick on Sphere2 gets detected.")
	y=y+15
	Text(x, y, "[A] [S] Change Radius   [Left] [Right] Move Sphere   [Up] [Down] Rotate Sphere")
	y=y+15
	Color(255,255,0)
	Text(x, y, "Radius: "+Str(Radius))
	y=y+15
	Color(0,255,0)
	Text(x, y, "EntityPick: "+Str(PEnt))
	y=y+15
	Text(x, y, "LinePick: "+Str(PEnt2))
	y=y+15
	Color(255,255,255)
	Text(x, y, "Sphere: "+Str(sphere))
	y=y+15
	color(255,0,0)
	Text(x, y, "Sphere2: "+Str(sphere2))
	y=y+15
	Color(255,255,255)
	Text(x, y, "Distance: "+Str(EntityDistance(sphere, sphere2)))
	y=y+15
	Text(x, y, "xD: "+Str(xD))
	y=y+15
	Text(x, y, "yD: "+Str(yD))
	y=y+15
	Text(x, y, "zD: "+Str(zD))
	
	flip(1)
Wend
End



; IDE Options = Blitz3DEd
; CursorPosition = 75
; FirstLine = 36
; Folding = --
; DisableDebugger
;Include "LinepickTestFunc.bb"