Unfilled ovals?

BlitzMax Forums/BlitzMax Beginners Area/Unfilled ovals?

Who was John Galt?

(Posted 2004) [#1]

How to? Some bright spark recently posted a method on these boards, now I can't find it for the life of me.

TeaVirus

(Posted 2004) [#2]

http://www.blitzbasic.com/Community/posts.php?topic=41793

fredborg

(Posted 2004) [#3]

Graphics 640,480,0
	
While Not KeyHit(KEY_ESCAPE)
	DrawOvalUnfilled Rand(0,640),Rand(0,480),Rand(10,100),Rand(10,100)
	Flip
	FlushMem
Wend
End
	
Function DrawOvalUnfilled( x0#,y0#,w#,h# )
	
	Local xr#=(w)*.5
	Local yr#=(h)*.5
	Local segs=Abs(xr)+Abs(yr)
		
	segs=Max(segs,12)&~3

	x0:+xr
	y0:+yr

	Local px#,py#
					
	glBegin GL_LINES
	For Local i=0 Until segs+1
		Local th#=i*360#/segs
		Local x#=x0+Cos(th)*xr
		Local y#=y0-Sin(th)*yr
		If i>0
			glVertex2f px,py
			glVertex2f x,y
		EndIf
		px# = x
		py# = y
	Next
	glEnd
	
End Function

Who was John Galt?

(Posted 2004) [#4]

Ta very much guys!

EOF	(Posted 2004) [#5]

Another way:

Graphics 400,300,0

' outlined
glPolygonMode(GL_FRONT, GL_LINE)
SetColor 200,0,0
DrawOval 80,60,70,80

' filled
glPolygonMode(GL_FRONT, GL_FILL)
SetColor 0,200,0
DrawOval 230,90,70,80

' dotted
glPolygonMode(GL_FRONT, GL_POINT)
SetColor 0,0,200
DrawOval 160,180,70,80

Flip
WaitKey
End

It would be nice if max had a SetDrawMode in a similar way to how SetBlend works.

Who was John Galt?

(Posted 2004) [#6]

Ah like that method Jim.

LeisureSuitLurie

(Posted 2004) [#7]

Now if you can come up with one for Arcs...