maxmod update 1.16

BlitzMax Forums/BlitzMax Module Tweaks/maxmod update 1.16

REDi	(Posted 2007) [#1]

New version of maxmod is up, just click the link in my sig...

REDi	(Posted 2007) [#2]

There is a few changes in this version, that will break current apps, I've seperated the TMusic object and streaming into two seperate object...

Local Music:TMusic = LoadMusic(RequestFile("Select music to play...",MusicExtensions())) 
If Not Music RuntimeError "Unable to open music"
Local Stream:TAudioStream = StreamMusic(Music)
If Not Stream Notify "Unable to open stream"
PlayStream(Stream)

So now the TMusic object is the player/decoder and TAudioStream handles the streaming to directsound.

Sorry, its a bit awkward, but IMO required in the long run. (ie, its easier to plug into other sound engines ;) )

on the plus side, you can now load the entire track and play it back with freeaudio, without touching a maxmod stream.

This release was rushed, so it wasn't as tested as i would have liked, so if you find some bugs, give me a shout.

GfK	(Posted 2007) [#3]

Eek!

Slowly getting my head around all this. But what's happened to the 'Pause' method?

Is there still a way to pause music then resume it from the same point??

REDi	(Posted 2007) [#4]

LOL, I'm on it.. ? lol

REDi	(Posted 2007) [#5]

Ok, another version for ya 1.16a, with a pause function!

Stream.pause or PauseStream(Stream)
Call it once to pause it, and again to unpause.

If you have any more problems (probably), let me know mate, I'll fix it asap, gotta get some sleep now tho -.-

anyway, sorry for the inconvenience, this update was a bit of a surprise.

hub	(Posted 2007) [#6]

Thanks Redi !

GfK	(Posted 2007) [#7]

Couple of problems turning up.

1. Geti(MM_ISPLAYING) - always returns 0.
2. tAudioStream.SetVolume(v) - "Too many function parameters"
3. Setf(MM_VOLUME,v) - does nothing.
4. SetStreamVolume(stream,v) - does nothing.
5. tMusic.Getf(MM_VOLUME) - always returns 0.

Matthew Smith

(Posted 2007) [#8]

Redi,

Any chance on taking a look at the SidStream changes at some stage?? Unfortunately, a bit beyond me!!

REDi	(Posted 2007) [#9]

thanks GfK, now thats what I call sloppy work! ;)

1. thanks easy fix
2. TAudioStream.SetVolume is a private method, forget that one (your right, i will make it uniform)
3. see 4
4. just tried it here and works okay, value should be between 0.0-1.0
5. oops, use Stream.alPitch as a temp fix

@Matt, sure thing, will do it tonight.

night all

Matthew Smith

(Posted 2007) [#10]

Thanks Redi

REDi	(Posted 2007) [#11]

no problems mate, fixes will be available tonite at some point.

skidracer

(Posted 2007) [#12]

REDi, in regards to streaming, I was wondering about the following change to freeaudioaudio.bmx[149]

<edit>

	Method Playing()
		Local status=fa_ChannelStatus( fa_channel ) & ~(FA_CHANNELSTATUS_STOPPED)
'		If status Return True
		If status Return fa_ChannelPosition(fa_channel)+1
	End Method

Which should give you the current readpointer of the channel in samples.

For music synthesis, you should be then able to play a looped sample and write your data ahead of the mixer's read pointer.

Kindof busy at the moment but will try and test / post some helper classes soon.

REDi	(Posted 2007) [#13]

Great news skid, much appreciated! :D

skidracer

(Posted 2007) [#14]

OK, it seems to be working, new freeaudio here, and the start of a synth class that supports 8/16/mono/stereo streaming, currently setdriver is required due to a nullaudiodevice somehow being installed after freeaudio default, not sure about that one....

A TFloatSynth is probably needed next, and then a hook to the oggreader code should hopefully be possible.

' synth.bmx

Strict

'SetAudioDriver "FreeAudio DirectSound"	'cludge around build order problems
SetAudioDriver "FreeAudio Default"	'cludge around build order problems


?BigEndian
Const SF_STEREO16=SF_STEREO16BE
Const SF_MONO16=SF_MONO16BE
?LittleEndian
Const SF_STEREO16=SF_STEREO16LE
Const SF_MONO16=SF_MONO16LE
?

Type TSynth

	Global timer:TTimer
	Global synthlist:TList=New TList
	
	Field sample:TAudioSample
	Field channel:TChannel
	Field sound:TSound

	Field bits
	Field channels
	Field format
	Field fragsize		
	Field writepos
	
	Function eventhook:Object(id%,data:Object,context:Object)
		Local synth:TSynth
		If context=timer 
			For synth=EachIn synthlist
				synth.Poll
			Next
			Return Null
		EndIf
	End Function
	
	Method Poll()
		Local readpos
		Local count
		readpos=ChannelPlaying(channel)/channels
		If readpos=0 Return 'this channel is stopped
		count=((readpos+fragsize*2-writepos)/fragsize)
		While count
			Select bits
				Case 8
					Mix8
				Case 16
					Mix16
			End Select
			writepos=writepos+fragsize
			count=count-1
		Wend
	End Method

' mix the next .fragsize samples into .sample at (.writepos mod .fragsize)

	Method Mix8()
	End Method

	Method Mix16()
	End Method
		
	Method CreateSynth:TSynth(frag=8192,_bits=16,_channels=2)
		fragsize=frag
		bits=_bits
		channels=_channels
		If bits=16
			If channels=2			
				format=SF_STEREO16
			Else
				format=SF_MONO16
			EndIf			
		Else
			If channels=2
				format=SF_STEREO8
			Else
				format=SF_MONO8
			EndIf
		EndIf		
		sample=CreateAudioSample(fragsize*4,44100,format)	'SF_MONO8)
		MemClear sample.samples,sample.capacity
		channel=AllocChannel() 
		sound=LoadSound(sample,True)
		PlaySound sound,channel
		If Not timer
			timer=CreateTimer(100)
			AddHook EmitEventHook,eventhook,timer
		EndIf
		synthlist.AddLast Self
		Return Self
	End Method
	
	Function Close()
		If timer
			RemoveHook EmitEventHook,eventhook
			StopTimer timer
			timer=Null
		EndIf
	End Function

End Type

Type TSweepSynth Extends TSynth

	Field rad#,radf#

	Method Mix8()
		Local b:Byte Ptr
		Local p,i	
		p=writepos Mod (fragsize*4)
		b=sample.samples+p*channels
		For i=0 Until fragsize*channels		
			rad=rad+radf/channels
			radf=radf+.00001/channels
			b[i]=128+127*Sin(rad)
		Next	
	End Method

	Method Mix16()
		Local s:Short Ptr
		Local p,i
		p=writepos Mod (fragsize*4)
		s=Short Ptr sample.samples+p*channels
		For i=0 Until fragsize*channels
			rad=rad+radf/channels
			radf=radf+.00001/channels
			s[i]=32767*Sin(rad)
		Next	
	End Method

	Method CreateSweepSynth:TSweepSynth(frag=8192,_bits=16,_channels=2)
		CreateSynth frag,_bits,_channels
		Return Self
	End Method

End Type


Function CreateSweepSynth:TSynth(fragsize,bits,channels)
	Return New TSweepSynth.CreateSweepSynth(fragsize,bits,channels)
End Function

CreateSweepSynth 8192,16,2

While True
	WaitEvent
	Print "yo!"
Wend

REDi	(Posted 2007) [#15]

Fixed (I hope) version of maxmod is now up 1.16b, including sidstream.mod update.

WOW, Thanks skidracer!, here's a quick bodged tester using maxmod... :D

' synth.bmx

Strict

Import REDi.MaxMod

'SetAudioDriver "FreeAudio DirectSound"	'cludge around build order problems
'SetAudioDriver "FreeAudio Default"	'cludge around build order problems
SetAudioDriver "Set OpenAL Generic Hardware"

?BigEndian
Const SF_STEREO16=SF_STEREO16BE
Const SF_MONO16=SF_MONO16BE
?LittleEndian
Const SF_STEREO16=SF_STEREO16LE
Const SF_MONO16=SF_MONO16LE
?

Type TSynth

	Global timer:TTimer
	Global synthlist:TList=New TList
	
	Field sample:TAudioSample
	Field channel:TChannel
	Field sound:TSound

	Field bits
	Field channels
	Field format
	Field fragsize		
	Field writepos
	
	Function eventhook:Object(id%,data:Object,context:Object)
		Local synth:TSynth
		If context=timer 
			For synth=EachIn synthlist
				synth.Poll
			Next
			Return Null
		EndIf
	End Function
	
	Method Poll()
		Local readpos
		Local count
		readpos=ChannelPlaying(channel)/channels
		If readpos=0 Return 'this channel is stopped
		count=((readpos+fragsize*2-writepos)/fragsize)
		While count
			Select bits
				Case 8
					Mix8
				Case 16
					Mix16
			End Select
			writepos=writepos+fragsize
			count=count-1
		Wend
	End Method

' mix the next .fragsize samples into .sample at (.writepos mod .fragsize)

	Method Mix8()
	End Method

	Method Mix16()
	End Method
		
	Method CreateSynth:TSynth(frag=8192,_bits=16,_channels=2)
		fragsize=frag
		bits=_bits
		channels=_channels
		If bits=16
			If channels=2			
				format=SF_STEREO16
			Else
				format=SF_MONO16
			EndIf			
		Else
			If channels=2
				format=SF_STEREO8
			Else
				format=SF_MONO8
			EndIf
		EndIf		
		sample=CreateAudioSample(fragsize*4,44100,format)	'SF_MONO8)
		MemClear sample.samples,sample.capacity
		channel=AllocChannel() 
		sound=LoadSound(sample,True)
		PlaySound sound,channel
		If Not timer
			timer=CreateTimer(100)
			AddHook EmitEventHook,eventhook,timer
		EndIf
		synthlist.AddLast Self
		Return Self
	End Method
	
	Function Close()
		If timer
			RemoveHook EmitEventHook,eventhook
			StopTimer timer
			timer=Null
		EndIf
	End Function

End Type

Type TMusicStream Extends TSynth

	Field Music:TMusic

	Method Mix8()
		Local b:Byte Ptr
		Local p,i	
		p=writepos Mod (fragsize*4)
		b=sample.samples+p*channels
		Music.FillBuffer(Int(p),fragsize*4)
	End Method

	Method Mix16()
		Local s:Short Ptr
		Local p,i
		p=writepos Mod (fragsize*4)
		s=Short Ptr sample.samples+p*channels
		Music.FillBuffer(Int(s),fragsize*4)
	End Method

	Function CreateMusicStream:TMusicStream(Music:TMusic)
		Local This:TMusicStream = New TMusicStream
		This.Music = Music
		This.CreateSynth(8192,16,2)
		Return This
	EndFunction

End Type




Local Music:TMusic = LoadMusic(RequestFile("Select music to play...",MusicExtensions())) 
If Not Music RuntimeError "Unable to open music"
If Not Music Notify "Unable to open music"
Local Stream:TMusicStream = TMusicStream.CreateMusicStream(Music:TMusic)

While True
	WaitEvent
	Print "yo!"
Wend

Matthew Smith

(Posted 2007) [#16]

Redi,

Thanks for the update and the changes for SidPlayer!

REDi	(Posted 2007) [#17]

No probs mate, give me a shout if you have problems with it.

Skid, how about filling the entire sample at creation first, then chasing the play cursor (filling in from the last write position to the play cursor), that way you should always have the entire sample size worth of audio prebuffered (less chance of glitches), also means you dont fill the buffer in same sized chuncks (more evenly spread cpu usage?)

See TAudioStream.Update in maxmod.mod/stream.bmx for an idea of how i done it for that.

Just a thought. Anyway thanks again, made my day that has!

Matthew Smith

(Posted 2007) [#18]

Everyone,

To simplify the playing of SIDs using Redi's excellent module, I have created a wrapper to give you access to the required items without flipping between the music and stream types.

example:

' load.bmx

Strict 
Framework BRL.GLMax2D 
Import REDi.MaxMod
Import SID.SIDStream

Graphics 800,600,0 

' initialize the MaxMod music system
InitMaxModStream()

' use the built-in SIDStream loader
Local Stream:SIDStream = New SIDStream
Stream.Load(RequestFile("Load a sid file"))

' start sid
Stream.Play()

Local Pitch# = 1
Repeat 

	Cls 
	DrawText "  ESCAPE = Exit",5,5
	DrawText "   SPACE = Play",5,20
	DrawText "       S = Stop",5,35
	DrawText "       P = Pause",5,50
	DrawText " UP/DOWN = Pitch",5,65
	
	DrawText "   PITCH = "+Pitch,5,125

	DrawText "TOTAL TRACKS = "+Stream.GetTrackCount(),5,170
	DrawText "       TRACK = "+Stream.CurrentTrack(),5,185
	DrawText "  LEFT/RIGHT = Select Track",5,200
	
	If KeyHit(KEY_S) 	 Then Stream.Stop()
	If KeyHit(KEY_SPACE) Then Stream.Play()
	If KeyHit(KEY_P) 	 Then Stream.Pause()
	If KeyDown(KEY_UP)	 Then Pitch:+0.001 ; Stream.SetHertz(Pitch)
	If KeyDown(KEY_DOWN) Then Pitch:-0.001 ; Stream.SetHertz(Pitch)
	If KeyHit(KEY_LEFT) Then Stream.SelectTrack(Stream.CurrentTrack()-1)
	If KeyHit(KEY_RIGHT) Then Stream.SelectTrack(Stream.CurrentTrack()+1)

	Flip True
	
Until KeyDown(KEY_ESCAPE) 
Stream.Free()
End

Please download it from here http://www.projectstudioide.com/files/sidstream.zip Unpack it into the \BlitzMax\mod\sid.mod folder

If anyone can tidy it up further go right ahead!!

skidracer

(Posted 2007) [#19]

Skid, how about filling the entire sample at creation first, then chasing the play cursor (filling in from the last write position to the play cursor), that way you should always have the entire sample size worth of audio prebuffered (less chance of glitches), also means you dont fill the buffer in same sized chuncks (more evenly spread cpu usage?)

See TAudioStream.Update in maxmod.mod/stream.bmx for an idea of how i done it for that.

Thanks, will take a look.

The theory behind current design is the mixer thread does force frag size on most drivers so I am most interested in syncing a synth to the mixer by having it poll at least twice the frequency of that frag length.

The Apple CoreAudio driver is a bit unique and it pulls what ever size it wants, I'm more into the fixed size, especially for decoder synths. Hmmm, changing the channel rate on a synth is going to be interesting, it's going to need fragsize * maximum rate for a buffer size, perhaps tsynth should extend tchannel so algorithmic synths can implement rate while decoder style streams get rate change for free but have to deliver more data.

Oh, also brl.freeaudioaudio now needs to maintain a reference to sample as pub.freeaudio is no longer making it's own copy of the memory so samples were going out of scope in my game, and when they were deleted freeaudio starts playing corrupted memory which sounded pretty awful, quick hack:


Strict

Module BRL.FreeAudioAudio

ModuleInfo "Version: 1.06"
ModuleInfo "Author: Mark Sibly"
ModuleInfo "License: Blitz Shared Source Code"
ModuleInfo "Copyright: Blitz Research Ltd"
ModuleInfo "Modserver: BRL"

ModuleInfo "History: 1.06 Release"
ModuleInfo "History: Added Method TFreeAudioChannel.Position"
ModuleInfo "History: 1.05 Release"
ModuleInfo "History: Mono and 8 bit sample support added"

Import BRL.Audio
Import Pub.FreeAudio

Type TFreeAudioSound Extends TSound

	Field src:TAudioSample
	Field fa_sound
	
	Method Delete()
		fa_FreeSound fa_sound
	End Method

	Method Play:TFreeAudioChannel( alloced_channel:TChannel )
		Local channel:TFreeAudioChannel,fa_channel
		If alloced_channel
			channel=TFreeAudioChannel( alloced_channel )
			If Not channel Return
			fa_channel=channel.fa_channel
		EndIf		
		fa_channel=fa_PlaySound(fa_sound,False,fa_channel)
		If Not fa_channel Return
		If channel And channel.fa_channel=fa_channel Return channel
		Return TFreeAudioChannel.CreateWithChannel( fa_channel )
	End Method
	
	Method Cue:TFreeAudioChannel( alloced_channel:TChannel )
		Local channel:TFreeAudioChannel,fa_channel
		If alloced_channel
			channel=TFreeAudioChannel( alloced_channel )
			If Not channel Return
			fa_channel=channel.fa_channel
		EndIf
		fa_channel=fa_PlaySound( fa_sound,True,fa_channel )
		If Not fa_channel Return
		If channel And channel.fa_channel=fa_channel Return channel
		Return TFreeAudioChannel.CreateWithChannel( fa_channel )
	End Method

	Function CreateWithSound:TFreeAudioSound( fa_sound,	src:TAudioSample )
		Local t:TFreeAudioSound=New TFreeAudioSound
		t.fa_sound=fa_sound
		t.src=src
		Return t
	End Function
	
End Type

Type TFreeAudioChannel Extends TChannel

	Field fa_channel

	Method Stop()
		fa_StopChannel fa_channel
	End Method
	
	Method SetPaused( paused )
		fa_SetChannelPaused fa_channel,paused
	End Method
	
	Method SetVolume( volume# )
		fa_SetChannelVolume fa_channel,volume
	End Method
	
	Method SetPan( pan# )
		fa_SetChannelPan fa_channel,pan
	End Method
	
	Method SetDepth( depth# )
		fa_SetChannelDepth fa_channel,depth
	End Method
	
	Method SetRate( rate# )
		fa_SetChannelRate fa_channel,rate
	End Method
	
	Method Playing()
		Local status=fa_ChannelStatus( fa_channel ) & ~(FA_CHANNELSTATUS_STOPPED)
'		If status Return True
		If status Return fa_ChannelPosition(fa_channel)+1
	End Method
	
	Method Position()
		Return fa_ChannelPosition( fa_channel )
	End Method
	
	Function CreateWithChannel:TFreeAudioChannel( fa_channel )
		Local t:TFreeAudioChannel=New TFreeAudioChannel
		t.fa_channel=fa_channel
		Return t
	End Function
	
End Type

Type TFreeAudioAudioDriver Extends TAudioDriver

	Method Enum$()
		Return _enum
	End Method
	
	Method Initialize()
		'***** Simon! *****
		If _ready fa_Close
		If fa_Init( _mode )<>-1
			atexit_ fa_Close
			_ready=True
		EndIf
		Return _ready
	End Method

	Method CreateSound:TSound( sample:TAudioSample,loop_flag )
		Assert _ready
		
		Local channels,bits
		
		Select sample.format
?BigEndian
		Case SF_MONO16LE
			sample=sample.Convert(SF_MONO16BE)
		Case SF_STEREO16LE
			sample=sample.Convert(SF_STEREO16BE)
?LittleEndian
		Case SF_MONO16BE
			sample=sample.Convert(SF_MONO16LE)
		Case SF_STEREO16BE
			sample=sample.Convert(SF_STEREO16LE)
?
		End Select
		If loop_flag loop_flag=-1
		channels=ChannelsPerSample[sample.format]
		If Not channels Return
		bits=8*BytesPerSample[sample.format]/channels
		Local fa_sound=fa_CreateSound( sample.length,bits,channels,sample.hertz,sample.samples,loop_flag )
		Return TFreeAudioSound.CreateWithSound( fa_sound,sample )
	End Method
	
	Method AllocChannel:TChannel()
		Assert _ready	
		Local fa_channel=fa_AllocChannel()
		If fa_channel Return TFreeAudioChannel.CreateWithChannel( fa_channel )
	End Method
		
	Function Create:TFreeAudioAudioDriver( enum$,mode )
		'***** need some kind of "exists but don't activate" init/check here *****
		Local t:TFreeAudioAudioDriver=New TFreeAudioAudioDriver
		t._enum=enum
		t._mode=mode
		Return t
	End Function
	
	Field _enum$,_mode,_ready
	
End Type

TFreeAudioAudioDriver.Create "FreeAudio Default",0
TFreeAudioAudioDriver.Create "FreeAudio DirectSound",1

SetAudioDriver "FreeAudio Default"

skidracer

(Posted 2007) [#20]

Looks like streaming to OpenAL is not going to be quite as straight forward (your test has error in driver name) as there are no dynamic buffers, streamed samples are going to need to have multiple buffers that are queued which need to refresh from the dynamic sample, yuck.

GfK	(Posted 2007) [#21]

There's something bothering me about all this streaming audio lark.

Blit3D's PlayMusic() handled it pretty well. Why's Blitzmax apparently such a different kettle of fish?

Mark Tiffany

(Posted 2007) [#22]

Because b3d used FMOD, and max doesn't?

GfK	(Posted 2007) [#23]

Yeah but my point is, is FMOD can do it, why is it proving to be so difficult for BRL?

REDi	(Posted 2007) [#24]

GfK, IMHO the point is FMOD wasn't written in a week mate! Those guys also have years of experience in audio, way back to the amiga days IIRC.

(LOL @ driver name error)

skidracer

(Posted 2007) [#25]

REDi, for freeaudio 1.20 which I think is now up on syncmods the channelplaying value now correctly returns position in samples so longer needs to be divided by channels, so where the synth has:

readpos=ChannelPlaying(channel)/channels

change to

readpos=ChannelPlaying(channel)

if you don't expect clicking buffer overruns...

REDi	(Posted 2007) [#26]

yeah thanks mate, i figured that one already ;) nice work, sounding good with the default driver, but the directsound one still jumps about abit! (eg, when i use the mouse wheel to scroll in IE)

Anyway I'll just wait and see what you come up with for ogg/wav streaming, then I'll follow suit afterwards.

tester for maxmod users...

Strict

Import REDi.MaxMod

'SetAudioDriver "FreeAudio DirectSound"
SetAudioDriver "FreeAudio Default"

?BigEndian
Const SF_STEREO16=SF_STEREO16BE
Const SF_MONO16=SF_MONO16BE
?LittleEndian
Const SF_STEREO16=SF_STEREO16LE
Const SF_MONO16=SF_MONO16LE
?

Type TSynth

	Global timer:TTimer
	Global synthlist:TList=New TList
	
	Field sample:TAudioSample
	Field channel:TChannel
	Field sound:TSound

	Field bits
	Field channels
	Field format
	Field fragsize		
	Field writepos
	
	Function eventhook:Object(id%,data:Object,context:Object)
		Local synth:TSynth
		If context=timer 
			For synth=EachIn synthlist
				synth.Poll
			Next
			Return Null
		EndIf
	End Function
	
	Method Poll()
		Local readpos
		Local count
		readpos=ChannelPlaying(channel)
		If readpos=0 Return 'this channel is stopped
		count=((readpos+fragsize*2-writepos)/fragsize)
		While count
			Select bits
				Case 8
					Mix8
				Case 16
					Mix16
			End Select
			writepos=writepos+fragsize
			count=count-1
		Wend
	End Method

' mix the next .fragsize samples into .sample at (.writepos mod .fragsize)

	Method Mix8()
	End Method

	Method Mix16()
	End Method
		
	Method CreateSynth:TSynth(frag=8192,_bits=16,_channels=2)
		fragsize=frag
		bits=_bits
		channels=_channels
		If bits=16
			If channels=2			
				format=SF_STEREO16
			Else
				format=SF_MONO16
			EndIf			
		Else
			If channels=2
				format=SF_STEREO8
			Else
				format=SF_MONO8
			EndIf
		EndIf		
		sample=CreateAudioSample(fragsize*4,44100,format)	'SF_MONO8)
		MemClear sample.samples,sample.capacity
		channel=AllocChannel() 
		sound=LoadSound(sample,True)
		PlaySound sound,channel
		If Not timer
			timer=CreateTimer(100)
			AddHook EmitEventHook,eventhook,timer
		EndIf
		synthlist.AddLast Self
		Return Self
	End Method
	
	Function Close()
		If timer
			RemoveHook EmitEventHook,eventhook
			StopTimer timer
			timer=Null
		EndIf
	End Function

End Type








Type TMusicStream Extends TSynth

	Field Music:TMusic

	Method Mix16()
		Local p=writepos Mod (fragsize*4)
		Local s:Short Ptr = Short Ptr sample.samples+p*channels
		Music.FillBuffer(Int(s), fragsize*4)
	End Method

	Method CreateBuffer(Music:TMusic)
		Self.Music 	= Music
		fragsize	= 1024*12
		bits		= 16
		channels	= 2
		format		= SF_STEREO16
		sample		= CreateAudioSample(fragsize*4,Music.SAMPLE_RATE,format)
		channel		= AllocChannel() 
		sound		= LoadSound(sample,True)
		PlaySound sound,channel
		If Not timer
			timer=CreateTimer(100)
			AddHook EmitEventHook,eventhook,timer
		EndIf
		synthlist.AddLast Self
	EndMethod

	Function CreateMusicStream:TMusicStream(Music:TMusic)
		Local This:TMusicStream = New TMusicStream
		This.CreateBuffer(Music)
		Return This
	EndFunction

End Type



Local Music:TMusic = LoadMusic(RequestFile("Select music to play...",MusicExtensions())) 
If Not Music RuntimeError "Unable to open music"
'Music.Seti(MM_SAMPLERATE,22050)
'Music.Seti(MM_INTERPOLATION,MM_CATMULLROM)
Local Stream:TMusicStream = TMusicStream.CreateMusicStream(Music:TMusic)

While True
	WaitEvent
	Print "yo!"
Wend

Note, since the syncmods it now works without altering any modules. if you have maxmod installed just copy, paste and run.

skidracer

(Posted 2007) [#27]

Cool, that maxmod synth seems to play just fine on Apple and Linux although on Linux the mod continues to play even though the process is reportedly finished, very strange...

REDi	(Posted 2007) [#28]

LOL, SWEET!

anawiki

(Posted 2007) [#29]

REDi, make sure to bring no loop functionality with next release :)

best
Roman

The Caffeine Kid

(Posted 2007) [#30]

What has happened to the site? :(

u2o	(Posted 2007) [#31]

Redi's site is down, does anyone else have a link for the download?

Many thanks

bursar

(Posted 2007) [#32]

Seek and ye shall find: http://www.blitzbasic.com/Community/posts.php?topic=67827 :)

Russell

(Posted 2007) [#33]

Using the FreeAudio methodology, is this version compatible with all platforms?

And on that note, does the entire mod have to be sampled into memory, or could this also be streamed (using FreeAudio for cross-compatibility)? Sampling a 5 minute .xm file, uncompressed, could be quite large! ;)

Russell

REDi	(Posted 2007) [#34]

Sorry guys, not online ATM, will be back soon I hope. to skint to be paying out on internet bills ATM.

Just to let you know work on maxmod is still going on, sound feking awesome now! and its a hell of a lot quicker to!

popcade

(Posted 2007) [#35]

REDi, that's Good News and hope everything will going well.

I really hope there'll be the possibility to "plug" the module part of MaxMod into official audio system so we can have a TModule class or something and they'll be fully cross platfrom.

uGMOD have DSound/OpenAL implementations too, but have conflict with official moduls that make it inconvenient to use, I hope MaxMod can integrate everything well....

Panno

(Posted 2008) [#36]

matts sid.mod link is down

have anyone an upload please .....

mfg

Matthew Smith

(Posted 2008) [#37]

Panno,

Sorry, removed the mod as Redi released a 1.20 version. Have a quick check around the forums for this version.

Josepho

(Posted 2008) [#38]

Anybody knows why when I make the game change between the windowed mode and the fullscreen mode my music repeats some seconds using maxmod streaming?? Anybody knows if its possible to fix it?

Thanks

REDi	(Posted 2008) [#39]

The repeating is caused by pauses in event handling being bigger than the audios circular buffer, you can make the streaming buffer bigger by changing the global variables used by maxmod...

TDirectSoundAudioStream.buffersize = 44100*3
TOpenALAudioStream._buffersize = 1024*8

the values above are the defaults for maxmod, so you could try doubling the buffer sizes, this should be enougth to fix the problem.