Slider stepping issue.

BlitzMax Forums/BlitzMax Beginners Area/Slider stepping issue.

Thareh

(Posted 2010) [#1]

Hi!
I'm creating a user interface, and I stumbled upon an annoying problem which I can't solve.

Graphics 1024, 768
SetClsColor( 255, 255, 255 )

Type TSlider
	
	Global List:TList = CreateList()
	
	Field X:Int, Y:Int, W:Int, H:Int
	Field SliderPos:Int, SliderSteps:Int
	
	Function Create:TSlider( X:Int, Y:Int, W:Int, H:Int, Steps:Int )
		Local A:TSlider = New TSlider
		A.X = X
		A.Y = Y
		A.W = W
		A.H = H
		A.SliderSteps = Steps
		ListAddLast( TSlider.List, A )
		Return( A )
	End Function
	
	Method Update()
		
		Local Size:Int = H - W
		Local StepSize:Int = Size/SliderSteps
		SliderPos = (MouseY() - Y)/StepSize*StepSize
		
		SetColor( 200, 200, 255 )
			DrawRect( X, Y, W, H )
		SetColor( 150, 150, 200 )
			DrawRect( X, Y + SliderPos, W, W )
		SetColor( 255, 255, 255 )
	End Method
	
	Function UpdateALL()
		For Local A:TSlider = EachIn TSlider.List
			A.Update()
		Next
	End Function
	
End Type

TSlider.Create( 100, 100, 20, 150, 20 )

While Not KeyHit( KEY_ESCAPE )
	
	TSlider.UpdateALL()
	
	Flip( 0 );Cls
Wend
End

I just can't get the damn thing to go even up!
I want it to go even up no matter what size and steps you choose if that makes any sense :P
Anyone who can throw me a helping hand? :)
Thanks!

matibee

(Posted 2010) [#2]

A simple order of operation issue I think...

SliderPos = ((MouseY() - Y)/StepSize)*StepSize

Thareh

(Posted 2010) [#3]

Nah, Didn't work :(

matibee

(Posted 2010) [#4]

You're right, it makes no difference. Sorry I didn't understand the problem. What do you mean by "even up".

Zeke	(Posted 2010) [#5]

SuperStrict
Graphics 1024, 768
SetClsColor( 255, 255, 255 )

Type TSlider
	
	Global List:TList = CreateList()
	
	Field X:Int, Y:Int, W:Int, H:Int
	Field SliderPos:Int, SliderSteps:int
	
	Function Create:TSlider( X:Int, Y:Int, W:Int, H:Int, Steps:Int )
		Local A:TSlider = New TSlider
		A.X = X
		A.Y = Y
		A.W = W
		A.H = H
		A.SliderSteps = Steps
		ListAddLast( TSlider.List, A )
		Return( A )
	End Function
	
	Method Update()
		
		Local Size:float = H - W
		Local StepSize:float = Size/SliderSteps
		SliderPos = (MouseY() - Y) / StepSize
		
		If sliderpos<0 Then sliderpos=0
		If sliderpos > slidersteps Then sliderpos = slidersteps
		
		SetColor( 200 , 200 , 255 )
			DrawText sliderpos , x , y - w
			DrawRect( X , Y , W , H )
		
		'Draw steps
		SetColor 0 , 0 , 0
		For Local i:Int = 0 To slidersteps
			DrawLine x - 10 , y + i * stepsize , x +w+ 10 , y + i * stepsize
		Next
		
		
		SetColor( 150, 150, 200 )
			DrawRect( X, Y + SliderPos*Stepsize, W, W )
		SetColor( 255, 255, 255 )
	End Method
	
	Function UpdateALL()
		For Local A:TSlider = EachIn TSlider.List
			A.Update()
		Next
	End Function
	
End Type

TSlider.Create( 100, 100, 20, 350, 30 )

While Not (KeyHit( KEY_ESCAPE ) Or AppTerminate())
	
	TSlider.UpdateALL()
	
	Flip( 0 );Cls
Wend
End

this is not perfect, but..

matibee

(Posted 2010) [#6]

I guessed that was the issue Zeke and just came back to post almost the exact same code (even down to SliderPos being in the range 0 to SliderSteps :)

Thareh

(Posted 2010) [#7]

Got it working now, Thanks guys :)
I just couldn't get my damn head around it!