Loading progress...

BlitzMax Forums/BlitzMax Programming/Loading progress...

orgos

(Posted 2009) [#1]

Hi people, i have problem to implement a loading feature.

I have my process to load resources, thats consist in a couple of lines reading the resources, imgs, sounds, and fonts.

I update my progress bar on each loaded resources, but now i want to make another load screen with some dinamics animations.

So i want to have a real progress of my loads and in the same screen while loading have a sprites animations.

What can be the best way to implement it?

GfK	(Posted 2009) [#2]

You need to load your resources in a separate thread, whilst running the loading animation or whatever in the main thread until the 'loading' thread ends.

Apparently graphics contexts are not thread-safe so you shouldn't do it the other way around, i.e. don't load graphics in the main thread and run the loading anim in a sub thread.

BlitzSupport

(Posted 2009) [#3]

Assuming you have the latest version of BlitzMax installed, check \samples\threads\background_loading.bmx for an example.

GfK	(Posted 2009) [#4]

Assuming you have the latest version of BlitzMax installed, check \samples\threads\background_loading.bmx for an example.

I didn't understand that bit of code last time you told me about it. Its a cracking bit of code, now that I understand Tmaps!

BlitzSupport

(Posted 2009) [#5]

Looking at it again, that code was really confusing, given it was only meant to be a simple example. I tried to make it too generic when I should have just hard-coded a bunch of global filenames.

I've just done a quick hack-job to make it work with simple arrays of pixmaps/images/filenames -- save this into the \samples\threads folder and run:


' -----------------------------------------------------------------------------
' MAKE SURE "Threaded Build" IS CHECKED IN THE Program -> Build Options menu!
' -----------------------------------------------------------------------------





' -----------------------------------------------------------------------------
' Loading screen...
' -----------------------------------------------------------------------------

AppTitle = "Multi-threaded loading screen demo..."

' -----------------------------------------------------------------------------
' This is used to simulate slower loading in the LoadPixmaps thread...
' -----------------------------------------------------------------------------

Global TestDelay = 1000 ' Simulating more/larger images, 3D models, etc...

' -----------------------------------------------------------------------------
' Array setup...
' -----------------------------------------------------------------------------

Global pixnum:Int = 6			' Number of pixmaps/images to be loaded

Global pix:TPixmap [pixnum]		' Pixmap handles for loading thread

Global pixname:String [pixnum]	' Filenames

	pixname [0] = "bluboing.png"
	pixname [1] = "bluegem.png"
	pixname [2] = "boing.png"
	pixname [3] = "dead.png"
	pixname [4] = "greengem.png"
	pixname [5] = "redgem.png"

' -----------------------------------------------------------------------------
' Set up display...
' -----------------------------------------------------------------------------

Graphics 640, 480
SetClsColor 32, 96, 128
SetMaskColor 255, 0, 255
AutoMidHandle True

' -----------------------------------------------------------------------------
' Start the LoadPixmaps thread...
' -----------------------------------------------------------------------------

thread:TThread = CreateThread (LoadPixmaps, Null)

' -----------------------------------------------------------------------------
' This is the loading screen! Some movement and colours while pixmaps load...
' -----------------------------------------------------------------------------

r = 0; g = 255; b = 127

' -----------------------------------------------------------------------------
' Do this routine until the thread has finished its work...
' -----------------------------------------------------------------------------

While ThreadRunning (thread) ' Important!

	Cls

	r = r + 8; If r > 255 Then r = 0
	g = g - 4; If g > 255 Then g = 0
	b = b + 2; If b > 255 Then b = 0

	SetColor 0, 0, 0	
	DrawRect MouseX (), MouseY (), 32, 32

	SetColor r, g, b
	DrawRect MouseX (), MouseY (), 30, 30

	SetColor 0, 0, 0
	DrawText "Slow-ding, please wait...", 20, 20
	SetColor 255, 255, 255
	DrawText "Slow-ding, please wait...", 18, 18

	Flip

Wend

' -----------------------------------------------------------------------------
' Right, the thread has finished. Should have a nice array filled with pixmaps!
' -----------------------------------------------------------------------------

' Just re-setting colours, 'scuse me...

r = 255; g = 255; b = 255
SetColor r, g, b


' -----------------------------------------------------------------------------
' Load images from pixmaps and free all TPixmap objects...
' -----------------------------------------------------------------------------

Global image:TImage [pixnum]	' Array of images to receive pixmap contents

' Load images, free pixmaps...

For p = 0 To pixnum - 1
	image [p] = LoadImage (TPixmap (pix [p]))
	pix [p] = Null
Next

' -----------------------------------------------------------------------------
' Yay... into the main game! Woo! Fun!
' -----------------------------------------------------------------------------

Repeat

	Cls
	
	x = 0
	y = 0

	SetRotation ang#; ang = ang + 1; If ang > 360 Then ang = 0
	
	' Draw all images in array...
	
	For p = 0 To pixnum - 1
		DrawImage image [p], x, y
		x = x + 96
		y = y + 96
	Next

	SetRotation 0

	SetColor 0, 0, 0	
	DrawRect MouseX (), MouseY (), 32, 32
	SetColor 255, 255, 255
	DrawRect MouseX (), MouseY (), 30, 30
	
	SetColor 0, 0, 0	
	DrawText "All done! We're in-game now! Fun, fun, fun...", 20, 20
	SetColor 255, 255, 255
	DrawText "All done! We're in-game now! Fun, fun, fun...", 18, 18

	Flip
	
Until KeyHit (KEY_ESCAPE)

End

' -----------------------------------------------------------------------------
' The threaded pixmap loading function...
' -----------------------------------------------------------------------------

' No mutexes are needed here since the global arrays are only accessed by
' the main program before and after this thread is finished...

Function LoadPixmaps:Object (data:Object)

	' Iterate through the global Map...
	
	For p = 0 To pixnum - 1
	
		' Load pixmaps into global pix [] array...

		pix [p] = LoadPixmap (pixname [p])
		
		' Fake delay to simulate loading bigger images for this demo!
		
		Delay TestDelay
		
	Next

End Function

This should make the basic loading process easier to follow anyway.

orgos

(Posted 2009) [#6]

Thanks for all the answers, thanks BlitzSupport for the example.

Arowx

(Posted 2009) [#7]

So how would you implement a simple int loading counter in this example?

orgos

(Posted 2009) [#8]

If you have the amount of resources to load in a global variable and you update that when you load each resource you can make a int loader or percent loader if you want to have more realistic progress bar.