Size of taskbar

Blitz3D Forums/Blitz3D Programming/Size of taskbar

Virtech

(Posted 2009) [#1]

Hi

Is it somehow possible to get the current size (width & height) of the taskbar from blitz3d, using some decls magic?

BlitzSupport

(Posted 2009) [#2]

Here you go...

; ------------------------------------------------------------------------------
; Taskbar size/location functions:
; ------------------------------------------------------------------------------

; TaskBarX ()
; TaskBarY ()
; TaskBarWidth ()
; TaskBarHeight ()

; ------------------------------------------------------------------------------
; Function template for shell32.decls
; ------------------------------------------------------------------------------
; .lib "shell32.dll"
; SHAppBarMessage% (msg, apb*)
; ------------------------------------------------------------------------------
;
; Create a plain text file called shell32.decls inside Blitz3D\Userlibs and
; add the above two lines, minus the comment symbol.
;
; If shell32.decls already exists, just add the SHAppBarMessage definition if
; it's not already there.
; ------------------------------------------------------------------------------



; ------------------------------------------------------------------------------
; Types...
; ------------------------------------------------------------------------------

; Weird field names due to conflicts between correct names and Blitz keywords!

Type AppBarData

	Field cbSize
    Field hWnd
    Field uCallbackMessage
    Field uEdge

	; RECT structure made inline...
	
	Field lLeft
	Field tTop
	Field rRight
	Field bBottom

    Field lParam

End Type

; ------------------------------------------------------------------------------
; Constants...
; ------------------------------------------------------------------------------

Const APB_X = 1
Const APB_Y = 2
Const APB_WIDTH = 3
Const APB_HEIGHT = 4

; ------------------------------------------------------------------------------
; Internal function used by TaskBarX/Y, etc...
; ------------------------------------------------------------------------------

Function TaskBarInfo_Internal (value)

	; Message value to pass to function...
	
	ABM_GETTASKBARPOS = 5
	
	; Size of AppBarData structure...
	
	APBSize = (9 * 4) ; 9 fields of 4 bytes
	
	; Create AppBarData object...
	
	apb.AppBarData = New AppBarData

	; Got to set structure size and a window before calling...
	
	apb\cbSize = APBSize
	apb\hWnd = 0

	; Get taskbar information...
		
	SHAppBarMessage (ABM_GETTASKBARPOS, apb)

	; Return requested value...
	
	Select value
		Case APB_X
			Return apb\lLeft
		Case APB_Y
			Return apb\tTop
		Case APB_WIDTH
			Return apb\rRight - apb\lLeft
		Case APB_HEIGHT
			Return apb\bBottom - apb\tTop
		Default
			DebugLog "Invalid value passed! Don't call this directly! Now go to your room."
	End Select

End Function

; ------------------------------------------------------------------------------
; The functions to call...
; ------------------------------------------------------------------------------

Function TaskBarX ()
	Return TaskBarInfo_Internal (APB_X)
End Function

Function TaskBarY ()
	Return TaskBarInfo_Internal (APB_Y)
End Function

Function TaskBarWidth ()
	Return TaskBarInfo_Internal (APB_WIDTH)
End Function

Function TaskBarHeight ()
	Return TaskBarInfo_Internal (APB_HEIGHT)
End Function

; ------------------------------------------------------------------------------
; Copy and paste ALL of the above at the top of your code!
; ------------------------------------------------------------------------------

; ------------------------------------------------------------------------------
; D e m o . . .
; ------------------------------------------------------------------------------

Graphics 640, 480, 0, 2
SetBuffer BackBuffer ()

Repeat

	Cls
	
	Text 20, 20, "Taskbar position:"
	Text 20, 60, "X: " + TaskBarX ()
	Text 20, 80, "Y: " + TaskBarY ()
	Text 20, 100, "Width: " + TaskBarWidth ()
	Text 20, 120, "Height: " + TaskBarHeight ()
	
	; Large delay needed in demo as it causes weird problems when trying to
	; move the taskbar!
	
	Delay 100
	
	Flip
	
Until KeyHit (1)

End

Run the demo after adding the .decls stuff to your userlibs, and try dragging the taskbar around to different locations -- it updates in real time. (You might have to unlock the taskbar first of course.)

Virtech

(Posted 2009) [#3]

This is exactly what I was looking for + the missing bits I forgot about...x,y coords ;)

Works great on xp, havent had a chance to try vista. Maybe someone else can confirm?

Thanks! :)

Nate the Great

(Posted 2009) [#4]

wow a nifty little program! maybe it will be of some use some day... although im not sure why you would ever need to know where the task bar is for a game :D

Adam Novagen

(Posted 2009) [#5]

Desktop interactivity, I'll bet; let the player fight a war on his/her own computer front! 8)

John Blackledge

(Posted 2009) [#6]

Nice.
James, how do you get the colour? (If a Blitz program wanted to duplicate the task bar look)

Virtech

(Posted 2009) [#7]

The reason I needed this is that I want to start my blitz application in widowed mode=desktop size, but I still want the taskbar to be visible.

BlitzSupport

(Posted 2009) [#8]

John, that would be trickier, since most people will have a themed taskbar (XP/Vista), so it's not just one colour. (I tried getting the list of system colours for non-themed desktops, but it was failing for some reason.)

I just found the XP Theme functions, though, which apparently should let me retrieve the bitmaps for each part of a window, menu, taskbar, etc, so I'll be fiddling with that anyway.

John Blackledge

(Posted 2009) [#9]

James,

I dug out some very old C code of mine - might useful to someone:

	crBackClr = GetSysColor(COLOR_ACTIVECAPTION);
	crTextClr = GetSysColor(COLOR_CAPTIONTEXT);
	backr = GetRValue(crBackClr);
	backg = GetGValue(crBackClr);
	backb = GetBValue(crBackClr);
	highr = min(255,backr*1.5);
	highg = min(255,backg*1.5);
	highb = min(255,backb*1.5);
	shadr = backr*.5;
	shadg = backg*.5;
	shadb = backb*.5;
	textr = GetRValue(crTextClr);
	textg = GetGValue(crTextClr);
	textb = GetBValue(crTextClr);