3d space...homeworld like..

; 3D Space Debris Demo
; By R.Baldewsingh :)
; ----------------------------
; The following code is just a simple
; demonstration of how i would create
; homeworld space. i lost my original
; code so this is a quick rewrite. I
; have used libs from others and my-
; self, many thanks! 1 thing that is
; still missing is the lensflares...
; ----------------------------

AppTitle "3D Space Demo"
Graphics3D 640,480,32,2
SetBuffer BackBuffer()
HidePointer

Include "bloom.bb"
Include "sdloader.bb"

Global PRNT%,CHILD%,CAMERA%,LIGHT%,SPHERE%,SPHERE_TEX1%,SPHERE_TEX2%
Global VEL#,MXS#,MYS#,BLURIMAGE%,BLURTEXTURE%,SW%,SH%

Global ENABLEBLUR% = 1
Global NSTR% = 1000
Global DIST% = 3000

Global FONT% = LoadFont("Tahoma",14) : SetFont(FONT%)

SpaceMapSetup_Load()   ; Initialize the DLoader
SpaceMapSetup_Create() ; Create Cam/Piv/Space Scene
SpaceDebris_Create%()  ; Setup Debris / Starfield (thankx rob)
BlurImage_Create()     ; Full Screen Motion Blur (thankx arkon)
InitGlow(CAMERA%)      ; FakeHDR (thankx naama)

While Not KeyHit(1)
	SpaceMapSetup_Update()
	SpaceDebris_Update%()
	Player_Update()
	
	If ENABLEBLUR% = 1 
		BlurImage_Update(.5)
		RenderGlow(0,5,1,1)
	Else
		RenderGlow(0,2,4,5)
	EndIf
	
	UpdateWorld
	RenderWorld
	
	Color 0,0,0
	Rect 0,0,GraphicsWidth(),40
	Rect 0,GraphicsHeight()-40,GraphicsWidth(),GraphicsHeight()
	Color 255,255,255
	Text 20,15,"3D Space Demo"
	
	If KeyHit(67) Then SaveScreenshot() ; F9

	Flip
Wend	

Function SpaceDebris_Create%()
	For I = 1 To NSTR%
		TMP% = CreateSprite()
		EntityAutoFade TMP%,DIST%/4,DIST%/2
		PositionEntity TMP%,Rnd(-DIST%,DIST%),Rnd(-DIST%,DIST%),Rnd(-DIST%,DIST%)
		EntityParent TMP%,PRNT%
	Next
End Function

Function SpaceDebris_Update%()
	For I=1 To CountChildren(PRNT%)
		CHILD% = GetChild(PRNT%,I)
		If EntityDistance(CHILD%,CAMERA%)>DIST%
			PositionEntity CHILD%,EntityX(CAMERA%),EntityY(CAMERA%),EntityZ(CAMERA%)
			RotateEntity CHILD%,EntityPitch(CAMERA%),EntityYaw(CAMERA%),0
			MoveEntity CHILD%,Rnd(-500,500),Rnd(-500,500),DIST%/2
		EndIf
	Next
End Function

Function SpaceMapSetup_Create()
	Dload_Do_Load()
	CAMERA% = CreateCamera()
	CameraRange CAMERA%,1,DIST%
	CameraFogMode CAMERA%,1
	CameraFogColor CAMERA%,0,0,0
	CameraFogRange CAMERA%,1,DIST%
	PRNT% = CreatePivot()
	
	LIGHT% = CreateLight(1,CAMERA%)
	RotateEntity LIGHT,45,0,0
	
	SPHERE% = CreateSphere(32,PRNT%)
	SPHERE_TEX1% = Dload_Get_Handle(1)
	SPHERE_TEX2% = Dload_Get_Handle(2)
	EntityTexture(SPHERE%,SPHERE_TEX2%)
	EntityTexture(SPHERE%,SPHERE_TEX1%)
	
	FlipMesh SPHERE%
	ScaleMesh SPHERE%,DIST%,DIST%,DIST%
End Function

Function SpaceMapSetup_Update()
	; Have to Add Code here that Positions Sphere in right place so cam doesnt fly out of it....
End Function

Function SpaceMapSetup_Load()
	Dload_Add_Item("gfx\neb_zero.jpg",FILE_TEX%)
	Dload_Add_Item("gfx\neb_one.jpg",FILE_TEX%)
End Function

Function Player_Update%()
	MXS#=MouseXSpeed()
	MYS#=MouseYSpeed()
	MoveMouse GraphicsWidth()/2,GraphicsHeight()/2

	If MouseDown(1)
		VEL#=VEL#+1
	EndIf
	VEL=VEL/1.05
	
	TurnEntity CAMERA%,MYS#,-MXS#,0
	MoveEntity CAMERA%,0,0,VEL#
End Function

Function BlurImage_Create()
	Local CAM% = CreateCamera()
	CameraClsMode CAM%, 0, 0
	CameraRange CAM%, 0.1, 1.5
	MoveEntity CAM%, 0, 0, 10000

	SW% = GraphicsWidth()
	SH% = GraphicsHeight()

	Local SPR%= CreateMesh(CAM%)
	Local SF% = CreateSurface(spr)
	AddVertex SF%, -1, 1, 0, 0, 0
	AddVertex SF%, 1, 1, 0, 1, 0
	AddVertex SF%, -1, -1, 0, 0, 1
	AddVertex SF%, 1, -1, 0, 1, 1
	AddTriangle SF%, 0, 1, 2
	AddTriangle SF%, 3, 2, 1
	EntityFX SPR%, 17
	ScaleEntity SPR%, 1024.0 / Float(SW%), 1024.0 / Float(SW%), 1
	PositionEntity SPR%, 0, 0, 1.0001
	EntityOrder SPR%, -100000
	EntityBlend SPR%, 1
	BLURIMAGE% = SPR%

	BLURTEXTURE% = CreateTexture(1024, 1024, 256)
	EntityTexture SPR%, BLURTEXTURE%
End Function

Function BlurImage_Update(POWER#)
	EntityAlpha BLURIMAGE%, POWER#
	CopyRect  SW% / 2 - 512, SH% / 2 - 512, 1024, 1024, 0, 0, BackBuffer(), TextureBuffer(BLURTEXTURE%)	
End Function

Function SaveScreenshot()
    iFileNumber% = 0
    Repeat
        iFileNumber = iFileNumber + 1
        sFileName$ = "Screenshot" + String$("0", 3 - Len(Str$(iFileNumber))) + iFileNumber + ".bmp"
    Until Not(FileType(sFileName))   
    SaveBuffer FrontBuffer(), sFileName
End Function