[Solved] TRamStream - Creating a textfile in memory?

BlitzMax Forums/BlitzMax Beginners Area/[Solved] TRamStream - Creating a textfile in memory?

Grisu

(Posted May) [#1]

Hello guys!

I want to write a textfile to a zip archive.

But doing this I don't want to write it to the HDD/SDD first and then zip it later. Instead I would like to create a simple textfile as filebuffer / TRamStream object and zip it directly. Should be much faster.

Can someone give me a simple example on how to add multiple strings to a filebuffer?

Something like this doesn't work:

Local zipfileBuffer:TRamStream 
WriteLine zipfileBuffer, "This is String #1"
WriteLine zipfileBuffer, zipfileBuffer+"This is String #2 added"

Grisu

degac

(Posted May) [#2]

At the moment I'm not on my computer, but I suppose you need to Create a RamStream before using it, not sure!

BlitzSupport

(Posted May) [#3]

Can't check right now, but think it will be something like:

Local zipfileBuffer:TRamStream 

zipfileBuffer = CreateStream () ' Or WriteStream (zipfileBuffer)?

if zipfileBuffer

WriteLine zipfileBuffer, "This is String #1"
WriteLine zipfileBuffer, "This is String #2 added" ' DOn't try to use zipfileBuffer as a string!

CloseStream zipfileBuffer

Endif

Grisu

(Posted May) [#4]

Thanks.

Getting closer, after some more goggeling. :)

Still need to test, if this works with the zip module.

SuperStrict
Import BRL.RamStream

Type TDynRamStream Extends TRamStream
	Const RAM_DOUBLER:Float = 1.5
	
	Field _max:Int
	
	'NOTE: @buf must either be Null or allocated by MemAlloc or MemExtend
	Function Create:TDynRamStream( buf:Byte Ptr, maxsize:Int, readable:Int, writeable:Int)
		Local stream:TDynRamStream = New TDynRamStream
		stream._buf = buf
		stream._max = maxsize
		If Not buf And maxsize > 0 Then
			stream._buf = MemAlloc(maxsize)
		EndIf
		stream._read = readable
		stream._write = writeable
		Return stream
	EndFunction
	
	Method Write:Int( buf:Byte Ptr, count:Int)
		If count <= 0 Or Not _write Then Return 0
		If _max <= 0 Then
			_max = count * RAM_DOUBLER
			_buf = MemAlloc(_max)
		ElseIf _pos + count > _max Then
			Local newsz:Int = (_pos + count) * RAM_DOUBLER
			_buf = MemExtend( _buf, _max, newsz)
			_max = newsz
		EndIf
		MemCopy _buf + _pos, buf, count
		_pos :+ count
		_size :+ count
		Return count
	EndMethod
	
	Method Close()
		If _buf Then MemFree(_buf)
		_buf = Null
		_pos = 0
		_size = 0
		_max = 0
	EndMethod
EndType

Print "write"

Local stream:TRamStream = TDynRamStream.Create( Null, 0, 1, 1)
stream.WriteString "Hello World #1"+Chr(10)
stream.WriteString "Hello World #2"+Chr(10)
stream.WriteString "Hello World #3"+Chr(10)
stream.WriteString "Hello World #4"+Chr(10)

Print "read"
stream.Seek(0)
While Not stream.Eof()
	Print stream.ReadLine()
Wend

stream.Close()

Grisu

(Posted May) [#5]

Works perfectly. Sometimes you just need a friendly slap in the face to get you back on track. :)

Thanks again!