autoscroll wxTreeCtrl

BlitzMax Forums/Brucey's Modules/autoscroll wxTreeCtrl

Warner

(Posted 2009) [#1]

Edit: Posting on this forum really helps somehow. I figured something out now. This is a real basic version, but if you combine it with a timer, it seems to work allright:

Framework wx.wxApp
Import wx.wxFrame
Import wx.wxTreeCtrl
Import wx.wxMessageDialog
Import brl.StandardIO
Import brl.Random

New MyApp.Run()

Type MyApp Extends wxApp

	Global dragging:wxTreeItemId
	Field structure:wxTreeCtrl
	Field root:wxTreeItemId

'------------------------------------------------------------------------------------------------------------------------------------
'											OnInit()
'------------------------------------------------------------------------------------------------------------------------------------

	Method OnInit()

		'create frame	
		Local window:wxFrame = New wxFrame.Create(Null, wxID_ANY, "Test", -1, -1, 120, 160, wxCLOSE_BOX | wxCAPTION | wxSYSTEM_MENU )
		window.Centre()

		'create treectrl
		structure = New wxTreeCtrl.Create(window, wxID_ANY, -1, -1, -1, -1)
		root = structure.AddRoot("ROOT", -1, -1, Null)
		
		'add items to it
		For i = 0 To 50
			Local obj1:wxTreeItemId = structure.AppendItem(root, "item" + i, -1, -1, Null)
		Next		
		structure.ExpandAll()

		'hook events
		Connect(structure.getID(), wxEVT_COMMAND_TREE_BEGIN_DRAG, _OnTreeDragBegin)
		Connect(structure.getID(), wxEVT_COMMAND_TREE_END_DRAG, _OnTreeDragEnd)
		
		Connect(structure.getID(), wxEVT_ENTER_WINDOW, OnEnter)
		Connect(structure.getID(), wxEVT_LEAVE_WINDOW, OnLeave)

		'show main window
		window.Show(True)
						 
		Return True
		
	End Method

'------------------------------------------------------------------------------------------------------------------------------------
'											_OnTreeDragBegin()
'------------------------------------------------------------------------------------------------------------------------------------

	'start dragging inside treeview
	Function _OnTreeDragBegin(event:wxEvent)
		Local evt:wxTreeEvent = wxTreeEvent(event)
		If evt = Null Then Return
	
		'store item
		dragging = evt.GetItem()
		'allow drag
		evt.Allow()
	End Function
		
'------------------------------------------------------------------------------------------------------------------------------------
'											_OnTreeDragEnd()
'------------------------------------------------------------------------------------------------------------------------------------

	'wrap OnTreeDragEnd()
	Function _OnTreeDragEnd(event:wxEvent)
		MyApp(event.parent).OnTreeDragEnd(event)
	End Function

	'receive dragging inside treeview
	Method OnTreeDragEnd(event:wxEvent)
	
		'ensure everything is valid
		Local evt:wxTreeEvent = wxTreeEvent(event)
		If evt = Null Then Return
		If evt.GetItem() = Null Then Return
		If dragging = Null Then Return
		If structure.GetItemText(evt.GetItem()) = "" Then Return

		'insert item to tree, and if successfull, remove original item
		If InsertItem(dragging, evt.GetItem()) Then
			structure.DeleteItem(dragging)
		End If
		
		'reset dragging flag/object
		dragging = Null		
	End Method


'------------------------------------------------------------------------------------------------------------------------------------
'											InsertItem()
'------------------------------------------------------------------------------------------------------------------------------------

	'insert treeview item to a parent item
	Method InsertItem:Int(o1:wxTreeItemId, o2:wxTreeItemId)
	
		'ensure this is a valid insert
		If o1 = o2 Then Return False
		If o1.Equals(o2) Then Return False
		If IsChild(o1, o2) Then Return False
		
		'add item to tree
		Local newr:wxTreeItemId = ..
				structure.AppendItem(o2, ..
				structure.GetItemText(o1), -1, -1, ..
				structure.GetItemData(o1))
				
		Local i:Int		
		Local c:Int = structure.GetChildrenCount(o1, False) 
		
		'if item has children
		If c > 0 Then
			'store them into an array
			Local cho:wxTreeItemId[] = New wxTreeItemId[c] 				
			cho[0] = structure.GetFirstChild(o1)
		
			For i = 1 To c - 1
				cho[i] = structure.GetNextChild(o1)
			Next

			'insert all items in this array to the tree as well
			For i = 0 To c - 1
				InsertItem( cho[i], newr )
			Next
						
		End If
		
		'show item
		structure.Expand(o2)
		structure.EnsureVisible(o2)
				
		Return True
			
	End Method

'------------------------------------------------------------------------------------------------------------------------------------
'											IsChild()
'------------------------------------------------------------------------------------------------------------------------------------

	'check if o2 is a (sub)child of o1	
	Method IsChild:Int(o1:wxTreeItemId, o2:wxTreeItemId)

		'if they are equal, return true	
		If o1 = o2 Then Return True
		If o1.Equals(o2) Then Return True

		'get child count
		Local c:Int = structure.GetChildrenCount(o1, False)
		
		'if more than 0 childs
		If c > 0 Then
			'store childs in array
			Local cho:wxTreeItemId[] = New wxTreeItemId[c] 				
			cho[0] = structure.GetFirstChild(o1)
			
			Local i:Int
		
			For i = 1 To c - 1
				cho[i] = structure.GetNextChild(cho[i - 1])
			Next

			'check if o2 is in this array
			For i = 0 To c - 1
				If cho[i] = o2 Then 
					Return True
				Else
					'also check each child of this item in array
					If IsChild(cho[i], o2) Then Return True
				End If
			Next
						
		End If
		
		'o2 is not a child of o1
		Return False
		
	End Method

	Function OnEnter(evt:wxEvent)
		MyApp(evt.parent)._OnEnter(evt)
	End Function
	
	Function OnLeave(evt:wxEvent)
		MyApp(evt.parent)._OnLeave(evt)
	End Function

	Method _OnEnter(evt:wxEvent)
		Print "end drag"
	End Method
	
	Method _OnLeave(evt:wxEvent)
		e:wxMouseEvent = wxMouseEvent(evt)
		If e = Null Then Return
		
		Local x:Int, y:Int
		Local w:Int, h:Int
		
		structure.GetSize(w, h)		
		e.GetPosition(x, y)
		
		If y < 5 Then structure.LineUp()
		If y > h - 5 Then structure.LineDown()
	End Method
 
		
End Type

Brucey

(Posted 2009) [#2]

btw, if you do this, the code looks a little cleaner :

	Function OnLeave(evt:wxEvent)
		MyApp(evt.parent)._OnLeave(wxMouseEvent(evt))
	End Function

	Method _OnLeave(evt:wxMouseEvent)
		....
	End Method

Oh, and Strict / SuperStrict is your friend ;-)

Warner

(Posted 2009) [#3]

Thank you Brucey!