Warp mesh ?

Blitz3D Forums/Blitz3D Programming/Warp mesh ?

Yue	(Posted 2016) [#1]

Hi, I 'm trying to think as to deform the ground by the impact of a bomb falling on the ground or any mesh , my tests are more focused to a meteor impact , but I really do not know how . In this has to do TformPoint ?, I would like someone to tell me that this form command means is that point refers to a point.

Greetings.

Graphics3D 800, 600, 32, 2
SetBuffer ( BackBuffer())

Local camara% 	= CreateCamera()
Local luz%		= CreateLight()
Local terreno% 	= LoadTerrain("Terreno.png")
Local bomba%    = LoadMesh("Bomba.b3d")

Local texturaT% = LoadTexture("Tierra.jpg")
ScaleTexture (texturaT%, 4,4 )
EntityTexture ( terreno%, texturaT%)
PositionEntity terreno%, -128, 0, -128
ScaleEntity terreno%, 1, 40, 1
ScaleEntity bomba%, .2, .2, .2

PositionEntity camara%, 0, 40,-10
PositionEntity bomba%, 0, 60, 50


EntityType bomba%, 1
EntityType terreno, 2




Collisions 1, 2,2, 2 


WireFrame True

While Not KeyHit(1)
	
	
	If EntityCollided(bomba%, 2 ) End 
	
	
	TranslateEntity bomba%, 0, -.5, 0
	
	
	UpdateWorld() 
	RenderWorld()
	Flip() 
	
	
	
	
Wend

Edit


	For  c% = 1 To CountCollisions(terreno%)
		
		colisionBomba% = GetEntityType(bomba%)
		
		If c% = colisionbomba% Then RuntimeError "Boom!!"
		
		
		
	Next

Edit 2 no work for me.



	For  c% = 1 To CountCollisions(terreno%)
		
		colisionBomba% = GetEntityType(bomba%)
		
		If c% = colisionbomba% Then 
			
			
			x# = EntityX(bomba%,True)
			y# = EntityY(bomba%,True)
			z# = EntityZ(bomba%,True)
			
			TFormPoint (x#, y#, z#, terreno%, 0 )
			
			ModifyTerrain ( terreno, TFormedX(), TFormedY()-100, TFormedZ(),True)
			
			
		End If 
		
		
		
		
		
	Next

RemiD

(Posted 2016) [#2]

You can see how to deform a blitz3d terrain in the demo Blitz3D\samples\mak\castle

also an example to modify the height with 0.1 precision :

TerrainB3D = CreateTerrain(32)
ScaleEntity(TerrainB3D,1,25.5,1) ;(max height of 25.5)
TerrainDetail(TerrainB3D,2048,True)
TerrainShading(TerrainB3D,True)
PositionEntity(TerrainB3D,0,0,0)

For HX% = 0 To 32-1
 For HZ% = 0 To 32-1
  HeightRGB% = Rand(030,035) ;(height between 3.0 and 3.5 on a greyscale heightmap)
  Height# = 1.0/255*HeightRGB ;(height in percent, if i remember correctly)
  ModifyTerrain(TerrainB3D,HX,HZ,Height,False) 
 Next
Next

Yue	(Posted 2016) [#3]

Thanks, but as I make a crater in the ground , I mean detect the coordinates of impact on terrain mesh and make a hole.

Rick Nasher

(Posted 2016) [#4]

Hehehe Yue. I did this years ago making use of some code from around here. Didn't know what I was doing but it worked more or less.
I'll look it up...

found it :


Function MakeTerrainCrater(entity,Terrain,radius#=.5,th#=10,hardness#=0.5)

; ex#,ez#,x#,z#,terrainscale ,radius# , hardness#,d#,h#,scale#

; A righthandy function that easily makes a nice round crater. 
; Assumes terrain sections are 1x1 Blitz units (add Step to change). 
; Also fun to tinker with, and easy to add particles, crater ring, etc.
;
; entity=entity crater is created around
; terrain=terrain in which the crater is formed
; radius=crater's radius (default is 1)
; th=maximum height of any terrain section (default is 100)
; hardness=hardness of the ground, 1 is completely soft, 0 is completely solid (default is 1) 


	ex#=EntityX#(entity)/terrainscale ; added /terrainscale to make work
	ey#=EntityY#(entity)
	ez#=EntityZ#(entity)/terrainscale
	
	;=============================
	; generate the crater
	;=============================
	For x#=-radius# To radius#
		For z#=-radius To radius#
			If Sqr(x#^2+z#^2)<=radius# And hardness#<>0
				d#=Sqr(x#*x#+z#*z#)	
				h#=TerrainHeight#(Terrain,ex+x#,ez+z#)
				scale#=th#/hardness#
				h#=h#+d#/scale#-radius#/scale#
				If h#<0 Then h#=0
				ModifyTerrain(Terrain,ex+x#,ez+z#,h#,True)
				
				ScorchTerrain(ex+x#,ez+z#) ;generate the black scorch 
				;ScorchTerrain(EntityX(marker2)/terrainscale,EntityZ(marker2)/terrainscale)	
			EndIf
		Next
	Next
	
End Function

Rick Nasher

(Posted 2016) [#5]

So basically you shoot bullet entity at the terrain and when it collided with terrain you execute this function.
I used it like this..

bullitX#=EntityX(b\entity)
bullitY#=EntityY(b\entity)
bullitZ#=EntityZ(b\entity)
				
PositionEntity b\entity,bullitX#,bullitY#+fall,bullitZ#	;fall to earth when velocity gets below threshold (1)
				
; if bullit is at terrainheight then explode & hide
If bullitY#<TerrainY(terrain,bullitX#,bullitY#,bullitZ#)+4 Or EntityCollided(b\entity,col_level) ; create different response for what has been hit later..

	b\inflight=0 ;flight has finished, so set flag & a MakeGrenadeExplosion
	MakeGrenadeExplosion(b\entity)
	HideEntity b\entity ; hide shot collided bullir

EndIf

Oh and btw you need to put a ; before the scorch bit, for I think it's something I added leaving a black stain on the crater.

or use this with it:

Function ScorchTerrain(scorchx#,scorchz#)
	
;** scorchx#,scorchz#, tertex2
	
	SetBuffer TextureBuffer(tertex2)
	Color 70,70,75 ;color is dark

	Plot scorchz#,scorchx#

	;SetBuffer BackBuffer()
End Function

And:

Function UpdateScorch()

; ** vars used:
; ** s.scorch,s\ent,s\life

	For s.scorch=Each scorch
		EntityAlpha s\ent,s\life
		s\life=s\life-0.005
		If s\life<0
			
			;MakeCrater(0,80,EntityX(s\ent),EntityY(s\ent),EntityZ(s\ent),level,20,1) ;=new=
			; or for this make a shallow dent..

			FreeEntity s\ent
			Delete s
		EndIf
	Next
End Function

Result is something like this:

Yue	(Posted 2016) [#6]

Ok , I have no problems , I have a bomb falling on the ground and leaving a huge crater.

Thank you very much. :)


Graphics3D 800, 600, 32, 2
SetBuffer ( BackBuffer())

Local camara% 	= CreateCamera()
Local luz%		= CreateLight()
Local terreno% 	= LoadTerrain("Terreno.png")
Local bomba%    = LoadMesh("Bomba.b3d")

Local texturaT% = LoadTexture("Tierra.jpg")
ScaleTexture (texturaT%, 4,4 )
EntityTexture ( terreno%, texturaT%)
PositionEntity terreno%, -128, 0, -128
ScaleEntity terreno%, 1, 40, 1
ScaleEntity bomba%, .2, .2, .2

PositionEntity camara%, 0, 25,10
PositionEntity bomba%, 0, 60, 30


EntityType bomba%, 1
EntityType terreno, 2




Collisions 1, 2,2, 2 

TerrainShading terreno,True
TerrainDetail terreno,2000

ModifyTerrain(terreno%,128, 128, 500,True)


WireFrame True

While Not KeyHit(1)
	
	
	
	
	
	
	
	
	
	For  c% = 1 To CountCollisions(terreno%)
		
		colisionBomba% = GetEntityType(bomba%)
		
		
		If c% = colisionbomba% Then 
			
			
			x# = EntityX(bomba%)
			y# = EntityY(bomba%)
			z# = EntityZ(bomba%)
			TFormPoint (x#, y#, z#,  0, terreno%  )
			
			
			
			
			h# = TerrainHeight(terreno,TFormedX(),TFormedY())
			
			
			
			If h > 0 Then
				h = h -.1
				If h < .5  Then  h = .5
				
				
				
				ModifyTerrain ( terreno%, TFormedX()+ Rnd(-2,2), TFormedZ()+Rnd(-2,2),h#,True)	
				
				
			End If 	
			
			
			
				
				
			
			
			
			
			
		End If 
		
		
		
		
		
	Next 
	
	
	
	
		
	;If col% = False 
	TranslateEntity bomba%, 0, -.5, 0
	
	
	UpdateWorld() 
	RenderWorld()
	
	Text 0, 0, TFormedY()
	Flip() 
	
	
	
	
Wend

Rick Nasher

(Posted 2016) [#7]

Nice. :-)

Rick Nasher

(Posted 2016) [#8]

These are meant for a meteor storm on Mars? So that the Rover needs to run away from them?

Yue	(Posted 2016) [#9]

@Rick Nasher, Yes,

If so , this is intended for meteors . if I remember correctly , it was your idea. :)

Rick Nasher

(Posted 2016) [#10]

:-D

Guy Fawkes

(Posted 2016) [#11]

; ==============================================
; FUNCTION: Crater
;(( Note - Fixed a few # ))
; ==============================================
Function crater(entity,Terrain,radius#=5,th#=10,hardness#=0.5)
	ex#=EntityX#(entity)
	ez#=EntityZ#(entity)
	For x#=-radius# To radius#
		For z#=-radius To radius#
			If Sqr(x#^2+z#^2)<=radius# And hardness#<>0
				d#=Sqr(x#*x#+z#*z#)	
				h#=TerrainHeight#(Terrain,ex+x#,ez+z#)
				scale#=th#/hardness#
				h#=h#+d#/scale#-radius#/scale#
				If h#<0 Then h#=0
				ModifyTerrain(Terrain,ex+x#,ez+z#,h#,True) 
			EndIf
		Next
	Next
End Function

Rick Nasher

(Posted 2016) [#12]

@ GF: ha, you took out my mods, making it pure again. :-)

Guy Fawkes

(Posted 2016) [#13]

LMFAO!

~GF