Planet Game Idea (need help)

BlitzMax Forums/BlitzMax Beginners Area/Planet Game Idea (need help)

B	(Posted 2011) [#1]

hey all,

back again with a new idea.

I want to create a simple demo for my idea and progress from there
into a game.

My idea is to have a small planet in the example colored brown and
a you are a person that can walk around the planets outside.

heres a picture to demonstrate:

i am having trouble with the setrotation() command.

I want the player to always be facing towards the center of the planet
and I do not know the formula to do this.

The arrow keys would control his movements, and using a distance formula i could keep the player at the surface of the planet, but
facing him towards the center is proving to be difficult for me.

Can anyone help me?

thanks! :)

heres my code so far

SuperStrict
Framework BRL.GLMax2D
Import BRL.Math
Import BRL.Random
Import BRL.PolledInput
Import BRL.KeyCodes
Import BRL.pngloader
Import BRL.Graphics

Graphics 1024,768


Global dx#,dy#,distance#




Global plyr:player = New player
	plyr.x#			= 20
	plyr.y#			= 20
	plyr.heading#		= 0
	SetColor (0,0,255) 'blue
	DrawRect 0,0,20,20
	plyr.image:TImage = CreateImage(20,20,1,DYNAMICIMAGE|MASKEDIMAGE)
	GrabImage plyr.image,0,0
	MidHandleImage(plyr.image)
Cls

