HSL<->RGB?

BlitzMax Forums/BlitzMax Programming/HSL<->RGB?

JoshK

(Posted 2009) [#1]

Does anyone have some BlitzMax code for HSL to RGB to HSL conversion? I know there is some .bb code, but I can't get it to work.

_Skully

(Posted 2009) [#2]

I'm looking for this exact thing right now for my particle system.. I'll post if I find it or make it work.

plash

(Posted 2009) [#3]

Specifically (first comment): http://www.blitzbasic.com/codearcs/codearcs.php?code=2494#comments
The archive is a nice multi-component color class.

Yahfree

(Posted 2009) [#4]

http://en.wikipedia.org/wiki/HSL_and_HSV

plash

(Posted 2009) [#5]

Oh :(
It's late.

Yahfree

(Posted 2009) [#6]

Blah. :p

JoshK

(Posted 2009) [#7]

That code doesn't convert between RGB and HSV reliably, either. Run an image through it, just converting to HSV and back, and you will see errors.

BlitzSupport

(Posted 2009) [#8]

Is HSV any use? (I don't quite get the difference from that Wiki page.)

Mark had a color.mod in very early BlitzMax that covered conversions between RGB, HSV and CMY. If that's any use (and Mark is OK with it) I've found the code...

Otus	(Posted 2009) [#9]

I used these in lossy compression so I may have taken shortcuts (not sure anymore). May or may not be exact enough for your use. All color values are taken to be in [0,1].

Function RGB2HSL(r:Float Var, g:Float Var, b:Float Var)
	Local mx:Float = r
	Local mn:Float = r
	If g > mx
		mx = g
	Else If g < mn
		mn = g
	End If
	If b > mx
		mx = b
	Else If b < mn
		mn = b
	End If
	
	Local mxmn:Float = mx+mn
	Local mx_mn:Float = mx-mn
	
	Local h:Float
	If mx = mn
		h = 0
	Else If mx = r
		h = (g - b) / mx_mn / 6
	Else If mx = g
		h = ( (b - r) / mx_mn + 2 ) / 6
	Else
		h = ( (r - g) / mx_mn + 4 ) / 6
	End If
	If h < 0 Then h :+ 1
	
	Local l:Float = mxmn / 2
	
	Local s:Float
	If mx = mn
		s = 0
	Else If l <= 0.5
		s = mx_mn / mxmn
	Else
		s = mx_mn / (2 - mxmn)
	End If
	
	r = h
	g = s
	b = l
End Function

Function HSL2RGB(h:Float Var, s:Float Var, l:Float Var)
	If s = 0
		h = 0
		s = 0
		l = 0
		Return
	End If
	
	Local p:Float, q:Float
	If l < 0.5
		q = l * (1 + s)
	Else
		q = l+s - l*s
	End If
	p = 2 * l - q
	
	Local r:Float = h + 1.0/3
	If r > 1 Then r :- 1
	If r < 1.0 / 6
		r = p + (q - p) * 6 * r
	Else If r < 1.0 / 2
		r = q
	Else If r < 2.0 / 3
		r = p + (q - p) * (2.0 / 3 - r) * 6
	Else
		r = p
	End If
	
	Local g:Float = h
	If g < 1.0 / 6
		g = p + (q - p) * 6 * g
	Else If g < 1.0 / 2
		g = q
	Else If g < 2.0 / 3
		g = p + (q - p) * (2.0 / 3 - g) * 6
	Else
		g = p
	End If
	
	Local b:Float = h - 1.0/3
	If b < 0 Then b :+ 1
	If b < 1.0 / 6
		b = p + (q - p) * 6 * b
	Else If b < 1.0 / 2
		b = q
	Else If b < 2.0 / 3
		b = p + (q - p) * (2.0 / 3 - b) * 6
	Else
		b = p
	End If
		
	h = r
	s = g
	l = b
End Function

Edit: I should also have an Int/Byte version somewhere (more lossy, faster), if someone needs one. Can't seem to find it at the moment, though. May be in another installation.