Change icon bmax in Confirm

BlitzMax Forums/MaxGUI Module/Change icon bmax in Confirm

mongia2

(Posted 2012) [#1]

My problem is:
change a icon in the confirm

result=Confirm("Are you sure?")

GfK	(Posted 2012) [#2]

You can set the Serious flag to True, but that's pretty much it.

matibee

(Posted 2012) [#3]

That is pretty much it. The alternative is to build a custom dialog.

Here's mine:

SuperStrict 
Import maxgui.drivers

Incbin "incbin/Delete.png"

'-----------------------------------------------------------------------------------------------------------------
'-----------------------------------------------------------------------------------------------------------------
Type ProceedWindow

	Global twYES:TGadget
	Global twNO:TGadget
	
	Global tWindow:TGadget
	
	Global twCaption:TGadget
	
	Global yes$ = "YES"
	Global no$ = "NO"
	Global cancel$ = "CANCEL"
	Global title$ = "Proceed?"
	Global caption$ = ".."
	
	Global inited:Int = False 
	
	'------------------------------------------------------------------------------------------------------------
	Function Init( window:TGadget )
		
		Local winwidth:Int = 380
		Local winheight:Int = 200
		
		tWindow = CreateWindow( title$, 0, 0, winwidth, winheight, window, ..
									WINDOW_TITLEBAR | WINDOW_CENTER | WINDOW_HIDDEN )

		twYES = CreateButton( yes$, 80, winheight - 110, winwidth - 100, 25, tWindow )
		twNO = CreateButton( no$, 80, winheight - 76, winwidth - 100, 30, tWindow )
		
		twCaption = CreateLabel( caption$, 84, 8, winwidth - 108, winheight - 130, tWindow )
		SetGadgetFont( twCaption, LoadGuiFont( "arial", 10, True ) )
		
		Local p:TGadget = CreatePanel( 14, 20, 52, 52, tWindow )
		SetGadgetPixmap( p, LoadPixmap( "incbin::incbin/Delete.png" ) )
		
		inited = True 
		 
	End Function 
	'------------------------------------------------------------------------------------------------------------
	Function Show:Int ( window:TGadget, _titlemsg$, _captionmsg$, _yesmsg$, _nomsg$, ..
						paintBackgroundCB() = Null  )
		
		yes$ = _yesmsg$
		no$ = _nomsg$

		title$ = _titlemsg$
		caption$ = _captionmsg$
		
		If ( Not inited ) 
			Init( window )
		Else 
			SetGadgetText( twYES, yes$ )
			SetGadgetText( twNO, no$ )
			SetGadgetText( twCAPTION, caption$ )
		End If 
		
		ShowGadget( tWindow )
		
		ActivateGadget( twNO )
		
		Repeat
			WaitEvent()
			Select EventID()
			Case EVENT_GADGETACTION
				HideGadget( twindow )
				Select EventSource()
				Case twYES
					Return 1
				Case twNO
					Return 0
				End Select 
			Case EVENT_WINDOWCLOSE
				HideGadget( twindow )
				Return 0
			Case EVENT_GADGETPAINT
				If ( paintBackgroundCB )	paintBackgroundCB()
			End Select 
		Forever 
		
		Return 0
	End Function 
	'------------------------------------------------------------------------------------------------------------
End Type

Use with caution: it's something I knocked up recently but I'm not sure it's 100% perfect.

Last edited 2012