Help with converting Blitz3D to MiniB3d...

BlitzMax Forums/MiniB3D Module/Help with converting Blitz3D to MiniB3d...

JA2	(Posted 2010) [#1]

Hi,
I'm trying to convert some Blitz3D code to MiniB3d. It's for toon shading without using shaders etc I've had a go at doing this myself but something's not working correctly. I'm using a slightly modified MiniB3D to use 2d drawing. Any help greatly appreciated :)

BB

Global CelTexture

Type CelShaded
	Field Mesh,OutLine
End Type

Function LinearGradient (Shades,Dir)

Local Steps

Repeat
	If Dir = 0
		Color 255-Steps*(255/Shades),255-Steps*(255/Shades),255-Steps*(255/Shades)
	Else
		Color Steps*(255/Shades),Steps*(255/Shades),Steps*(255/Shades)
	EndIf
	Steps = Steps + 1
	Rect 0,-256/Shades+Steps*256/Shades,256,256/Steps,True
Until Steps = Shades

End Function

Function CelShader (Shades=3)

	Local CD.CelShaded
	
	If Shades < 1 Then Return
	Local Camera = CreateCamera()
	Local Light = CreatePivot()
	Local Sphere = CreateSphere (12)
	Local Texture = CreateTexture (1,256,16+32)
	For CD.CelShaded = Each CelShaded
		Delete CD
	Next
	If CelTexture <> 0
		FreeTexture CelTexture
		CelTexture = 0
	EndIf
	CelTexture = CreateTexture (256,256,16+32+64+256)
	LinearGradient (Shades,0)
	CopyRect 0,0,256,256,0,0,BackBuffer(),TextureBuffer(Texture)
	Planer (Sphere)
	EntityFX Sphere,1
	RotateMesh Sphere,90,0,0
	PositionEntity Sphere,0,65536,65536
	EntityTexture Sphere,Texture
	PositionEntity Light,0,65536+65536,65536-16384
	PointEntity Sphere,Light
	CameraZoom Camera,2
	CameraViewport Camera,0,0,256,256
	PositionEntity Camera,0,65536,65536-2.21
	Cls 
	RenderWorld
	CopyRect 0,0,256,256,0,0,BackBuffer(),TextureBuffer(CelTexture)
	FreeTexture Texture
	FreeEntity Camera
	FreeEntity Light
	FreeEntity Sphere
	Cls

End Function

Function CelShade (Mesh,Index=0)

	Local A
	Local Children = CountChildren (Mesh)
	
	If EntityClass (Mesh) = "Mesh"
		Local CD.CelShaded = New CelShaded
		CD\Mesh	= Mesh
		If Index = 0
			EntityTexture Mesh,CelTexture,0,1
			EntityFX Mesh,1
		Else
			Local Brush	= CreateBrush()
			Surface = GetSurface (Mesh,Index)
			BrushFX Brush,1
			BrushTexture Brush,CelTexture,0,1
			PaintSurface Surface,Brush
			FreeBrush Brush
		EndIf
	EndIf
	If Children = 0 Then Return
	For A = 1 To Children
		Local Child = GetChild (Mesh,A)
		CelShade (Child,Index)
	Next

End Function

Function Planer (Mesh)

	Local A,B
	Local Height# = MeshHeight (Mesh)
	Local Surfaces = CountSurfaces (Mesh)
	
	For A = 1 To Surfaces
		Local Surface = GetSurface (Mesh,A)
		Local Vertices = CountVertices(Surface)
		For B = 0 To Vertices-1
			Local Y# = (VertexY(Surface,B)/Height) + 0.5
			VertexTexCoords Surface,B,0.5,1.0-Y
		Next
	Next
	
End Function

Graphics3D 640,480,0,2
SetBuffer BackBuffer()

Local Camera = CreateCamera()
Local Light = CreateLight()
Local Mesh = CreateCone()

MoveEntity Mesh,0,0,3
CameraClsColor Camera,50,50,50

CelShader (5)
CelShade (Mesh)

While Not KeyDown (1)

	Cls

	TurnEntity Mesh,0.1,0.2,0.3
	
	UpdateWorld
	RenderWorld
	
	Flip

Wend
End

BMX

Import sidesign.minib3d

Global CelTexture:TTexture

Type CelShaded

	Field Mesh:TMesh
	
End Type

Function LinearGradient (Shades:Int,Dir:Int=0)

	TGlobal.BeginMax2D

	Local Steps:Int
	Repeat
		If Dir = 0
			SetColor 255-Steps*(255/Shades),255-Steps*(255/Shades),255-Steps*(255/Shades)
		Else
			SetColor Steps*(255/Shades),Steps*(255/Shades),Steps*(255/Shades)
		EndIf
		Steps = Steps + 1
		DrawRect 0,-256/Shades+Steps*256/Shades,256,256/Steps
	Until Steps = Shades
	
	TGlobal.EndMax2D

End Function

Function CelShader (Shades:Int=3)
	
	If Shades < 1 Then Return
	Local Camera:TCamera = CreateCamera()
	Local light:TPivot = CreatePivot()
	Local Sphere:TMesh = CreateSphere (12)
	Local Texture:TTexture = CreateTexture (1,256,16+32)
	If CelTexture <> Null
		FreeTexture CelTexture
		CelTexture = Null
	EndIf
	LinearGradient (Shades,0)
	BackBufferToTex (Texture)
	Planer (Sphere)
	EntityFX Sphere,1
	RotateMesh Sphere,90,0,0
	PositionEntity Sphere,0,65536,65536
	EntityTexture Sphere,Texture
	PositionEntity light,0,65536+65536,65536-16384
	PointEntity Sphere,Light
	CameraZoom Camera,2
	CameraViewport Camera,0,0,256,256
	PositionEntity Camera,0,65536,65536-2.21
	CelTexture = CreateTexture (256,256,16+32+64+256)
	RenderWorld
	BackBufferToTex (CelTexture)
	FreeTexture Texture
	FreeEntity Camera
	FreeEntity Light
	FreeEntity Sphere

End Function

Function CelShade (Mesh:TMesh,Index:Int=0)
	
	Local Children:Int = CountChildren (Mesh)
	If EntityClass (Mesh) = "Mesh"
		Local CD:CelShaded = New CelShaded
		CD.Mesh	= Mesh
		If Index = 0
			EntityTexture Mesh,CelTexture,0,1
			EntityFX Mesh,1
		Else
			Local Brush:TBrush = CreateBrush()
			Surface = GetSurface (Mesh,Index)
			BrushFX Brush,1
			BrushTexture Brush,CelTexture,0,1
			PaintSurface Surface,Brush
			FreeBrush Brush
		EndIf
	EndIf
	If Children = 0 Then Return
	For A:Int = 1 To Children
		Local Child = GetChild (Mesh,A)
		CelShade (Child,Index)
	Next

End Function

Function Planer (Mesh:TMesh)

	Local Height:Float = MeshHeight (Mesh)
	Local Surfaces:Int = CountSurfaces (Mesh)
	For A:Int = 1 To Surfaces
		Local Surface = GetSurface (Mesh,A)
		Local Vertices = CountVertices (Surface)
		For B:Int = 0 To Vertices-1
			Local Y:Float = (VertexY(Surface,B)/Height)+0.5
			VertexTexCoords Surface,B,0.5,1.0-Y
		Next
	Next

End Function

Graphics3D 640,480,16,0
ClearTextureFilters

Local Cam:TCamera = CreateCamera()
Local light:TLight = CreateLight()
Local Mesh:TMesh = CreateCone()

PositionEntity Mesh,0,0,3
CameraClsColor Cam,50,50,50

CelShader (5)
CelShade (Mesh)

While Not KeyDown (KEY_ESCAPE)

	TurnEntity Mesh,0.1,0.2,0.3

	UpdateWorld
	RenderWorld
	
	Flip
	
Wend
End

jkrankie

(Posted 2010) [#2]

http://www.blitzbasic.com/Community/posts.php?topic=79166#889143

Cheers
Charlie

JA2	(Posted 2010) [#3]

Hi, that is actually my old post. Nobody posted an updated BlitzMax version of it tho so I'm finally getting around to trying it myself.

JA2	(Posted 2010) [#4]

I've made a little progress:

Import sidesign.minib3d

'Global CelTexture:TTexture = CreateTexture (256,256,16+32+64+256)
Global CelTexture:TTexture = CreateTexture (256,256,64+256)

Type CelShaded

	Field Mesh:TMesh
	
End Type

Function LinearGradient (Shades:Int)

	TGlobal.BeginMax2D

	Local Steps:Int
	Repeat
		SetColor 255-Steps*(255/Shades),255-Steps*(255/Shades),255-Steps*(255/Shades)
		Steps = Steps + 1
		DrawRect 0,-256/Shades+Steps*256/Shades,256,256/Steps
	Until Steps = Shades
	
	TGlobal.EndMax2D

End Function
	
Function CelShader (Shades:Int=3)
	
	If Shades < 1 Then Return
	Local Camera:TCamera = CreateCamera()
	Local Light:TPivot = CreatePivot()
	Local Sphere:TMesh = CreateSphere (12)
	Local Texture:TTexture = CreateTexture (1,256,16+32)
	LinearGradient (Shades)
	BackBufferToTex (Texture)
	Planer (Sphere)
	EntityFX Sphere,1
	RotateMesh Sphere,90,0,0
	PositionEntity Sphere,0,65536,65536
	EntityTexture Sphere,Texture
	PositionEntity Light,0,65536+65536,65536-16384
	PointEntity Sphere,Light
	CameraZoom Camera,2
	CameraViewport Camera,0,0,256,256
	PositionEntity Camera,0,65536,65536-2.21
	RenderWorld
	BackBufferToTex (CelTexture)
	'FreeTexture Texture
	'FreeEntity Camera
	'FreeEntity Light
	'FreeEntity Sphere
	
End Function

Function CelShade (Mesh:TMesh,Index:Int=0)
	
	Local Children:Int = CountChildren (Mesh)
	If EntityClass (Mesh) = "Mesh"
		Local CD:CelShaded = New CelShaded
		CD.Mesh	= Mesh
		If Index = 0
			EntityTexture Mesh,CelTexture,0,1
			EntityFX Mesh,1
		Else
			Local Brush:TBrush = CreateBrush()
			Surface = GetSurface (Mesh,Index)
			BrushFX Brush,1
			BrushTexture Brush,CelTexture,0,1
			PaintSurface Surface,Brush
			FreeBrush Brush
		EndIf
	EndIf
	If Children = 0 Then Return
	For A:Int = 1 To Children
		Local Child = GetChild (Mesh,A)
		CelShade (Child,Index)
	Next

End Function

Function Planer (Mesh:TMesh)

	Local Height:Float = MeshHeight (Mesh)
	Local Surfaces:Int = CountSurfaces (Mesh)
	For A:Int = 1 To Surfaces
		Local Surface = GetSurface (Mesh,A)
		Local Vertices = CountVertices (Surface)
		For B:Int = 0 To Vertices-1
			Local Y:Float = (VertexY(Surface,B)/Height)+0.5
			VertexTexCoords Surface,B,0.5,1.0-Y
		Next
	Next

End Function

Graphics3D 640,480,16,0
ClearTextureFilters

Local Cam:TCamera = CreateCamera()
Local light:TLight = CreateLight()
Local Mesh:TMesh = CreateCone()

PositionEntity Mesh,0,0,3
CameraClsColor Cam,50,50,50

CelShader (5)
CelShade (Mesh)

While Not KeyDown (KEY_ESCAPE)

	TurnEntity Mesh,0.1,0.2,0.3

	UpdateWorld
	RenderWorld
	
	'Works okay here but not using 2nd camera in CelShader() ???
	
	If KeyHit (KEY_SPACE)
		CameraViewport Cam,0,0,256,256
		BackBufferToTex (CelTexture)
		CameraViewport Cam,0,0,640,480
	EndIf
	
	Flip
	
Wend
End

Using texture flags 16+32 makes a strange looking texture. The texture looks correct with the flags are removed but messes up when the mesh it's applied to is rotated (because of the clamping?)

Also, copying the backbuffer to the CelTexture doesn't work correctly in the CelShader() function. Pressing 'space' in the above code renders the sphere in the top left of the screen to the CelTexture.

Any ideas?

[edit]Okay, I got this to work in the CelShader() function by simply calling RenderWorld twice :)[/edit]

JA2	(Posted 2010) [#5]

Sorry to keep bumping my own thread but I think that the problem is with using texture flag 32 (Clamp V). Is this a bug with MiniB3D?

Import sidesign.minib3d

Global Texture1:TTexture = CreateTexture (256,256,16+64+256)
Global Texture2:TTexture = CreateTexture (256,256,16+32+64+256)

Function LinearGradient (Shades:Int)

	TGlobal.BeginMax2D

	Local Steps:Int
	Repeat
		SetColor 255-Steps*(255/Shades),255-Steps*(255/Shades),255-Steps*(255/Shades)
		Steps = Steps + 1
		DrawRect 0,-256/Shades+Steps*256/Shades,256,256/Steps
	Until Steps = Shades
	
	TGlobal.EndMax2D

End Function

Graphics3D 640,480,16,0

Local Cam:TCamera = CreateCamera()
Local light:TLight = CreateLight()
Local Mesh1:TMesh = CreateCube()
Local Mesh2:TMesh = CreateCube()

CameraViewport Cam,0,0,256,256
LinearGradient (5)
BackBufferToTex (Texture1)
BackBufferToTex (Texture2)
CameraViewport Cam,0,0,640,480

EntityTexture Mesh1,Texture1
EntityTexture Mesh2,Texture2
MoveEntity Mesh1,-2,0,5
MoveEntity Mesh2,2,0,5

While Not KeyDown (KEY_ESCAPE) And Not AppTerminate()

	TurnEntity Mesh1,1,0,0
	TurnEntity Mesh2,1,0,0

	UpdateWorld
	RenderWorld
	
	Flip
	
Wend
End

simonh

(Posted 2010) [#6]

I tried your example, and it crashed - I had to move the CreateTexture calls to below Graphics3D to get it working. Once I got it working, I couldn't tell what the problem was supposed to be - can you explain?

JA2	(Posted 2010) [#7]

Hi Simon.

When using texture flag 32, my texture looks like this:

It looks correct in Blitz3D on the right. Using Psionic's ninja model for testing here but it looks the same with any models I try. It only does this with flag 32. I've even moved the CreateTexture calls to below Graphics3D even tho it was working for me before...

Import sidesign.minib3d

Type CelShaded

	Field Mesh:TMesh
	
End Type

Function LinearGradient (Shades:Int)

	TGlobal.BeginMax2D

	Local Steps:Int
	Repeat
		SetColor 255-Steps*(255/Shades),255-Steps*(255/Shades),255-Steps*(255/Shades)
		Steps = Steps + 1
		DrawRect 0,-256/Shades+Steps*256/Shades,256,256/Steps
	Until Steps = Shades
	
	TGlobal.EndMax2D

End Function
	
Function CelShader (Shades:Int=3)
	
	If Shades < 1 Then Return
	Local Camera:TCamera = CreateCamera()
	Local Light:TPivot = CreatePivot()
	Local Sphere:TMesh = CreateSphere (12)
	Local Texture:TTexture = CreateTexture (1,256,16+32)
	CameraViewport Camera,0,0,256,256
	LinearGradient (Shades)
	BackBufferToTex (Texture)
	Planer (Sphere)
	EntityFX Sphere,1
	RotateMesh Sphere,90,0,0
	PositionEntity Sphere,0,65536,65536
	EntityTexture Sphere,Texture
	PositionEntity Light,0,65536+65536,65536-16384
	PointEntity Sphere,Light
	CameraZoom Camera,2
	'CameraViewport Camera,0,0,256,256
	PositionEntity Camera,0,65536,65536-2.21
	RenderWorld
	RenderWorld
	BackBufferToTex (CelTexture)
	FreeTexture Texture
	FreeEntity Camera
	FreeEntity Light
	FreeEntity Sphere
	
End Function

Function CelShade (Mesh:TMesh,Index:Int=0)
	
'	Local Children:Int = CountChildren (Mesh)
	If EntityClass (Mesh) = "Mesh"
		Local CD:CelShaded = New CelShaded
		CD.Mesh	= Mesh
		If Index = 0
			EntityTexture Mesh,CelTexture,0,1
			EntityFX Mesh,1
		Else
			Local Brush:TBrush = CreateBrush()
			Surface = GetSurface (Mesh,Index)
			BrushFX Brush,1
			BrushTexture Brush,CelTexture,0,1
			PaintSurface Surface,Brush
			FreeBrush Brush
		EndIf
	EndIf
'	If Children = 0 Then Return
'	For A:Int = 1 To Children
'		Local Child = GetChild (Mesh,A)
'		CelShade (Child,Index)
'	Next

End Function

Function Planer (Mesh:TMesh)

	Local Height:Float = MeshHeight (Mesh)
	Local Surfaces:Int = CountSurfaces (Mesh)
	For A:Int = 1 To Surfaces
		Local Surface = GetSurface (Mesh,A)
		Local Vertices = CountVertices (Surface)
		For B:Int = 0 To Vertices-1
			Local Y:Float = (VertexY(Surface,B)/Height)+0.5
			VertexTexCoords Surface,B,0.5,1.0-Y
		Next
	Next

End Function

Graphics3D 640,480,16,0
ClearTextureFilters

Global CelTexture:TTexture = CreateTexture (256,256,16+32+64+256)
'Global CelTexture:TTexture = CreateTexture (256,256,16+64+256)

Local Cam:TCamera = CreateCamera()
Local light:TLight = CreateLight()
Local Mesh:TMesh = LoadMesh ("Testing\Ninja.b3d")

MoveEntity Mesh,0,-5,10

CelShader (4)
CelShade (Mesh)

While Not KeyDown (KEY_ESCAPE) And Not AppTerminate()

	TurnEntity Mesh,0.0,0.5,0.0

	UpdateWorld
	RenderWorld
	
	Flip
	
Wend
End