Global p:planet = New planet
	p.x#				= 512
	p.y#				= 384
	p.r#				= 500
	SetColor (128,64,0) 'brown
	DrawOval 0,0,p.r#,p.r#
	p.image:TImage = CreateImage((p.r#),(p.r#),1,DYNAMICIMAGE|MASKEDIMAGE)
	GrabImage p.image,0,0
	MidHandleImage(p.image)
Cls


While Not KeyDown(key_escape)
Cls


p.draw()
plyr.draw()


If KeyDown(key_right)		plyr.x#:+1
If KeyDown(key_left)		plyr.x#:-1
SetColor(255,255,255)
DrawText plyr.x# + " " + plyr.y#,0,0

Flip
Wend


Type player
	Field x#,y#,heading#,image:TImage
	
	Method setheading()
		distance#=Sqr((x#-p.x#)*(x#-p.x#)+(y#-p.y#)*(y#-p.y#))
		
		
	EndMethod
	
	Method gravity()
		
	EndMethod
	
	Method draw()
		'SetRotation(plyr.heading#)
		DrawImage plyr.image,plyr.x#,plyr.y#
	EndMethod
EndType

Type planet
	Field x#,y#,r#,image:TImage
	
	Method draw()
		DrawImage p.image,p.x#,p.y#
	EndMethod
EndType

should run fine since i create the images inside the program

EDIT:
Im wondering if i should just rotate the planet and the things I plan on
putting on the planet underneath your character and have the character
stay in the same place.
What do you guys think?

Last edited 2011

Sloan

(Posted 2011) [#2]

What about this?

SuperStrict
Graphics 800, 600

Local innerradius:Float = 92
Local radius:Float = 100
Local x:Float = 400
Local y:Float = 300
Local angle:Float = 0

While Not KeyHit(KEY_ESCAPE)
	
	If KeyDown(KEY_LEFT)
		angle:-2
		If angle < 0
			angle = angle + 360
		End If 		
	Else If KeyDown(KEY_RIGHT)
		angle:+2
		If angle > 360
			angle = angle - 360
		End If 
	End If 
	
	Cls
	
		Local rx:Float = Sin(angle) * radius
		Local ry:Float = Cos(angle) * radius
		
		SetColor 128, 192, 0
		DrawOval x - innerradius, y - innerradius, innerradius* 2, innerradius * 2
		 
		SetRotation angle 
		
		SetColor 255, 255, 255
		DrawRect x + rx, y - ry, 8, 8
		SetRotation 0
		
		DrawText "Angle: " + angle, 10, 10
			
	Flip
Wend

It uses a little bit of trig to get the position of the square just right, and the same angle value is used in SetRotation to get it in the correct orientation.

Last edited 2011

B	(Posted 2011) [#3]

wow! thats perfect!

i guess i should brush up on my trig, havent used it much since highschool.
haha!

thanks man! ill see what i can put together :)

Sloan

(Posted 2011) [#4]

No problem :)

Kryzon

(Posted 2011) [#5]

Might be fun to play with the sense of reference, related to when you're upside down. Your reference to what's "to the left" and what's "to the right" are reversed.

Try this (move the square toward the bottom of the sphere, release the arrow keys completely and then try to move again):

SuperStrict
Graphics 800, 600

Local innerradius:Float = 92
Local radius:Float = 100
Local x:Float = 400
Local y:Float = 300
Local angle:Float = 0
Local charSpeed:Int = -2 'Added
Local kLeft:Int,kRight:Int 'Added

While Not KeyHit(KEY_ESCAPE)
	
	kLeft = KeyDown(KEY_LEFT)
	kRight = KeyDown(KEY_RIGHT)
	
	If kLeft And Not kRight Then  
		angle:+charSpeed
		If angle < 0
			angle = angle + 360
		End If
	EndIf 
	If kRight And Not kLeft Then
		angle:-charSpeed
		If angle > 360
			angle = angle - 360
		End If 
	End If
	
	If (kLeft + kRight) = 0 Then 
		If angle > 90 And angle < 270 Then 
			charSpeed = 2 'Negative.
		Else
			charSpeed = -2 'Positive.
		EndIf 
	EndIf
	
	Cls
	
		Local rx:Float = Sin(angle) * radius
		Local ry:Float = Cos(angle) * radius
		
		SetColor 128, 192, 0
		DrawOval x - innerradius, y - innerradius, innerradius* 2, innerradius * 2
		 
		SetRotation angle 
		
		SetColor 255, 255, 255
		DrawRect x + rx, y - ry, 8, 8
		SetRotation 0
		
		DrawText "Angle: " + angle, 10, 10
		DrawText "Speed: " + charSpeed, 10, 20
			
	Flip
Wend

Last edited 2011

Sloan

(Posted 2011) [#6]

Nice touch, Kryzon! Feels a bit weird to begin with-- to get your head around the fact your on the southern hemisphere. Kinda like "playing with portals" :)

andy_mc

(Posted 2011) [#7]

It's Mario Galaxy 2D!!! Will the player be able to jump onto new planets? This reminds me of the british gas adverts.

B	(Posted 2011) [#8]

hey guys

so here is what came about.

its not nearly finished, not really fun to play for a long time
but still pretty cool and innovative...i think.

SuperStrict
Graphics 800, 600

Local i%,w%
Local innerradius:Float = 200
Local radius:Float = innerradius + 20
Local x:Float = 400
Local y:Float = 300
Local angle:Float = 0
Local money:Float = 0
Local wood:Float = 0
Local totalbuilds# = 0
Local totaltrees# = 20
Local steam:Float = 0
Local maxsteam# = (totalbuilds# * 20)
Local ablebuild# = 1
Local maxbuilds#	= 100
Local maxtrees#		= 100
Local buildkey% = 70 'f
Local buildtrigger% = 0
Local treetrigger%	= 0
Local steamtrigger%	= 0

SetColor 255,0,255
SetMaskColor 255,0,255
DrawRect 0,0,20,20

SetColor 170,90,0
	'trunk
	DrawRect 5,0,10, 20
SetColor 64,128,0
	'leaves
	DrawRect 0,0,20,10
Local treeimage:TImage = CreateImage(20,20,1,DYNAMICIMAGE|MASKEDIMAGE)
GrabImage treeimage,0,0

SetColor 50,50,50
	'outline
	DrawRect 0,0,20,30
SetColor 120,120,120
	'building
	DrawRect 2,2,16,26
SetColor 50,50,50
	'vents
	DrawLine 4,10,14,10
	DrawLine 4,11,14,11
	'
	DrawLine 4,15,14,15
	DrawLine 4,16,14,16
	'
	DrawLine 4,20,14,20
	DrawLine 4,21,14,21
Local buildimage:TImage = CreateImage(20,30,1,DYNAMICIMAGE|MASKEDIMAGE)
GrabImage buildimage,0,0



Local t:tree[100]
For i = 0 To 19
	t:tree[i] = New tree
		t[i].a# = Rand(0,360)
		t[i].t# = 100
		t[i].b# = 1
Next
For i = 20 To 99
	t:tree[i] = New tree
		t[i].a# = Null
		t[i].t# = 100
		t[i].b# = 1
Next

Local b:building[maxbuilds#]
For i = 0 To maxbuilds#-1
	b:building[i] = New building
		b[i].b# = 0
		b[i].a# = Null
		b[i].r# = Null
Next

Cls


While Not KeyHit(KEY_ESCAPE)
	
	If KeyDown(KEY_LEFT)
		angle:-1
		If angle < 0
			angle = angle + 360
		End If 		
	Else If KeyDown(KEY_RIGHT)
		angle:+1
		If angle > 360
			angle = angle - 360
		End If 
	End If 
	
	Cls
		maxsteam# = (totalbuilds# * 20)
		Local rx:Float = Sin(angle) * radius
		Local ry:Float = Cos(angle) * radius
		
		SetColor 128,64,0
		DrawOval x - innerradius, y - innerradius, innerradius* 2, innerradius * 2
		 
		SetRotation angle + 3
		
		SetColor 0,0,200
		DrawRect x + rx, y - ry, 20, 20
		
		SetColor 255,255,255
		If steam# > 499
			If KeyDown(key_s) steamtrigger% = 1
				If KeyDown(key_s) = False And steamtrigger% = 1	steamtrigger% = 0	steam#:-500	money#:+10
		EndIf
		If wood# > 19 And totaltrees# < maxtrees# - 1
			If KeyDown(key_t) treetrigger% = 1
				If t[w].a# < t[i].a# - 5 Or t[w].a# > t[i].a# + 5
					If KeyDown(key_t) = False And treetrigger% = 1
						treetrigger% = 0
						t[totaltrees#].b# = 1
						t[totaltrees#].a# = angle#
						wood#:-20
						totaltrees#:+1
					EndIf
				EndIf
		EndIf
		If ablebuild# = 1 And wood# > 49 And totalbuilds# < maxbuilds# - 1
			If KeyDown(key_f) buildtrigger% = 1
					If KeyDown(key_f) = False And buildtrigger% = 1
						buildtrigger% = 0
						b[totalbuilds#].b# = 1
						b[totalbuilds#].a# = angle#
						wood#:-50
						totalbuilds#:+1
					EndIf
		EndIf
		For i = 0 To totalbuilds#
			SetColor(255,255,255)
			SetRotation(b[i].a#)
			If b[i].b# = 1
				DrawImage buildimage,x + (Sin(b[i].a#) * radius),y - (Cos(b[i].a#) * radius)
				If steam# < maxsteam#	steam#:+0.01
			EndIf
		Next
		
		For i = 0 To totaltrees#
			If angle# > t[i].a# - 5 And angle# < t[i].a# + 5
				ablebuild# = 0
			Else If angle < t[i].a# - 5 Or angle# > t[i].a# +5
				ablebuild# = 1
			EndIf
		Next
					
		For i = 0 To totaltrees#
			SetRotation t[i].a#
			If t[i].b# = 1 And t[i].t# > 0
				DrawImage treeimage,x + (Sin(t[i].a#) * radius),y - (Cos(t[i].a#) * radius)
				If angle > t[i].a# - 5 And angle < t[i].a# + 5
					SetColor 170,90,0
					SetRotation 0
					SetScale 2,2
					DrawRect 350,20,((t[i].t# / 100) * 50),5
					SetColor(255,255,255)
					SetScale 1,1
					
					If KeyDown(key_space)	t[i].t#:-0.5	wood#:+0.5
				EndIf

				EndIf
		Next
		SetRotation 0
		
		
		
		SetColor 255,255,255
		DrawText "Angle: " + Int(angle#), 10, 10
		DrawText "Money: " + Int(money#), 10, 25
		DrawText "Wood:  " + Int(wood#),  10, 40
		DrawText "Steam: " + Int(steam#) + "/" + Int(maxsteam#), 10, 55
		
		DrawText "F - Build Steam Factory", 10,400
		DrawText "T - Plant Tree", 10,420
		DrawText "S - Sell Steam",10,440
		DrawText "    500 steam - $10",10,460
		
		
	Flip
Wend 



Type tree
	Field b#,a#,t#,image:TImage
End Type

Type building
	Field b#,a#,r#,image:TImage
	'b = built
	'a = angle
	'r = resources
End Type

oh ya and space to collect wood from trees

pretty random i know,

but tell me what you think.

:)

Last edited 2011

Sloan

(Posted 2011) [#9]

Liking it so far :)