[Windows] Some fun with drawing on the desktop

BlitzMax Forums/BlitzMax Programming/[Windows] Some fun with drawing on the desktop

grable

(Posted 2017) [#1]

After the thread in General Help by Mainswhorty, about drawing to desktop i found this: https://www.codeproject.com/articles/856020/draw-behind-desktop-icons-in-windows

The code there deals with drawing BEHIND the desktop icons, and was quite fun working out.
Im posting it here for future reference and for others to have fun with as well :)

Drawing using GDI, only works in Windows 8+. Though maybe one can draw directly to the shell window instead of the worker?


SuperStrict

SeedRnd MilliSecs()

Local workerw:Int = SpawnDesktopWorkerWindow()
If Not workerw Then Throw "no desktop worker window!"

Local dc:Int = GetDCEx( workerw, 0, DCX_WINDOW | DCX_CACHE | DCX_LOCKWINDOWUPDATE)
Local time:Int
Repeat
	TextOut dc, Rand(DesktopWidth()), Rand(DesktopHeight()), "Hello Desktop!"
	Delay 50
	time :+ 50
Until time >= 5000
ReleaseDC( workerw, dc)
CloseDesktopWorkerWindow(workerw)
End


Function TextOut:Int( dc:Int, x:Int,y:Int, s:String)
	Extern "Win32"
		Function TextOut_:Int( dc:Int, x:Int,y:Int, s$w, sz:Int) = "TextOutW@20"
	EndExtern
	Return TextOut_( dc, x,y, s, s.Length)
EndFunction


Extern "Win32"
	Const SPAWN_DESKTOP_WOKER_WINDOW:Int = $052C
	
	Const SMTO_NORMAL:Int = $0000
	
	Const RDW_INVALIDATE:Int = $0001
	Const RDW_ERASE:Int = $0004
	
	Const RDW_UPDATENOW:Int = $0100
	Const RDW_ERASENOW:Int = $0200
	
	
	Const DCX_WINDOW:Int = $00000001
	Const DCX_CACHE:Int = $00000002
	Const DCX_LOCKWINDOWUPDATE:Int = $00000400

	Function GetShellWindow:Int()
	Function EnumWindows:Int( enumproc:Byte Ptr, lparam:Int)
	Function FindWindowExW:Int( hwndparent:Int, hwndchildafter:Int, classname$w, windowtitle$w)	
	Function SendMessageW:Int( hwnd:Int, msg:Int, wparam:Int, lparam:Int)
	Function SendMessageTimeoutW:Int( hwnd:Int, msg:Int, wparam:Int, lparam:Int, mode:Int, timeout:Int, result:Byte Ptr)
	Function GetDCEx:Int( hwnd:Int, region:Int, flags:Int)
	Function ReleaseDC:Int( hwnd:Int, dc:Int)
EndExtern

Function SpawnDesktopWorkerWindow:Int( timeout:Int = 1000)
	Local shell:Int = GetShellWindow()
	Local result:Int
	SendMessageTimeoutW( shell, SPAWN_DESKTOP_WOKER_WINDOW, 0, 0, SMTO_NORMAL, timeout, Varptr result)
		
	Function enumproc:Int( tophwnd:Int, lparam:Int) "win32"
		Local hwnd:Int = FindWindowExW( tophwnd, 0, "SHELLDLL_DefView", Null)
		If hwnd Then
			hwnd = FindWindowExW( 0, tophwnd, "WorkerW", Null)
			If hwnd Then Int Ptr(lparam)[0] = hwnd
		EndIf
		Return True
	EndFunction
	
	Local hwnd:Int
	EnumWindows( Byte Ptr enumproc, Int Varptr hwnd)
	
	Return hwnd
EndFunction

' doesnt close the window, only clears it. as it functions as a singleton.
Function CloseDesktopWorkerWindow( hwnd:Int, timeout:Int = 1000)
'	RedrawWindow( hwnd, Null, Null, RDW_ERASE | RDW_INVALIDATE | RDW_ERASENOW | RDW_UPDATENOW)
	ShowWindow( hwnd, False)
	ShowWindow( hwnd, True)	
EndFunction

Drawing using Max2D and a seperate window, works in Windows 8+ but check further down for code to make it work on Windows 7:


SuperStrict

WindowGraphics()
Local hwnd:Int = GetBlitzmaxWindow()

Local workerw:Int = SpawnDesktopWorkerWindow()
If Not workerw Then Throw "no desktop worker window!"
SetParent( hwnd, workerw)

SeedRnd MilliSecs()
Local time:Int
Repeat
	
	SetColor Rand(256),Rand(256),Rand(256)
	DrawRect Rand(DesktopWidth()), Rand(DesktopHeight()), Rand(100), Rand(100)
	
	Flip
'	Cls
	
	time :+ 10
Until time >= 5000
EndGraphics
CloseDesktopWorkerWindow(workerw)
End


Function TextOut:Int( dc:Int, x:Int,y:Int, s:String)
	Extern "Win32"
		Function TextOut_:Int( dc:Int, x:Int,y:Int, s$w, sz:Int) = "TextOutW@20"
	EndExtern
	Return TextOut_( dc, x,y, s, s.Length)
EndFunction


