For...Each freezes game. A newbie needs help

BlitzPlus Forums/BlitzPlus Beginners Area/For...Each freezes game. A newbie needs help

mbrenner

(Posted 2016) [#1]

Hey everyone! Thanks for helping :). I'm a newbie at this and just need some help. My code is below.

Graphics 800,600,0,2
SetBuffer BackBuffer()

Dim array(10,10)

Data 1,1,1,1,1,1,1,1,1,1
Data 1,1,1,1,1,1,1,1,1,1
Data 1,1,1,1,1,1,1,1,1,1
Data 1,1,1,0,0,0,0,1,1,1
Data 1,1,1,0,0,0,0,1,1,1
Data 1,1,1,0,0,0,0,1,1,1
Data 1,1,1,0,0,0,0,1,1,1
Data 1,1,1,1,1,1,1,1,1,1
Data 1,1,1,1,1,1,1,1,1,1
Data 1,1,1,1,1,1,1,1,1,1


;###########################################
;#            Type Definitions             #
;###########################################
Type brick
	Field x,y
	Field image
	Field hitpoints
End Type

Type player
	Field lives
	Field x,y
	Field image
End Type

Type ball
	Field x,y
	Field vX, vY
	Field image
End Type

;###########################################
;#        Variable and New Types           #
;###########################################
Global weakbrick.brick = New brick
weakbrick\x = 150
weakbrick\y = 150
weakbrick\image = LoadImage("brick.bmp")
weakbrick\hitpoints = 1

Global ball.ball = New ball
ball\x = 400
ball\y = 300
ball\vX = 4
ball\vY = 4
ball\image = LoadImage("ball.bmp")

Global player.player = New player
player\lives = 3
player\x = 350
player\y = 580
player\image = LoadImage("player.bmp")

Global background1 = LoadImage("background1.bmp")
Global readinfo = 1

;###########################################
;#               Main Loop                 #
;###########################################
While Not KeyHit(1)
	Cls
	drawImages()
	drawlevel()
	movement()
	collisions()
	Flip
Wend


;###########################################
;#    Performs all Collision Detection     #
;###########################################
Function collisions()
	;Tests to see whether ball collides with sides
	If ball\y > 595 Then ball\vY = -ball\vY
	If ball\x > 796 Then ball\vX = -ball\vX
	If ball\y < 0 Then ball\vY = -ball\vY
	If ball\x < 0 Then ball\vX = -ball\vX
	
	;If the ball hits the player paddle	
	If ImagesCollide(player\image, player\x, player\y, 0, ball\image, ball\x,ball\y, 0) Then
		ball\vY = -ball\vY
	EndIf
	
	If ImagesCollide(weakbrick\image, weakbrick\x, weakbrick\y, 0, ball\image, ball\x,ball\y, 0) Then
		ball\vY = -ball\vY
	EndIf
	
	;If the player paddle hits the edges
	If player\x < 0 Then player\x = 0
	If player\x > 721 Then player\x = 721		
	
End Function


;###########################################
;#           Draws all images              #
;###########################################
Function drawImages()
	DrawImage(background1,0,0)
	DrawImage(player\image,player\x,player\y)
	DrawImage(ball\image,ball\x,ball\y)
End Function

Function drawlevel()
	For y = 1 To 10
		For x = 1 To 10
			If readinfo = 1 Then Read array(x,y)
			If array(x,y) = 1 Then
				DrawImage(weakbrick\image, x * 50, y * 20)
			EndIf
		Next
	Next
	readinfo = 0
End Function


;###########################################
;#            Movement Inputs              #
;###########################################
Function movement()
	;ball movement
	ball\x = ball\x + ball\vX
	ball\y = ball\y + ball\vY
	
	;player movement
	If KeyDown(203) Then
		player\x = player\x - 5
	Else If KeyDown(205) Then
		player\x = player\x + 5
	EndIf
End Function

End

I'm trying to create a breakout game and I have multiple bricks drawn to the screen. However, each time I use the FOR EACH method to try to add behaviors to the bricks it freezes the game. Why does it do this?

Everyone in advance.

-- Matt

