How to set position when playing a MP3 with Fmod?

BlitzMax Forums/BlitzMax Programming/How to set position when playing a MP3 with Fmod?

Rico	(Posted 2012) [#1]

I would normally ask this in Brucey's modules section but nothing much seems to go on there these days.

Could anyone tell me how to set the position in a MP3 do i can start playing it from a certain point? i am trying to synch an intro to some music and i keep having to start from the beginning each time and sit through all the stuff i have already synched.

I know i can get the position within a track with this command

Function bmx_FMOD_Channel_GetPosition:Int(handle:Byte Ptr, position:Int Ptr, posType:Int)

Also does anyone know where the instructions are for FMOD? i cant remember its been so long since i used it!

Thank you for any help :)

Grisu

(Posted 2012) [#2]

Hi Rico!

I assume you use Fmod 4.3x.xx.

Here's a quick and dirty example code on how to play an mp3 from a certain position (in this case 8 secs from start).

SuperStrict

Framework BaH.FMOD
Import BRL.GLMax2d

Local system:TFMODSystem = New TFMODSystem.Create()

system.Init(32)

Local sound1:TFMODSound = system.CreateSoundURL("test.mp3", FMOD_SOFTWARE)
sound1.SetMode(FMOD_LOOP_OFF)

Local channel:TFMODChannel

Graphics 640, 480, 0

While Not KeyDown(KEY_ESCAPE)

	Cls
	
		DrawText "===================================================================", 50, 10
		DrawText "PlaySound Example.", 50, 30
		DrawText "===================================================================", 50, 50
		DrawText "Press '1' to Play a mono sound using software mixing", 50, 70

		DrawText "Press 'Esc' to quit", 50, 130

		If KeyHit(KEY_1) Then
			channel = system.PlaySound(1, sound1)
			channel.SetPosition(8000, FMOD_TIMEUNIT_MS) ' <- Insert starting position in ms here ---------------------------------------------------------------
		End If

		system.Update()
	
		Local playing:Int
		Local paused:Int
		Local pos:Int
		Local lenms:Int
		Local channelsPlaying:Int
		
		If channel Then
			channel.IsPlaying(playing)
			
			channel.GetPaused(paused)
			
			channel.GetPosition(pos, FMOD_TIMEUNIT_MS)

			Local currentSound:TFMODSound = channel.GetCurrentSound()			
			If currentSound Then
				currentSound.GetLength(lenms, FMOD_TIMEUNIT_MS)
			End If

		End If
		
		system.GetChannelsPlaying(channelsPlaying)
		
		Local s:String = "Time " + Pad(pos / 1000 / 60) + ":" + Pad(pos / 1000 Mod 60) + ..
			":" + Pad(pos / 10 Mod 100) + " /" + Pad(lenms / 1000 / 60) + ":" + Pad(lenms / 1000 Mod 60) + ..
			":" + Pad(lenms / 10 Mod 100)
			
		If paused Then
			s:+ " : Paused"
		Else If playing Then
			s:+ " : Playing"
		Else
			s:+ " : Stopped"
		End If
		
		s:+ " : Channels Playing : " + channelsPlaying
		
		DrawText s, 50, 200
		
	Flip

Wend

' shut down
sound1.SoundRelease()

system.Close()
system.SystemRelease()


End

Function Pad:String(val:Int, size:Int = 2)
	Local s:String = "00" + val
	Return s[s.length - size..]
End Function

Grisu