win/mac custom cursor/pointer module

BlitzMax Forums/MaxGUI Module/win/mac custom cursor/pointer module

skn3	(Posted 2011) [#1]

Hey,

I just finished another maxgui extension module today for setting custom cursors cross platform (well mac and windows ... sorry linux).

The module lets you import a windows.cur file and set it.

Some things to remember
- Store cursor in windows .cur file format
- Store only 1 cursor per .cur file
- In mac mode don't set the cursor right at the start of the program as it wont work (this is a general osx behaviour)
- make sure to manually free the cursor when you are done with it.

Osx supports loading a .cur file into an NSImage object but as far as I could tell has no knowledge of the hotspot a cursor has. I made a simple .cur file parser which will read out the hotspot data and set it for you automatically.

I have tested the code on windows 7 and osx lion.

example

Local pointer:Skn3CustomPointer = LoadCustomPointer("blah.cur")
SetCustomPointer(pointer)
FreeCustomPointer(pointer)

custumcursor.bmx


Import maxgui.drivers
Import brl.filesystem
Import brl.map

?Win32
Extern "Win32"
	Function Skn3LoadCursorFromFile:Int(path$w) = "LoadCursorFromFileW@4"
	Function Skn3DestroyCursor:Int(hcursor:Int) = "DestroyCursor@4"
EndExtern

?MacOs
Import "customcursor.m"
Extern "macos"
	Function skn3_loadCustomPointer:Int(path:String,cursorX:Int,cursorY:Int)
	Function skn3_setCustomPointer:Int(cursor:Int)
	Function skn3_freeCustomPointer:Int(cursor:Int)
	Function skn3_currentCursor:Int()
EndExtern
?

Function LoadCustomPointer:Skn3CustomPointer(path:String)
	' --- this will load a cursor ---
	Local pointer:Skn3CustomPointer
	
	'check for cache
	If Skn3CustomPointer.all = Null
		' make sure teh cursor store is created
		Skn3CustomPointer.all = CreateMap()
	Else
		'check existance
		pointer = Skn3CustomPointer(Skn3CustomPointer.all.ValueForKey(path))
	EndIf
	
	'create new pointer
	If pointer = Null
		'create custom pointer
		pointer = New Skn3CustomPointer
		pointer.path = path
		Skn3CustomPointer.all.Insert(path,pointer)

		'load in os (using path)
		?Win32
		pointer.pointer = Skn3LoadCursorFromFile(path)
		?MacOs
		'first get the offset
		Local offset:Int[] = ExtractCursorHotspot(path)
		'now load the pointer
		pointer.pointer = skn3_loadCustomPointer(path,offset[0],offset[1])
		?
	End If
		
	'return pointer
	If pointer.pointer <> 0
		'increase reference count
		pointer.refCount :+ 1
		Return pointer
	EndIf
End Function

Function SetCustomPointer(pointer:Skn3CustomPointer)
	' --- set the pointer up in os ---
	If pointer
		lastPointer = -1
		?Win32
		SetCursor(pointer.pointer)
		TWindowsGUIDriver._cursor = pointer.pointer
		If TWindowsTextArea._oldCursor Then TWindowsTextArea._oldCursor = pointer.pointer
		?MacOs
		skn3_setCustomPointer(pointer.pointer)
		?
	EndIf
End Function

Function FreeCustomPointer(pointer:Skn3CustomPointer)
	' --- free the pointer ---
	If pointer
		'decrease ref coutn then check
		pointer.refCount :- 1
		If pointer.refCount = 0
			'free in maxguiex
			Skn3CustomPointer.all.remove(pointer.path)
			
			'free in os
			?Win32
			'check if we need to reset in maxgui
			If TWindowsGUIDriver._cursor = pointer.pointer SetPointer(POINTER_DEFAULT)
			
			Skn3DestroyCursor(pointer.pointer)
			pointer.pointer = 0
			?MacOs
			If skn3_currentCursor() = pointer.pointer SetPointer(POINTER_DEFAULT)
			skn3_freeCustomPointer(pointer.pointer)
			?
		EndIf
	EndIf
End Function

Function ExtractCursorHotspot:Int[](path:String,index:Int=0)
	' --- function to extract the hotspot x,y from a cursor ---
	Local result:Int[2]
	
	Local file:TStream = ReadFile("littleendian::"+path)
	If file
		'reserved
		file.seek(2)
		
		'only process cursor types
		Local temp:Int = file.ReadShort()
		If temp = 2
			'only process if valid index
			temp = file.ReadShort()
			If index < temp
				'only process if offset isnt beyond file length
				temp = 6+(12*index)+4
				If temp < file.size()
					file.seek(temp)
					result[0] = file.ReadShort()
					result[1] = file.ReadShort()
				EndIf
			EndIf
		EndIf
		
		'close the stream
		file.close()
	EndIf
	
	'return the result
	Return result
End Function

Type Skn3CustomPointer
	Global all:TMap
	Field path:String
	Field pointer:Int
	Field refCount:Int
End Type

customcursor.h

NSCursor * skn3_loadCustomPointer(BBString *path,int hotspotX,int hotspotY);
void skn3_setCustomPointer(NSCursor *cursor);
void skn3_freeCustomPointer(NSCursor *cursor);
NSCursor * skn3_currentCursor();

customcursor.m

NSCursor * skn3_loadCustomPointer(BBString *path,int hotspotX,int hotspotY) {
	//load image
	NSImage * image = [[NSImage alloc] initWithContentsOfFile:[NSString stringWithCString:bbStringToCString(path)]];
	
	//create cursor
	NSCursor * cursor = [[NSCursor alloc] initWithImage: image hotSpot:NSMakePoint(hotspotX,hotspotY)];
	
	[image release];
	
	//return as int handle
	return cursor;
}

void skn3_setCustomPointer(NSCursor *cursor) {
	[cursor set];
}

void skn3_freeCustomPointer(NSCursor *cursor) {
	[cursor release];
}

NSCursor * skn3_currentCursor() {
	return [NSCursor currentCursor];
}

Last edited 2011

Last edited 2011

Last edited 2011

skn3	(Posted 2011) [#2]

.

Last edited 2012