Camera movement not in sync with player

Blitz3D Forums/Blitz3D Programming/Camera movement not in sync with player

A51M15X

(Posted 2010) [#1]

Whenever I move around the camera moves at a different rate than the player. This causes the movement to get out of sync. I'm still pretty new at this so any help is much appreciated.


While Not KeyDown(1)


PositionEntity player, x#, y#, z#
;PositionEntity camera, x#, y#, z#

	x#=x#+xspeed#
	z#=z#+zspeed#
	;y#=y#+.2

	xspeed#=xspeed#*.90
	zspeed#=zspeed#*.90

forward=KeyDown(17)
back=KeyDown(31)
moveleft=KeyDown(30)
moveright=KeyDown(32)
mouse1=MouseHit(1)
mouse2=MouseHit(2)
space=KeyDown(57)

If forward Then zspeed#=zspeed#+.5
If back Then zspeed#=zspeed#-.5
If moveleft Then xspeed#=xspeed#-.5
If moveright Then xspeed#=xspeed#+.5
If space Then y#=y#+1

h# = h# + MouseXSpeed()/6.0
g# = g# + MouseYSpeed()/6.0

If g < -80 Then g = -80
If g > 80 Then g = 80

RotateEntity camera, g, 0, 0
RotateEntity player, 0, -h, 0

MoveMouse GraphicsWidth()/2, GraphicsHeight()/2

UpdateWorld()

RenderWorld()

Flip
Wend
End

Yes, I know i still have to fix the y# movement, but i'd like to fix the camera thing first.

Oiduts Studios

(Posted 2010) [#2]

Well before anyone looks at the code they will probably tell you to pivot the camera around the player instead of repositioning it manually.

A51M15X

(Posted 2010) [#3]

What do you mean?

This is what I have:

player = CreatePivot()
camera = CreateCamera(player)

lo-tekk

(Posted 2010) [#4]

This should work better, look into the UpdateGame() function:

Graphics3D 800,600

Global light=CreateLight()
Global player=CreatePivot()
Global Camera=CreateCamera(player)
Global plane=CreatePlane()

Global tex=CreateTexture(256,256)

SetBuffer TextureBuffer(tex)

For j=0 To 255 Step 32
	For k=0 To 255 Step 32
		
		Color Rnd(10,200),Rnd(10,200),Rnd(10,200)
		
		Rect j,k,32,32
		
	Next
Next

SetBuffer BackBuffer()

EntityTexture plane,tex

ScaleTexture tex,4,4

PositionEntity plane,0,-5,0

Const GameUPS=60 ; Updates per second
Local Period=1000/GameUPS 
Local FrameTime=MilliSecs()-Period

Local Tween#, Ticks,i,Remaining,StartTime,Elapsed

While Not KeyHit(1)
	
	StartTime = MilliSecs()
	
	Repeat
		Elapsed=MilliSecs()-FrameTime
	Until Elapsed
	
	Ticks=Elapsed / Period
	Tween=Float(Elapsed Mod Period)/Float(Period)
	
	For i=1 To Ticks
		FrameTime=FrameTime+Period
		If i=Ticks Then
			CaptureWorld
		End If
		UpdateGame()
		UpdateWorld
	Next
	RenderWorld Tween
	
	Remaining = Period - (MilliSecs() - StartTime)
	If Remaining > 1 Then 
		Delay (Remaining-1) ; Free some CPU time
	End If
	
	Flip
	
Wend

End

Global y#,xspeed#,zspeed#,h#,g#
Global forward,back,moveleft,moveright,mouse1,mouse2,space

Function UpdateGame()


	xspeed#=xspeed#*.90
	zspeed#=zspeed#*.90
	y#=y#*.90
	
	forward=KeyDown(17)
	back=KeyDown(31)
	moveleft=KeyDown(30)
	moveright=KeyDown(32)
	mouse1=MouseHit(1)
	mouse2=MouseHit(2)
	space=KeyDown(57)
	
	If forward Then zspeed#=zspeed#+.05
	If back Then zspeed#=zspeed#-.05
	If moveleft Then xspeed#=xspeed#-.05
	If moveright Then xspeed#=xspeed#+.05
	If space Then y#=y#+.05
	
	h# = h# + MouseXSpeed()/6.0
	g# = g# + MouseYSpeed()/6.0
	
	If g < -80 Then g = -80
	If g > 80 Then g = 80
	
	TranslateEntity player,xspeed#,y#,zspeed#
	
	RotateEntity Camera, g, 0, 0
	RotateEntity player, 0, -h, 0
	
	MoveMouse GraphicsWidth()/2, GraphicsHeight()/2
	
End Function