multiselect-flag for RequestFile$ (Win32)

BlitzMax Forums/BlitzMax Module Tweaks/multiselect-flag for RequestFile$ (Win32)

Byteemoz

(Posted 2005) [#1]

Some changes to the BRL.System module files to allow selecting multiple files in the win32 RequestFile dialog:

In "system.bmx" line 219, function RequestFile$

Function RequestFile$( text$,extensions$="",save_flag=False,initial_path$="", allow_multiselect=False)
?Win32	
	Return Driver.RequestFile( text,extensions,save_flag +allow_multiselect*2 ,initial_path )
?
	Return Driver.RequestFile( text,extensions,save_flag,initial_path )
End Function

In "system.win32.bmx" line 78, method RequestFile$ of TWin32SystemDriver

	Method RequestFile$( text$,exts$,save,path$)
		Local file$,dir$
		
		path=path.Replace( "/","\" )
		
		Local i=path.FindLast( "\" )
		If i<>-1
			dir=path[..i]
			file=path[i+1..]
		Else
			file=path
		EndIf
	
		If exts
			If exts.Find(":")=-1
				exts="Files~0*."+exts
			Else
				exts=exts.Replace(":","~0*.")
			EndIf
			exts=exts.Replace(";","~0")
			exts=exts.Replace(",",";*.")+"~0"
		EndIf
		
		Local buf:Byte[4096]
		
		Local realsave = (save & 1) > 0
		Local realmulti = (save & 2) > 0
		
		If bbSystemRequestFile( text,exts,realsave,realmulti,file,dir,buf,buf.length ) 
			If realmulti Then
				Local mfiles$ = String.FromBytes(buf, 4096).Trim()
				If mfiles.find("~0") = -1 Then
					Return mfiles$
				Else
					Local mdir$ = mfiles[..mfiles.find("~0")]+"\" ' extract directory
					Return mfiles[mfiles.find("~0")..].Replace("~0", "~0"+mdir)[2..]
				EndIf
			Else
				Return String.FromCString(buf)
			EndIf
		EndIf

	End Method

In "system.win32.c" line 237, C-Function int bbSystemRequestFile

int bbSystemRequestFile( const char *text,const char *exts,int save, int multiselect ,const char *file,const char *dir,char *buf,int bufsz ){
	int n;
	OPENFILENAME of={sizeof(of)};
	
	strcpy( buf,file );
	
	of.hwndOwner=GetActiveWindow();
	of.lpstrTitle=text;
	of.lpstrFilter=exts;
	of.lpstrFile=buf;
	of.lpstrInitialDir=dir[0] ? dir : 0;
	of.nMaxFile=bufsz;
	of.Flags=OFN_HIDEREADONLY|OFN_NOCHANGEDIR;

	beginPanel();
	
	if( save ){
		of.Flags|=OFN_OVERWRITEPROMPT;
		n=GetSaveFileName( &of );
	}else{
		of.Flags|=OFN_FILEMUSTEXIST;
		if( multiselect )
			of.Flags|=OFN_ALLOWMULTISELECT|OFN_EXPLORER;
		n=GetOpenFileName( &of );
	}
	
	endPanel();
	
	return n ? 1 : 0;
}

--Byteemoz

Perturbatio

(Posted 2005) [#2]

I posted something like this here

Byteemoz

(Posted 2005) [#3]

Whoopsie... kinda missed that one.