Extern "Win32"
	Const SPAWN_DESKTOP_WOKER_WINDOW:Int = $052C
	
	Const SMTO_NORMAL:Int = $0000
	
	Const RDW_INVALIDATE:Int = $0001
	Const RDW_ERASE:Int = $0004
	
	Const RDW_UPDATENOW:Int = $0100
	Const RDW_ERASENOW:Int = $0200
	
	
	Const DCX_WINDOW:Int = $00000001
	Const DCX_CACHE:Int = $00000002
	Const DCX_LOCKWINDOWUPDATE:Int = $00000400

	Function GetShellWindow:Int()
	Function EnumWindows:Int( enumproc:Byte Ptr, lparam:Int)
	Function FindWindowExW:Int( hwndparent:Int, hwndchildafter:Int, classname$w, windowtitle$w)	
	Function SendMessageW:Int( hwnd:Int, msg:Int, wparam:Int, lparam:Int)
	Function SendMessageTimeoutW:Int( hwnd:Int, msg:Int, wparam:Int, lparam:Int, mode:Int, timeout:Int, result:Byte Ptr)
	Function SetParent:Int( hwnd:Int, hwndparent:Int)
EndExtern

Function SpawnDesktopWorkerWindow:Int( timeout:Int = 1000)
	Local shell:Int = GetShellWindow()
	Local result:Int
	SendMessageTimeoutW( shell, SPAWN_DESKTOP_WOKER_WINDOW, 0, 0, SMTO_NORMAL, timeout, Varptr result)
		
	Function enumproc:Int( tophwnd:Int, lparam:Int) "win32"
		Local hwnd:Int = FindWindowExW( tophwnd, 0, "SHELLDLL_DefView", Null)
		If hwnd Then
			hwnd = FindWindowExW( 0, tophwnd, "WorkerW", Null)
			If hwnd Then Int Ptr(lparam)[0] = hwnd
		EndIf
		Return True
	EndFunction
	
	Local hwnd:Int
	EnumWindows( Byte Ptr enumproc, Int Varptr hwnd)
	
	Return hwnd
EndFunction

' doesnt close the window, only clears it. as it functions as a singleton.
Function CloseDesktopWorkerWindow( hwnd:Int, timeout:Int = 1000)
'	RedrawWindow( hwnd, Null, Null, RDW_ERASE | RDW_INVALIDATE | RDW_ERASENOW | RDW_UPDATENOW)
	ShowWindow( hwnd, False)
	ShowWindow( hwnd, True)	
EndFunction



Function GetBlitzmaxWindow:Int()
?Win32
	Extern "Win32"
		Function FindWindowA:Int( classname$z, windowtitle$z)	
	EndExtern
	Local handle:Int
	handle = FindWindowA( "BBDX9Device Window Class", AppTitle)								' D3D9Max2D
	If Not handle Then handle = FindWindowA( "BlitzMax GLGraphics", AppTitle)			' GLMax2D
	If Not handle Then handle = FindWindowA( "BBDX7Device Window Class", AppTitle)	' D3D7Max2D
	If Not handle Then handle = FindWindowA( "BLITZMAX_WINDOW_CLASS", AppTitle)		' MaxGUI
	Return handle
?
EndFunction

Function WindowGraphics:TGraphics( depth:Int = 0, hz:Int = 60, flags:Int = 0)
	Extern "Win32"
		Const SPI_GETWORKAREA:Int = $30
		
		Function SystemParametersInfoW:Int( action:Int, param1:Int, param2:Byte Ptr, winini:Int)
	EndExtern

	' get size of desktop minus taskbar/toolbars
	Local rect:Int[4]
	SystemParametersInfoW( SPI_GETWORKAREA, 0, rect, 0)
	
	Local g:TGraphics = Graphics( rect[2], rect[3], depth, hz, flags)
	Local hwnd:Int = GetBlitzmaxWindow()
	Assert hwnd Else "unable to find BlitzMax window"

	' remove window frame
	Local wflags:Int = GetWindowLongW( hwnd, GWL_STYLE)	
	SetWindowLongW( hwnd, GWL_STYLE, wflags & ~WS_CAPTION)
	SetWindowPos( hwnd, HWND_TOP, 0,0,0,0, SWP_FRAMECHANGED | SWP_NOZORDER | SWP_NOMOVE | SWP_NOSIZE | SWP_HIDEWINDOW)

	' force window refresh
	Cls
	
	' update window
	SetWindowPos( hwnd, HWND_TOP, rect[0],rect[1], rect[2], rect[3], SWP_NOZORDER | SWP_SHOWWINDOW)
	
	Return g
EndFunction

GW	(Posted 2017) [#2]

Doesn't work for me. win7 pro. the exception is thrown.

grable

(Posted 2017) [#3]

Ah yes, i forgot to add, this works for Win 8+, same as the article.
To get it to work for Windows 7, you would have to change the enumeration proc, i think you can change "SHELLDLL_DefView" to "SysListView32".
I dont have Windows 7 so am unable to test myself, but you can read the article and then try something like WinSpy to check the window relations.

grable

(Posted 2017) [#4]

There is a comment in that article which mentions how to do it for Windows 7, could work for the second example:

- Create the second WorkerW with the hidden user message as described here.
- Hide this new WorkerW that you just created with ShowWindow().
- Create your new custom window, that you want to draw behind the desktop icons, as a child of Progman.

But again, the relationship between windows is different, so a change to the enumeration proc still has to be made so one can find the WorkerW window.

EDIT: Progman is the Shell window btw.

EDIT2: Had a friend with Windows 7 test for me, for the second example:
Change

SetParent( hwnd, workerw)

SetParent( hwnd, GetShellWindow())
ShowWindow( workerw, False)

BlitzSupport

(Posted 2017) [#5]

Yeah, EDIT2 works here on '7, pretty cool. Opens a huge ugly window to start with, but I imagine that could be hidden with a little hackery...

grable

(Posted 2017) [#6]

Yeah, the reason for that is because its using a Graphics window. And it is created AND shown before the changes are made to it, making it flicker (on slower computers anyway, i dont see it :p)

Theres no way around this without modifying the Max2D backends im afraid.
Using MaxGUI though, you can create the window hidden then show it after the changes, which works.