How to progressively reveal an image (ala C&C)

BlitzMax Forums/BlitzMax Programming/How to progressively reveal an image (ala C&C)

semar

(Posted 2010) [#1]

never mind, please delete this post.

Czar Flavius

(Posted 2010) [#2]

Do you mean invisible to visible? You can use SetAlpha to set transparency.

abelian_grape

(Posted 2010) [#3]

I'd like to resurrect this post because I'm doing something similar. I want to load my program, and upon the loading, slowly fade in a small title image in the middle of the screen that just has the name of the program and my name. In my code below, I'm referring to this as "titleTag". I guess my problem is that the SetAlpha is affecting everything, not just the one image (titleTag). Not only that, but nothing is fading in anyway, so I was wondering if people knew how to go about this.

	SetClsColor(159, 182, 205)	'Gray background
	For Local i:Int = 0 To 100
		SetAlpha(i *.01)
		DrawImage(titleTag, 512, 384)
		Delay 10
		SetAlpha(1)
	Next

Czar Flavius

(Posted 2010) [#4]

Here you go, you can extend a TFaderImage that draws an image instead of a rect too.

Strict
Graphics 640, 480
SetBlend(ALPHABLEND)
Local fader1:TFader = TFaderRect.create_fader_rect(255, 0, 0, 50, 50, 100, 50).setup(0.0, 0.05, 100)
Local fader2:TFader = TFaderRect.create_fader_rect(0, 255, 255, 50, 250, 50, 50).setup(1.0, -0.05, 50)
While Not KeyDown(KEY_ESCAPE)
	Cls
	fader1.update()
	fader1.draw()
	fader2.update()
	fader2.draw()
	Flip
Wend
End

Type TFader
	Field alpha:Float
	Field delta:Float
	Field rate
	Field last_time = MilliSecs()
	
	Method setup:TFader(palpha:Float, pdelta:Float, prate)
		alpha = palpha
		delta = pdelta
		rate = prate
		Return Self
	End Method
	
	Method update()
		Local new_time = MilliSecs()
		If new_time >= last_time + rate
			alpha :+ delta
			If delta < 0.0
				If alpha <= 0.0
					alpha = 0.0
				End If
			ElseIf delta > 0.0
				If alpha >= 1.0
					alpha = 1.0
				End If
			End If
			last_time = new_time
		End If
	End Method
		
	Method draw() Final
		SetAlpha alpha
		sub_draw()
		SetAlpha 1.0
	End Method
	
	Method sub_draw() Abstract
End Type

Type TFaderRect Extends TFader
	Field r, g, b
	Field x, y, w, h
	
	Method sub_draw()
		SetColor r, g, b
		DrawRect x, y, w, h
	End Method
	
	Function create_fader_rect:TFaderRect(r, g, b, x, y, w, h)
		Local fader:TFaderRect = New TFaderRect
		fader.r = r
		fader.g = g
		fader.b = b
		fader.x = x
		fader.y = y
		fader.w = w
		fader.h = h
		Return fader
	End Function
End Type

abelian_grape

(Posted 2010) [#5]

I have come to the conclusion that you are a magician. Thank you so much!

Something I notice about your code in comparison to mine is that when you want to accomplish something, almost always it involves complex types and very few lines of code in the game loop. I guess I am still trying to adjust to the object-oriented method of programming and thinking in terms of the most basic objects, what their most basic functions should be, and then adding to it. It's a bottom-up approach whereas I think of things top-down...I get a great idea, think about what makes it great, and then instantly try to implement it, usually using some sort of hack, but mostly procedural programming techniques. Your style is much more elegant and portable and I hope I can achieve that style eventually.

-muffins

Mr. Write Errors Man

(Posted 2010) [#6]

muffins,

You need to set blend mode to ALPHABLEND, for alpha to work properly. You also need to call "flip" to update the screen.


Graphics 400,400
Global titleTag:TImage = LoadImage("superlogo.png")

SetBlend ALPHABLEND	' <-- Without this alpha does not really work
SetClsColor(159, 182, 205)	'Gray background

For Local i:Int = 0 To 100

	Cls
	
	SetAlpha(i *.01)
	DrawImage(titleTag, 100, 100)
	
	SetAlpha(1)
	DrawText("INTRO",100,100)
	
	Flip 0 ' <-- this updates the screen
	Delay 50
Next
	
End