Help with SetConsoleCursorPosition

BlitzMax Forums/BlitzMax Beginners Area/Help with SetConsoleCursorPosition

Hezkore

(Posted 2009) [#1]

Right, so I'm trying to use SetConsoleCursorPosition to set the cursors position in my console window.

Extern "Win32"
	Function SetConsoleCursorPosition(hbuffOUT%, xyCoord:Byte Ptr)
End Extern

SetConsoleCursorPosition(stdOUT, Byte Ptr(10)) DOES work but I can only set its X position, how would I set its Y position?

plash

(Posted 2009) [#2]

Try something like this (data types might need to be changed):

Type TCoord
	Field x:Short
	Field y:Short
	
	Method Set(_x:Short, _y:Short)
		
		x = _x
		y = _y
		
	End Method
	
End Type

Local coord:TCoord = New TCoord

coord.Set(10, 5)
SetConsoleCursorPosition(stdOUT, coord)

Hezkore

(Posted 2009) [#3]

That was what I first tried but it just doesn't work :/

Extern "Win32"
	Function GetStdHandle:Int(nStdHandle:Int)
	Function SetConsoleCursorPosition(hbuffOUT%, xyCoord:Byte Ptr)
End Extern

Type TCoord
	Field x:Short
	Field y:Short
	
	Method Set(_x:Short, _y:Short)
		x = _x
		y = _y
	End Method
End Type

Local stdOUT% = GetStdHandle(- 11)
Local coord:TCoord = New TCoord
coord.Set(5, 10)
SetConsoleCursorPosition(stdOUT, coord)

Print("Testing!")
Delay 1000

Setting xyCoord:Byte Ptr to xyCoord:TCoord does not help either.

plash

(Posted 2009) [#4]

Hmm, arrays aren't working either.

Hezkore

(Posted 2009) [#5]

Yeah tried that too, heh...
Feels like I've tried everything. x_X

grable

(Posted 2009) [#6]

COORD should not be a pointer, it is copied by value in c.. so treat it as an Int in stead.

Extern "Win32"
	Function SetConsoleCursorPosition( hbuffOUT%, coord:Int)
EndExtern

Function MakeCoord:Int( x:Int, y:Int)
	Return y Shl 16 | x
EndFunction

SetConsoleCursorPosition( stdout, MakeCoord(70,20))
WriteStdOut "it works!"

Hezkore

(Posted 2009) [#7]

Cheers mate, you've saved me heh.

plash

(Posted 2009) [#8]

Doesn't work for me.

EDIT: Doh! 'Strict' is evil. Works a treat!

EOF	(Posted 2009) [#9]

I have a (almost) complete Console Control library here if you are interested
It has functionality to clear the screen, change fore/back colours, write text anywhere in the screen, and accept user input

DEMO #1

Strict
Framework brl.blitz
Import "ConsoleControl.bmx"

Console.Open "CLS test"
For Local clr%=1 To $80
	Console.SetColorAttr clr
	Console.WriteLine "Testing attribute color ["+String(clr)+"]"
Next
Console.SetColor WHITE,BLUE
Console.WaitReturn
Console.SetColor YELLOW,RED
Console.Cls
Console.Write "Final line written"
Delay 1000

End

DEMO #2

Strict
Framework brl.blitz
Import "ConsoleControl.bmx"

Console.Open
'Console.CreateScreenBuffer
Console.SetTitle "Console - Input test"
Console.SetColor WHITE,BLUE

Console.WriteLine "   OO    OO   O    O   OOO    OO   O     OOOO"
Console.WriteLine "  O     O  O  OO   O  O      O  O  O     O   "
Console.WriteLine "  O     O  O  O O  O  O      O  O  O     O   "
Console.WriteLine "  O     O  O  O O  O   OOO   O  O  O     OOO "
Console.WriteLine "  O     O  O  O  O O      O  O  O  O     O   "
Console.WriteLine "  O     O  O  O   OO      O  O  O  O     O   "
Console.WriteLine "   OO    OO   O    O   OOO    OO   OOOO  OOOO"

Console.SetColor GREY,BLACK
Console.SetCursorPos 0,10
Local name$=Console.Input("Your name? >")
Console.SetColor BLACK,DYELLOW
Console.Cls
Console.SetCursorPos 4,14
Local t$=Console.Input("Hello ~q"+name+"~q enter some random text >")
Console.write name+", Text written was '"+t+"'"
Console.WaitReturn
Console.Close
End

CONSOLECONTROL.bmx

Rem
	Title: ConsoleControl v0.01
	Author: Jim Brown
EndRem

Strict

Const BLACK = 0
Const DBLUE = 1
Const DGREEN = 2
Const DRED = 4
Const INTENSITY = 8
Const DYELLOW = DRED+DGREEN
Const DCYAN = DGREEN+DBLUE
Const DPURPLE = DRED+DBLUE
Const BLUE = DBLUE+INTENSITY
Const GREEN = DGREEN+INTENSITY
Const RED = DRED+INTENSITY
Const WHITE = DBLUE+DGREEN+DRED+INTENSITY
Const GREY = DBLUE+DGREEN+DRED
Const YELLOW = DGREEN+DRED+INTENSITY
Const CYAN = DGREEN+DBLUE+INTENSITY
Const PURPLE = DRED+DBLUE+INTENSITY


Extern "Win32"
	Function WriteConsoleW%(hnd%,lpBuff$w,NChars%,NCharsWritten:Int Ptr,Reserved%)
	Function AllocConsole%()
	Function FreeConsole()
	Function CreateConsoleScreenBuffer%(Access%,ShareMode%,secAttr:Byte Ptr,Flags%,Reserved%)
	Function SetConsoleActiveScreenBuffer(hScreenBuff%)
	Function SetStdHandle(tpy%,hnd%)
	Function GetStdHandle(tpy%)
	Function SetConsoleTitleW(title$w)
	Function SetConsoleCursorPosition(hbuffOUT%,xyPos%)
	Function FillConsoleOutputCharacterW%(hbuffOUT%,char%,numChars%,xyPos%,nCharsWritten:Int Ptr)
	Function FillConsoleOutputAttribute%(hbuffOUT%,attr%,numChars%,xyPos%,nCharsWritten:Int Ptr)
	Function GetConsoleScreenBufferInfo(hbuffOUT%,tCONSOLEINFO:Byte Ptr)
	Function SetConsoleTextAttribute(hbuffOUT%,attr%)
	Function FlushConsoleInputBuffer(hbuffIN%)
	Function ReadConsoleA(hbuffIN%,lBuffAddr:Byte Ptr,numCharsToRead%,nCharsRead:Int Ptr,Reserved%)
	Function ReadConsoleW(hbuffIN%,lBuffAddr:Byte Ptr,numCharsToRead%,nCharsRead:Int Ptr,Reserved%)
	Function PeekConsoleInput(hbuffIN%,lpBuffer:Long Ptr,Length%,numEventsRead%)
	Function ReadConsoleOutputW(hbuffOUT%,lBuffAddr:Byte Ptr,xypos%,buffCoord%,sRect:Int Ptr)
	Function ReadConsoleOutputCharacterA(hbuffOUT%,lBuffAddr:Byte Ptr,numCharsToRead%,buffCoord%,nCharsRead:Int Ptr)
End Extern


Type Console
	Const STD_INPUT_HANDLE% = -10
	Const STD_OUTPUT_HANDLE% = -11
	Global hnd% , stdOUT% , stdIN% , ForeColor%,BackColor%
	Global Width%,Height%
	Global sbinfo:ConsoleScreenBufferInfo=New ConsoleScreenBufferInfo
	'
	Function Open(title$="ConsoleControl Window")
		Assert Console.hnd=Null,"Console already open!"
		Console.hnd=AllocConsole()
		Assert Console.hnd,"Console failed to open"
		Console.ForeColor=7 ; Console.BackColor=0
		Console.stdOUT=GetStdHandle(Console.STD_OUTPUT_HANDLE)
		Console.stdIN=GetStdHandle(Console.STD_INPUT_HANDLE)
		Assert Console.stdOUT,"Failed to get console screen OUT buffer"
		Assert Console.stdIN,"Failed to get console screen IN buffer"
		GetConsoleScreenBufferInfo Console.stdOUT,Console.sbinfo
		Console.Width=Console.sbinfo.numCols ; Console.Height=Console.sbinfo.numRows
		Console.Cls
		Console.SetTitle title
	End Function
	'
	Function CreateScreenBuffer%()
		Const GEN_READ=$80000000 , GEN_WRITE=$40000000
		Local hndSB%=CreateConsoleScreenBuffer(GEN_READ+GEN_WRITE, 1+2,Null,1,Null)
		SetConsoleActiveScreenBuffer hndSB
		SetStdHandle Console.STD_OUTPUT_HANDLE,hndSB
		Console.stdOUT=GetStdHandle(Console.STD_OUTPUT_HANDLE)
		Console.stdIN=GetStdHandle(Console.STD_INPUT_HANDLE)
		Return hndSB
	End Function
	'
	Function Close()
		Assert Console.hnd,"No Console to 'close'"
		FreeConsole() ; Console.hnd=Null
		Console.stdOUT=0 ; Console.stdIN=0
		Console.Width=0 ; Console.Height=0
	End Function
	'
	Function SetCursorPos(x%,y%)
		SetConsoleCursorPosition Console.stdOUT, (y Shl 16) + x
	End Function
	'
	Function GetCursorPos(x% Var,y% Var)
		GetConsoleScreenBufferInfo Console.stdOUT,Console.sbinfo
		x=Console.sbinfo.CursorXPos ; y=Console.sbinfo.CursorYPos
	End Function
	'
	Function Write(txt$)
		Assert Console.hnd,"Console not open - Unable to write text"
		WriteConsoleW Console.stdOUT,txt,txt.Length,Null,0
	End Function
	'
	Function WriteLine(l$)
		Console.Write l$+Chr(10)	
	End Function
	'
	Function Read$(x%,y%,numChars%=1)
		Local inp:Byte[numChars] ' space for character(s) to read
		Local ncr% ' storage variable for number of chars actually read
		DebugLog "R="+ReadConsoleOutputCharacterA(Console.stdOUT%,Varptr(inp[0]),numChars,(y Shl 16) + x, Varptr(ncr))
		DebugLog inp[0]
		Return String.FromCString(inp).Trim()
	End Function
	'
	Function ReadLine$(yPos%)
		Return Console.Read(0,yPos,Console.Width)
	End Function
	'
	Function Cls()
		Local sz%=Console.Width*Console.Height
		FillConsoleOutputCharacterW Console.stdOUT,32,sz,0,Null
		FillConsoleOutputAttribute Console.stdOUT,Console.BackColor*16,sz,0,Null
		SetConsoleCursorPosition Console.stdOUT,0
	End Function
	'
	Function SetColor(fore%,back%=-1)
		If back=-1 Then back=Console.BackColor
		If fore=-1 Then fore=Console.ForeColor
		SetConsoleTextAttribute Console.stdOUT,fore+(back*16)
		Console.ForeColor=fore ; Console.BackColor=back
	End Function
	'
	Function SetColorAttr(index%)
		If index<0 Or index%>128 Then Return
		SetConsoleTextAttribute Console.stdOUT,index
	End Function
	'
	Function WaitReturn()
		Console.SetColor GREY
		Console.WriteLine "~nPress RETURN .."
		FlushConsoleInputBuffer Console.StdIN
		ReadConsoleA Console.StdIN,Null,1,Null,0
	End Function
	'
	Function Input$(defprompt$="> ")
		Local inp:Byte[16384]
		Local ncr% ' storage variable for number of chars actually read
		Console.Write defprompt$
		FlushConsoleInputBuffer Console.StdIN
		ReadConsoleA(Console.StdIN,Varptr(inp[0]),inp.Length,Varptr(ncr),Null)
		Local rs$=String.FromCString(inp)
		If rs.Length<=2 Then Return "" ' user pressed RETURN only
		Return String(rs[..rs.Length-2]) ' strip RETURN and NULL characters
	End Function
	'
	Function SetTitle(newtitle$)
		SetConsoleTitleW newtitle$
	End Function
	'
End Type

Type ConsoleScreenBufferInfo
	Field numCols:Short , numRows:Short
	Field CursorXPos:Short,CursorYPos:Short
	Field Attrs:Short
    	Field sbuffL:Short,sbuffT:Short,sbuffR:Short,sbuffB:Short
	Field MaxWinXSize:Short,MaxWinYSize:Short
End Type

Type tCoord
	Field x%,y%
End Type

Hezkore

(Posted 2009) [#10]

Hey thanks Jim Brown (and everyone else) I might use this if I'm allowed. :3

EOF	(Posted 2009) [#11]

Sure

GW	(Posted 2009) [#12]

This is pretty nice Jim!
looking over the code, where are you getting the hwnd of the console window?

EOF	(Posted 2009) [#13]

Thanks
The console window is 'handle' based. The following line retains the handle after opening the console window:

Console.hnd=AllocConsole()

em22	(Posted 2009) [#14]

Awesome :)

Chroma

(Posted 2010) [#15]

...