MaxGUI strange idea...

BlitzMax Forums/MaxGUI Module/MaxGUI strange idea...
degac
(Posted 2010) [#1]
I just wrote this 'strange' MaxGUI 'self-contained-definition' gadgets...
Just for fun (or for my lazyness)
' createwindow.bmx

Import MaxGui.Drivers

Strict 

AppTitle = "CreateWindow() Example"

Global FLAGS:Int

' Comment/uncomment any of the following lines to experiment with the different styles.

FLAGS:| WINDOW_TITLEBAR
FLAGS:| WINDOW_RESIZABLE
'FLAGS:| WINDOW_MENU
FLAGS:| WINDOW_STATUS
FLAGS:| WINDOW_CLIENTCOORDS
'FLAGS:| WINDOW_HIDDEN
FLAGS:| WINDOW_ACCEPTFILES
'FLAGS:| WINDOW_TOOL
FLAGS:| WINDOW_CENTER

Local window:TGadget = CreateWindow( AppTitle, 100, 100, 320, 370, Null, FLAGS )

If (FLAGS & WINDOW_STATUS) Then
	SetStatusText( window, "Left aligned~tCenter aligned~tRight aligned" )
EndIf

Local btn:tgadget=CreateButtonX("Hallo{=pos:;size:50%,25%;title:I'm special!;fcolor:200,50,50;bcolor:255,200,125;layout:2,2,2,2=}",10,10,100,20,window)

Local btn2:tgadget=CreatebuttonX("My{=pos:100,100;activate:;layout:2,2,2,2=}",,,80,30 ,window)

Local btn3:tgadget=CreateListBoxX("{=size:50%;fcolor:200,250,50;bcolor:128,128,128;layout:2,2,2,2;items:One,Two,Three,Four,Five;select:2=}",10,150,100,180,window)

Repeat
	WaitEvent()
	Print CurrentEvent.ToString()
	Select EventID()
		Case EVENT_APPTERMINATE, EVENT_WINDOWCLOSE
			End
	End Select
Forever

Function CreateButtonX:tgadget(tx$,x:Int=0,y:Int=0,w:Int=0,h:Int=0,win:tgadget=Null,style:Int=BUTTON_PUSH)
	
	Local p1:Int,p2:Int,recode:Int,cod:String
	Local gad:tgadget
	
	p1=Instr(tx,"{=")
	p2=Instr(tx,"=}",p1)
	
	If p1>0 And p2>0
		cod=tx[p1+1..p2-1]
		recode=1
		tx=tx[..p1-1]
	End If
	
	gad=CreateButton(tx,x,y,w,h,win,style)
	
	If recode=1 And gad<>Null Special(gad,cod)
	
	Return gad
End Function

Function CreateListBoxX:tgadget(tx$,x:Int=0,y:Int=0,w:Int=0,h:Int=0,win:tgadget=Null,style:Int=BUTTON_PUSH)
	
	Local p1:Int,p2:Int,recode:Int,cod:String
	Local gad:tgadget
	
	p1=Instr(tx,"{=")
	p2=Instr(tx,"=}",p1)
	
	If p1>0 And p2>0
		cod=tx[p1+1..p2-1]
		recode=1
		tx=tx[..p1-1]
	End If
	
	gad=CreateListBox(x,y,w,h,win,style)
	
	If recode=1 And gad<>Null Special(gad,cod)
	
	Return gad
End Function


	Function Special(gad:tgadget,cod:String)
		Local cmd:String[],pars:String[]
		Local cs:String,pss:String
		cmd=cod.split(";")
		For Local s$=EachIn cmd
			cs=s.tolower()
			cs=cs[..cs.find(":")]
			pss=s[s.find(":")+1..]
			pars=pss.split(",")
			
			Select cs
				Case "pos"
					pars=pars[..2]
					SetGadgetShape gad,Int(pars[0]),Int(pars[1]),GadgetWidth(gad),GadgetHeight(gad)
				
				Case "size"
					pars=pars[..2]
					Local ww:Int,hh:Int,done:Int
					ww=Int(pars[0])
					hh=Int(pars[1])
			
					If Instr(pars[0],"%")>0 
						pars[0]=Replace(pars[0],"%","")
						ww=GadgetWidth(gad.parent)*(Float(pars[0])/100)-gad.xpos
					End If
					
					If Instr(pars[1],"%")>0 
						pars[1]=Replace(pars[1],"%","")
						hh=GadgetHeight(gad.parent)*(Float(pars[1])/100)-gad.ypos

					End If
			
					If ww=0 Or ww=-1 ww=GadgetWidth(gad.parent)-gad.xpos
					If hh=0 Or hh=-1 hh=GadgetHeight(gad.parent)-((gad.parent.style & WINDOW_STATUS<>0)*1)-gad.ypos
					
					
					
					SetGadgetShape gad,gad.xpos,gad.ypos,ww,hh
					
					
				Case "title"
					pars=pars[..1]
					SetGadgetText gad,pars[0]
				Case "fcolor"
					pars=pars[..3]
					SetGadgetColor gad,Int(pars[0]),Int(pars[1]),Int(pars[2]),False
				Case "bcolor"
					pars=pars[..3]
					SetGadgetColor gad,Int(pars[0]),Int(pars[1]),Int(pars[2]),True
				Case "disable"
					DisableGadget gad
				Case "enable"
					EnableGadget gad
				Case "layout"
					pars=pars[..4]
					SetGadgetLayout gad,Int(pars[0]),Int(pars[1]),Int(pars[2]),Int(pars[3])
				Case "status"
					pars=pars[..1]
					SetButtonState gad,Int(pars[0])
				Case "activate"
					ActivateGadget gad
					
				Case "items"
					For Local it$=EachIn pars
						AddGadgetItem gad,it
					Next
				Case "select"
					SelectGadgetItem gad,Int(pars[0])
					

			End Select
		Next
	End Function