calendar control

BlitzMax Forums/BlitzMax Beginners Area/calendar control

r	(Posted 2009) [#1]

Hello,
is possible to have the windows calendar control/calendar combo and date/time editor ?
Maybe with the direct use of comctrl32.dll ?

Beaker

(Posted 2009) [#2]

It is possible, but you would have to code it yourself. Or use wxMax?

jsp	(Posted 2009) [#3]

Or maybe try degac's calender gadget (MaxGui ProxyGadget):
http://www.blitzbasic.com/Community/posts.php?topic=85151#962708
Should be cross-platform.

xlsior

(Posted 2009) [#4]

Degac's is nice, but personally I'd still be interested in finding out how to use the native windows control as well...

r	(Posted 2009) [#5]

Somebody can help me ?

I try that :

Import MaxGUI.drivers

Extern "win32"
Function GetModuleHandle:Int(lpmodulehandlename:Byte Ptr)="GetModuleHandleW@4"
Function CreateWindowEx:Int(dwexstyle:Int,lpclassname:Byte Ptr,lpwindowname:Byte Ptr, dwstyle:Int,x:Int,y:Int,w:Int,h:Int,hwndparent:Int,hmenu:Int,hinstance:Int,lpparam:Int)="CreateWindowExW@48"
Function InitCommonControlsEx(lp:Byte Ptr)="InitCommonControlsEx@4"
End Extern

Type _initcommoncontrolsex
Field dwsize:Int
Field dwlicc:Int
End Type

Const icc_date_classes=256
Const ws_child=1073741824
Const ws_visible=268435456
Const ws_border=8388608

Local icex:_initcommoncontrolsex
icex.dwsize=SizeOf(icex)
icex.dwlicc=icc_date_classes
'
initcommoncontrolsex(Varptr(icex))

Global window0:TGadget = CreateWindow:TGadget("calendar",207,48,300,300,Null,WINDOW_TITLEBAR|WINDOW_MENU |WINDOW_STATUS |WINDOW_CLIENTCOORDS|window_center )

createwindowex(0,"SysMonthCal32","",ws_child & ws_visible & ws_border,0,0,200,200,HandleFromObject(window0),0,getmodulehandle(Null),0)

Repeat
	WaitEvent()
	Select EventID()
Case EVENT_WINDOWCLOSE
			Select EventSource()
				Case window0 close()
				
			End Select
	End Select
Forever

Function close()
End
EndFunction

but that don't work.
Any idea ????

EOF	(Posted 2009) [#6]

This modifed version shows the calender
I had to change a few things in your code. One of the main ones being:

="CreateWindowExW@48" to ="CreateWindowExA@48"

The other being:

InitCommonControlsEx(Varptr (icex)) to InitCommonControlsEx(Byte Ptr (icex))

Framework brl.blitz

Import MaxGUI.drivers
Import brl.eventqueue
'Import "-lcomctl32"

Extern "win32"
	Function GetModuleHandle:Int (lpmodulehandlename:Byte Ptr)="GetModuleHandleW@4"
	Function CreateWindowEx:Int (dwExstyle:Int,lpclassname:Byte Ptr,lpwindowname:Byte Ptr, dwStyle:Int,x:Int,y:Int,w:Int,h:Int,hwndparent:Int,hmenu:Int,hinstance:Int,lpparam:Int)="CreateWindowExA@48"
	Function InitCommonControlsEx:Int (lp:Byte Ptr)="InitCommonControlsEx@4"
End Extern

Type _initcommoncontrolsex
	Field dwsize:Int
	Field dwlicc:Int
End Type

Const ICC_LISTVIEW_CLASSES = $1 ' listview, header 
Const ICC_TREEVIEW_CLASSES = $2' treeview, tooltips 
Const ICC_BAR_CLASSES = $4 ' toolbar, statusbar, trackbar, tooltips 
Const ICC_TAB_CLASSES = $8' tab, tooltips 
Const ICC_UPDOWN_CLASS = $10 ' updown 
Const ICC_PROGRESS_CLASS = $20 ' progress 
Const ICC_HOTKEY_CLASS = $40 ' hotkey 
Const ICC_ANIMATE_CLASS = $80 ' animate 
Const ICC_WIN95_CLASSES = $FF' loads everything above 
Const ICC_DATE_CLASSES = $100' month picker, date picker, time picker, updown 
Const ICC_USEREX_CLASSES = $200' comboEx 
Const ICC_COOL_CLASSES = $400' rebar (coolbar) control 

Const WS_CHILD%=$40000000
Const WS_VISIBLE%=$10000000
Const WS_BORDER%=$800000

Global icex:_initcommoncontrolsex=New _initcommoncontrolsex
icex.dwsize=SizeOf(icex)
icex.dwlicc=ICC_DATE_CLASSES
'
DebugLog InitCommonControlsEx(Byte Ptr (icex))

Global window0:TGadget = CreateWindow:TGadget("calendar",207,48,300,300,Null,WINDOW_TITLEBAR|WINDOW_MENU |WINDOW_STATUS |WINDOW_CLIENTCOORDS|window_center )

DebugLog CreateWindowEx(0,"SysMonthCal32","Cal",WS_CHILD|WS_VISIBLE|WS_BORDER,0,0,200,200,QueryGadget(window0,QUERY_HWND),Null,GetModuleHandle(Null),Null)

Repeat
	WaitEvent()
	Select EventID()
		Case EVENT_WINDOWCLOSE
		Select EventSource()
			Case window0 close()	
		End Select
	End Select
Forever

Function close()
End
EndFunction

r	(Posted 2009) [#7]

I have a calendar !

Thx to jim brown

how to interact with ? Receive event ?
I can't send message to change date...

Framework brl.blitz

Import MaxGUI.drivers
Import brl.eventqueue

Extern "win32"
	Function GetModuleHandle:Int (lpmodulehandlename:Byte Ptr)="GetModuleHandleA@4"
	Function CreateWindowEx:Int (dwExstyle:Int,lpclassname:Byte Ptr,lpwindowname:Byte Ptr, dwStyle:Int,x:Int,y:Int,w:Int,h:Int,hwndparent:Int,hmenu:Int,hinstance:Int,lpparam:Int)="CreateWindowExA@48"
	Function InitCommonControlsEx:Int (lp:Byte Ptr)="InitCommonControlsEx@4"
	Function SendMessage:Int(hwnd:Int,mess:Int,wparam:Int,lparam:Int)="SendMessageA@16"
End Extern

Type _initcommoncontrolsex
	Field dwsize:Int
	Field dwlicc:Int
End Type

Type _systemtime
	Field year,month,dayofweek,day,hour,minute,second,milliseconds:Short
EndType

Const ICC_LISTVIEW_CLASSES = $1 ' listview, header 
Const ICC_TREEVIEW_CLASSES = $2' treeview, tooltips 
Const ICC_BAR_CLASSES = $4 ' toolbar, statusbar, trackbar, tooltips 
Const ICC_TAB_CLASSES = $8' tab, tooltips 
Const ICC_UPDOWN_CLASS = $10 ' updown 
Const ICC_PROGRESS_CLASS = $20 ' progress 
Const ICC_HOTKEY_CLASS = $40 ' hotkey 
Const ICC_ANIMATE_CLASS = $80 ' animate 
Const ICC_WIN95_CLASSES = $FF' loads everything above 
Const ICC_DATE_CLASSES = $100' month picker, date picker, time picker, updown 
Const ICC_USEREX_CLASSES = $200' comboEx 
Const ICC_COOL_CLASSES = $400' rebar (coolbar) control 
'
Const WS_CHILD%=$40000000
Const WS_VISIBLE%=$10000000
Const WS_BORDER%=$800000
Const MCM_SETTODAY=$1000+$C
Const MCM_SETCURSEL=$1000+$2
'
Global icex:_initcommoncontrolsex=New _initcommoncontrolsex
icex.dwsize=SizeOf(icex)
icex.dwlicc=ICC_DATE_CLASSES
'

Global window0:TGadget = CreateWindow:TGadget("calendar",207,48,300,300,Null,WINDOW_TITLEBAR|WINDOW_MENU |WINDOW_STATUS |WINDOW_CLIENTCOORDS|window_center )
InitCommonControlsEx(Byte Ptr icex)

Local calend:Int= CreateWindowEx(0,"SysMonthCal32","Cal",WS_CHILD|WS_VISIBLE|WS_BORDER,10,10,200,200,QueryGadget(window0,QUERY_HWND_client),Null,GetModuleHandle(Null),Null)
Local st:_systemtime=New _systemtime
st.year=2009
st.day=7
st.dayofweek=0
st.month=7
'
sendmessage(calend,MCM_Setcursel,0,Int(Byte Ptr st)) ' don't work

Repeat
	WaitEvent()
	Select EventID()
		Case EVENT_WINDOWCLOSE
		Select EventSource()
			Case window0 close()	
		End Select
	End Select
Forever

Function close()
End
EndFunction

EOF	(Posted 2009) [#8]

Your undefined variables in _systemtime are INT by default
Change as follows to fix the SendMessage call to change the date

Type _systemtime
	Field year:Short,month:Short,dayofweek:Short,day:Short
	Field hour:Short,minute:Short,second:Short,milliseconds:Short
EndType

I have no time at the moment to look at the event side of things though