Print without newline?

BlitzMax Forums/BlitzMax Beginners Area/Print without newline?

xlsior

(Posted 2010) [#1]

I'm looking at putting together a very basic command line program (under Win32), and was wondering if there's an easy way to re-write a line of text in the console window.

the "Print" command automatically appends a newline so the cursor goes to the next line, but I'm hoping to have a simple progress counter which would require me to update the same line of text a number of times.

Any idea?

Zeke	(Posted 2010) [#2]

Extern "win32"
	Function SetConsoleCursorPosition:Int(handle:Int , pos:Int)
End Extern

Function Locate(x:Int , y:Int)
	SetConsoleCursorposition(GetStdHandle( STD_OUTPUT_HANDLE) , y Shl 16+x)
End function


locate 10 , 10
Print "test"
locate 20 , 20
Print "it's working"

For Local i:Int = 0 To 100
	locate 30 , 0
	Print "Count: " + i
	Delay 200
Next

Here you can find other console functions: http://msdn.microsoft.com/en-us/library/ms682073%28VS.85%29.aspx
Note that this wont work when running from IDE, so you must build exe and run that.

xlsior

(Posted 2010) [#3]

Very interesting...

Although for it to be usable, I'll need to figure out how to parse the current cursor position through GetconsoleScreenBufferInfo first. :-?

(Blah, I hate pointers... :-? )

xlsior

(Posted 2010) [#4]

Ok, with some help of other console code by Jim Brown, I've been able to piece together some code that can also read the current location.

This will print an growing text progressbar on the same line in the active console window:
(After printing the progress bar, it will move the cursor back to the same line so the updated version overwrites the previous one)

Extern "win32"
	Function SetConsoleCursorPosition:Int(handle:Int , pos:Int)
	Function GetConsoleScreenBufferInfo(handle:Int ,sbinfo:Byte Ptr)
End Extern

Function Locate(x:Int , y:Int)
	SetConsoleCursorposition(GetStdHandle( STD_OUTPUT_HANDLE) , y Shl 16+x)
End Function

Global cursorX:Int
Global cursorY:Int
Global progressbar:String

Print
Print

For Local myloop:Int=0 To 100
	console.GetCursorPos(x,y)
	Locate cursorx,cursory-1
	Delay 100
	progressbar:String=""
	For Local myloop2:Int=0 To myloop/4
		progressbar:String=progressbar:String+"|"
	Next
	Print myloop+"% "+Progressbar:String

Next


Global sbinfo:ConsoleScreenBufferInfo=New ConsoleScreenBufferInfo


Type Console
	Const STD_INPUT_HANDLE% = -10
	Const STD_OUTPUT_HANDLE% = -11
	Global hnd% , stdOUT% , stdIN% , ForeColor%,BackColor%
	Global Width%,Height%
	Global sbinfo:ConsoleScreenBufferInfo=New ConsoleScreenBufferInfo
	Function GetCursorPos(x% Var,y% Var)
		GetConsoleScreenBufferInfo GetStdHandle( STD_OUTPUT_HANDLE),Console.sbinfo
		CursorX = Console.sbinfo.CursorXPos 
		CursorY = Console.sbinfo.CursorYPos
	End Function
End Type

Type ConsoleScreenBufferInfo
	Field numCols:Short , numRows:Short
	Field CursorXPos:Short,CursorYPos:Short
	Field Attrs:Short
    	Field sbuffL:Short,sbuffT:Short,sbuffR:Short,sbuffB:Short
	Field MaxWinXSize:Short,MaxWinYSize:Short
End Type

Function SetCursorPos(x%,y%)
	SetConsoleCursorPosition GetStdHandle( STD_OUTPUT_HANDLE), (y Shl 16) + x
End Function

Thanks for the pointer, Zeke! (and Jim, too)

d-bug

(Posted 2010) [#5]

Nice one, but whats wrong with WriteStdOut?

xlsior

(Posted 2010) [#6]

Nice one, but whats wrong with WriteStdOut?

Absolutely nothing...

...Had I known it existed. :-?

Looks like that one works perfectly to re-write the current line without needing to figure out where it's at:

WriteStdOut "OLD"
WriteStdOut chr$(8)+chr$(8)+chr$(8)  ' chr$(8) = Backspace
WriteStdOut "NEW"

Thanks for the heads up.

EOF	(Posted 2010) [#7]

Thanks for the mention. Just a little plug, you can use my console library for doing funky stuff like changing the color attributes, clearing the screen, reading the text buffer ..

If anyone's interested:

DEMO #1

Strict
Framework brl.blitz
Import "ConsoleControl.bmx"

Console.Open "CLS test"
For Local clr%=1 To $80
	Console.SetColorAttr clr
	Console.WriteLine "Testing attribute color ["+String(clr)+"]"
Next
Console.SetColor WHITE,BLUE
Console.WaitReturn
Console.SetColor YELLOW,RED
Console.Cls
Console.Write "Final line written"
Delay 1000

End

DEMO #2

Strict
Framework brl.blitz
Import "ConsoleControl.bmx"

Console.Open
'Console.CreateScreenBuffer
Console.SetTitle "Console - Input test"
Console.SetColor WHITE,BLUE

Console.WriteLine "   OO    OO   O    O   OOO    OO   O     OOOO"
Console.WriteLine "  O     O  O  OO   O  O      O  O  O     O   "
Console.WriteLine "  O     O  O  O O  O  O      O  O  O     O   "
Console.WriteLine "  O     O  O  O O  O   OOO   O  O  O     OOO "
Console.WriteLine "  O     O  O  O  O O      O  O  O  O     O   "
Console.WriteLine "  O     O  O  O   OO      O  O  O  O     O   "
Console.WriteLine "   OO    OO   O    O   OOO    OO   OOOO  OOOO"

Console.SetColor GREY,BLACK
Console.SetCursorPos 0,10
Local name$=Console.Input("Your name? >")
Console.SetColor BLACK,DYELLOW
Console.Cls
Console.SetCursorPos 4,14
Local t$=Console.Input("Hello ~q"+name+"~q enter some random text >")
Console.write name+", Text written was '"+t+"'"
Console.WaitReturn
Console.Close
End

ConsoleControl.bmx

Rem
	Title: ConsoleControl v0.01
	Author: Jim Brown
EndRem

Strict

Const BLACK = 0
Const DBLUE = 1
Const DGREEN = 2
Const DRED = 4
Const INTENSITY = 8
Const DYELLOW = DRED+DGREEN
Const DCYAN = DGREEN+DBLUE
Const DPURPLE = DRED+DBLUE
Const BLUE = DBLUE+INTENSITY
Const GREEN = DGREEN+INTENSITY
Const RED = DRED+INTENSITY
Const WHITE = DBLUE+DGREEN+DRED+INTENSITY
Const GREY = DBLUE+DGREEN+DRED
Const YELLOW = DGREEN+DRED+INTENSITY
Const CYAN = DGREEN+DBLUE+INTENSITY
Const PURPLE = DRED+DBLUE+INTENSITY


Extern "Win32"
	Function WriteConsoleW%(hnd%,lpBuff$w,NChars%,NCharsWritten:Int Ptr,Reserved%)
	Function AllocConsole%()
	Function FreeConsole()
	Function CreateConsoleScreenBuffer%(Access%,ShareMode%,secAttr:Byte Ptr,Flags%,Reserved%)
	Function SetConsoleActiveScreenBuffer(hScreenBuff%)
	Function SetStdHandle(tpy%,hnd%)
	Function GetStdHandle(tpy%)
	Function SetConsoleTitleW(title$w)
	Function SetConsoleCursorPosition(hbuffOUT%,xyPos%)
	Function FillConsoleOutputCharacterW%(hbuffOUT%,char%,numChars%,xyPos%,nCharsWritten:Int Ptr)
	Function FillConsoleOutputAttribute%(hbuffOUT%,attr%,numChars%,xyPos%,nCharsWritten:Int Ptr)
	Function GetConsoleScreenBufferInfo(hbuffOUT%,tCONSOLEINFO:Byte Ptr)
	Function SetConsoleTextAttribute(hbuffOUT%,attr%)
	Function FlushConsoleInputBuffer(hbuffIN%)
	Function ReadConsoleA(hbuffIN%,lBuffAddr:Byte Ptr,numCharsToRead%,nCharsRead:Int Ptr,Reserved%)
	Function ReadConsoleW(hbuffIN%,lBuffAddr:Byte Ptr,numCharsToRead%,nCharsRead:Int Ptr,Reserved%)
	Function PeekConsoleInput(hbuffIN%,lpBuffer:Long Ptr,Length%,numEventsRead%)
	Function ReadConsoleOutputW(hbuffOUT%,lBuffAddr:Byte Ptr,xypos%,buffCoord%,sRect:Int Ptr)
	Function ReadConsoleOutputCharacterA(hbuffOUT%,lBuffAddr:Byte Ptr,numCharsToRead%,buffCoord%,nCharsRead:Int Ptr)
End Extern


Type Console
	Const STD_INPUT_HANDLE% = -10
	Const STD_OUTPUT_HANDLE% = -11
	Global hnd% , stdOUT% , stdIN% , ForeColor%,BackColor%
	Global Width%,Height%
	Global sbinfo:ConsoleScreenBufferInfo=New ConsoleScreenBufferInfo
	'
	Function Open(title$="ConsoleControl Window")
		Assert Console.hnd=Null,"Console already open!"
		Console.hnd=AllocConsole()
		Assert Console.hnd,"Console failed to open"
		Console.ForeColor=7 ; Console.BackColor=0
		Console.stdOUT=GetStdHandle(Console.STD_OUTPUT_HANDLE)
		Console.stdIN=GetStdHandle(Console.STD_INPUT_HANDLE)
		Assert Console.stdOUT,"Failed to get console screen OUT buffer"
		Assert Console.stdIN,"Failed to get console screen IN buffer"
		GetConsoleScreenBufferInfo Console.stdOUT,Console.sbinfo
		Console.Width=Console.sbinfo.numCols ; Console.Height=Console.sbinfo.numRows
		Console.Cls
		Console.SetTitle title
	End Function
	'
	Function CreateScreenBuffer%()
		Const GEN_READ=$80000000 , GEN_WRITE=$40000000
		Local hndSB%=CreateConsoleScreenBuffer(GEN_READ+GEN_WRITE, 1+2,Null,1,Null)
		SetConsoleActiveScreenBuffer hndSB
		SetStdHandle Console.STD_OUTPUT_HANDLE,hndSB
		Console.stdOUT=GetStdHandle(Console.STD_OUTPUT_HANDLE)
		Console.stdIN=GetStdHandle(Console.STD_INPUT_HANDLE)
		Return hndSB
	End Function
	'
	Function Close()
		Assert Console.hnd,"No Console to 'close'"
		FreeConsole() ; Console.hnd=Null
		Console.stdOUT=0 ; Console.stdIN=0
		Console.Width=0 ; Console.Height=0
	End Function
	'
	Function SetCursorPos(x%,y%)
		SetConsoleCursorPosition Console.stdOUT, (y Shl 16) + x
	End Function
	'
	Function GetCursorPos(x% Var,y% Var)
		GetConsoleScreenBufferInfo Console.stdOUT,Console.sbinfo
		x=Console.sbinfo.CursorXPos ; y=Console.sbinfo.CursorYPos
	End Function
	'
	Function Write(txt$)
		Assert Console.hnd,"Console not open - Unable to write text"
		WriteConsoleW Console.stdOUT,txt,txt.Length,Null,0
	End Function
	'
	Function WriteLine(l$)
		Console.Write l$+Chr(10)	
	End Function
	'
	Function Read$(x%,y%,numChars%=1)
		Local inp:Byte[numChars] ' space for character(s) to read
		Local ncr% ' storage variable for number of chars actually read
		DebugLog "R="+ReadConsoleOutputCharacterA(Console.stdOUT%,Varptr(inp[0]),numChars,(y Shl 16) + x, Varptr(ncr))
		DebugLog inp[0]
		Return String.FromCString(inp).Trim()
	End Function
	'
	Function ReadLine$(yPos%)
		Return Console.Read(0,yPos,Console.Width)
	End Function
	'
	Function Cls()
		Local sz%=Console.Width*Console.Height
		FillConsoleOutputCharacterW Console.stdOUT,32,sz,0,Null
		FillConsoleOutputAttribute Console.stdOUT,Console.BackColor*16,sz,0,Null
		SetConsoleCursorPosition Console.stdOUT,0
	End Function
	'
	Function SetColor(fore%,back%=-1)
		If back=-1 Then back=Console.BackColor
		If fore=-1 Then fore=Console.ForeColor
		SetConsoleTextAttribute Console.stdOUT,fore+(back*16)
		Console.ForeColor=fore ; Console.BackColor=back
	End Function
	'
	Function SetColorAttr(index%)
		If index<0 Or index%>128 Then Return
		SetConsoleTextAttribute Console.stdOUT,index
	End Function
	'
	Function WaitReturn()
		Console.SetColor GREY
		Console.WriteLine "~nPress RETURN .."
		FlushConsoleInputBuffer Console.StdIN
		ReadConsoleA Console.StdIN,Null,1,Null,0
	End Function
	'
	Function Input$(defprompt$="> ")
		Local inp:Byte[16384]
		Local ncr% ' storage variable for number of chars actually read
		Console.Write defprompt$
		FlushConsoleInputBuffer Console.StdIN
		ReadConsoleA(Console.StdIN,Varptr(inp[0]),inp.Length,Varptr(ncr),Null)
		Local rs$=String.FromCString(inp)
		If rs.Length<=2 Then Return "" ' user pressed RETURN only
		Return String(rs[..rs.Length-2]) ' strip RETURN and NULL characters
	End Function
	'
	Function SetTitle(newtitle$)
		SetConsoleTitleW newtitle$
	End Function
	'
End Type

Type ConsoleScreenBufferInfo
	Field numCols:Short , numRows:Short
	Field CursorXPos:Short,CursorYPos:Short
	Field Attrs:Short
    	Field sbuffL:Short,sbuffT:Short,sbuffR:Short,sbuffB:Short
	Field MaxWinXSize:Short,MaxWinYSize:Short
End Type

Type tCoord
	Field x%,y%
End Type

xlsior

(Posted 2010) [#8]

I found that in another thread, but both demos failed for me, always saying it could not create a console... (windows 7, x64)

EOF	(Posted 2010) [#9]

Xlsior,
Are you running the demos as GUI build? I'm guessing BlitzMax is already opening the console window. My module handles the whole console window opening and closing affair (Console.Open / Console.Close)

xlsior

(Posted 2010) [#10]

No, I wasn't using it as a GUI build -- if that's a pre-requisite then it won't work for me anyway... The entire point is that I'm creating a command line app that I can run straight from a normal DOS window, interacting with other command line applications.

If your library tries to create and conotrol its own console window that would explain the error, although that does mean it won't be usable for my purposes...