okee	(Posted 2016) [#2]

i would sort out the array sizes first

Dim array(10,10)
creates an array 11 x 11 as arrays start at 0
so an array with 10 elements would be
Dim array(9,9)

then use
for x = 0 to 9

At the moment it's just creating an empty element at the beginning
What was the for each code that was being used ?

Dan	(Posted 2016) [#3]

In your code, you have defined only 1 instance of the Brick type.

here is how i would do it:

;Graphics 320,240,32,6 ;b3d ...
;Graphics 320,240,32,7 ;b3d ...

Graphics 320,240,0,2

Type dat
	Field x,y
	Field typ
End Type 

;setup the level:
For y=1 To 4
	For x=1 To 7
		Read dx  ; 0,1,2 or 3 
		If dx>0
			brick.dat = New dat
			brick\typ=dx	;Brick type 
			brick\x=x*10	;Brick x size 
			brick\y=y*10	;Brick y size
		End If
	Next ;y
Next ;x

;main loop
Repeat
	Cls
	Gosub drawlevel
	Flip
	
Until KeyHit(1)


End

.drawlevel

For tmp.dat = Each dat
	Text tmp\x,tmp\y,tmp\typ
Next

Return

Data 0,0,0,0,0,0,0
Data 0,1,2,3,2,1,0
Data 0,1,2,0,2,1,0
Data 0,1,2,3,2,1,0

Then you can use collision detection like this:

for tmp.dat = each dat 
	If ImagesCollide(brickimage, tmp\x, tmp\y, 0, ball\image, ball\x,ball\y, 0) Then
		ball\vY = -ball\vY
                delete tmp
	EndIf 
next

Dan	(Posted 2016) [#4]

A small game, for Blitz3d - click on maximize box ;)

Graphics 120,100,32,6 ;bb3d ...
Graphics 120,100,32,7 ;bb3d ...

;Graphics 120,100,0,2 ; Blitzplus

SetBuffer BackBuffer()

Font=LoadFont("Courier",13,False,False,False)
SetFont font

Type info
	Field x,y
	Field shot
	Field timer
	Field movtimer
	Field score
End Type

player.info = New info
player\x = 32
player\y = 90
player\timer=MilliSecs()
player\movtimer=MilliSecs()
player\shot=0

Type dat
	Field x,y
	Field typ
End Type 

;setup the level:
maxscore=0
For y=1 To 4
	For x=1 To 7
	
		Read dx         ; 0,1,2,3 to 9
		
		If dx<0 Or dx>9 Then dx=Rand(0,9)     ;numbers between 0 and 9 please
		
		If dx>0
			brick.dat = New dat
			brick\typ=dx			;Brick type 
			brick\x=2+(x*12)		;Brick x size 
			brick\y=3+(y*10)		;Brick y size
			maxscore=maxscore+dx	;add score, to display the game over
		End If
		
	Next ;y
Next ;x

;main loop
Repeat
	Cls
	Gosub drawlevel 		;Draw level
	Gosub drawplayer		;Draw player
	If player\shot=1 
		Gosub drawbullet	;Draw bullet
	EndIf
	
	Flip					;Flip to see
	
Until KeyHit(1)


End

.drawplayer
If MilliSecs()-player\movtimer>10     ;player movement delay
	player\movtimer=MilliSecs()
	dx=KeyDown(205)-KeyDown(203)      ;nice trick, makes dx=-1 for left  and dx=1 for right arrow key
	player\x=player\x+dx
EndIf

;stop the player movement
If player\x<0 Then player\x=0          ; left side
If player\x>100 Then player\x=100      ; right side


If (KeyDown(29) Or KeyDown(157)) And player\shot=0  ;left or right ctrl
	bullet.info = New info
	bullet\x=player\x
	bullet\y=player\y
	player\timer=MilliSecs()
	player\shot=1
EndIf

Color $ff,$ff,$ff
Text player\x,player\y,"^"

Return

.drawbullet
If player\shot=1
	
	
	If bullet\y<=-20 
		Delete bullet 
		player\shot=0
		Return
	Else
	  If MilliSecs()-player\timer=>5    ;Speed of the bullet
		player\timer=MilliSecs()
		bullet\y=bullet\y-1
	  EndIf 
	EndIf
	
	For tmp.dat = Each dat                                   ;Collision detection:
		If (bullet\x=>tmp\x-2 And bullet\x<=tmp\x+4) And (bullet\y=>tmp\y And bullet\y<=tmp\y+4)
			player\score=player\score+tmp\typ        ;Score
			Delete bullet                            ;Remove bullet
			Delete tmp                               ;remove brick
			player\shot=0                            ;Alow player to shot again
			Return                                   ;Exit the drawbullet function, because bullet is not active anymore.
		EndIf
	Next
	
	Color $ff,$ff,$0
	Text bullet\x,bullet\y,"|"       ;Draw the bullet
EndIf
Return 

.drawlevel
Color $ff,$ff,$ff
Text 1,1,"Score = "+Player\Score         ;Display score

For tmp.dat = Each dat                   ;Display level data
    f=45*tmp\typ
    Color $ff-f,f,$ff
	Text tmp\x,tmp\y,tmp\typ
Next

If player\score=>maxscore
Color $ff,$ff,$ff 
  Text 10,28,"Game Over"
  Text 10,42,"Press Esc"
EndIf

Return

Data 4,0,0,9,0,0,4
Data 0,1,2,3,2,1,0
Data 0,1,2,0,2,1,0
Data 0,1,2,3,2,1,0

(edit #xxl)