"Digital Space" - screensaver kind of effect

Community Forums/Showcase/"Digital Space" - screensaver kind of effect

Damien Sturdy

(Posted 2009) [#1]

Hi all,

Well, I recently found a screensaver I coded a few years ago in EXE form, source code lost, and decided to recode the visual side of it. Along the way, I made some improvements.

This isn't completely a screensaver, but it prevents multiple loads of itself so you can use it as one if you rename it to SCR and don't mind the preview window not working.

Never mind a download link - Have the source!

'''''''''''''''''''''''''''''''''
''  DIGITAL SPACE SCREENSAVER  ''
'' by Damien Sturdy AKA Cygnus ''
'''''''''''''''''''''''''''''''''
SuperStrict
SeedRnd(MilliSecs())
Global scx:Int = 1920
Global scy:Int = 1080
If FileType("Alreadyopen.dat") <> 0 Then End
Global fs:TStream = WriteFile("Alreadyopen.dat")
CloseFile fs

Type TPattern
	Field currx:Double
	Field curry:DOUBLE
	Field dirx:DOUBLE
	Field diry:DOUBLE
	Field scale:DOUBLE
	Field angle:DOUBLE
	Field startangle:DOUBLE
	Field startcolor:Int
	Field linesize:DOUBLE
	Field linegrowth:DOUBLE
	Field itterations:Float
	Field currentitterations:Float
	Field anglechange:DOUBLE
	Field life:DOUBLE
	Field width:DOUBLE
	
	Field framecount:Int
	
	Field colourmover:Int
	Field colourmoveg:Int
	Field colourmoveb:Int
	
	Global patternlist:TList
	
	Function Init()
		patternlist = New TList
	End Function
	Function renderall()
		For Local p:TPattern = EachIn patternlist
			 p.render()
			 If p.CURRENTitterations < 1 Then patternlist.Remove(p)
		Next
	End Function
	Function Create:TPattern(x:Int, y:Int, angle:DOUBLE)
		Local obj:TPattern = New TPattern
		obj.currx = x
		obj.curry = y
		obj.dirx = Rnd(- 2, 2)
		obj.diry = Rnd(- 2, 2)
		obj.startangle = Rand(0, 99999)
		obj.angle = angle
		obj.dirx = Rnd(- 1, 1)
		obj.diry = Rnd(- 1, 1)
		obj.scale = 1
		obj.linesize = Rand(1, 4)
		obj.itterations:Float = Rand(32, 256)
		obj.anglechange:Double = Rnd(-.01, .01)
		obj.life = 1
		obj.width = Rnd(.2, 10)
		OBJ.linegrowth = OBJ.width / 6.0
		If OBJ.linegrowth < 1 Then OBJ.linegrowth = 1
		
		obj.colourmover = Rnd(1, 14)
		obj.colourmoveg = Rnd(1, 14)
		obj.colourmoveb = Rnd(1, 14)
		OBJ.currentitterations = 1
		
		patternlist.AddFirst(obj)
		Return obj
	End Function

	Method render()
		SetLineWidth width * scale
		framecount = framecount + 1
		Local rotspeed:Double = Sin(framecount / 3)
		Local x:Double = currx
		Local y:Double = curry
		Local linelength:DOUBLE = linesize
		Local currangle:Double = startangle
			
		Local colr:Int
		Local colg:Int
		Local colb:Int
		Local alpha:Double
		Local ALPHAOFF:Float
		Local newy:Double
		Local newx:Double
							
		If LIFE >.1 And CURRENTITTERATIONS < ITTERATIONS Then CURRENTITTERATIONS = CURRENTITTERATIONS +.5
		Local isvalid:Int
		For Local index:Int = 1 To CURRENTitterations
			newy:Double = y + Cos(currangle) * linelength * scale
			newx:Double = x + Sin(currangle) * linelength * scale
			If isvalid = False Then
				If (x > 0 And x < scx And y > 0 And y < scy) Or (newx > 0 And newx < scx And newy > 0 And newy < scy) Then isvalid = True
			EndIf
			currangle = currangle + angle
			linelength = linelength + linegrowth
			colr:Int = (Sin(index * colourmover) + 1) * 128
			colg:Int = (Sin(index * colourmoveg) + 1) * 128
			colb:Int = (Cos(index * colourmoveb) + 1) * 128
			alpha:Double = 1.0 - (Double(index) / Double(CURRENTitterations))

			If alpha <.01 Then Exit
			SetAlpha alpha
			SetColor colr, colg, colb
			DrawLine x, y, newx, Newy, False
			x = newx
			y = newy
		Next
		If isvalid = False Then life = 0;currentitterations = 0
		If life <.1 Then CURRENTitterations = CURRENTitterations -.1
		currx = currx + dirx *.25 * scale
		curry = curry + diry *.25 * scale
		life = life -.001
		angle = angle + anglechange *.5 * rotspeed
		STARTANGLE = STARTANGLE - anglechange *.5 * (itterations / 2.0) * rotspeed
	End Method
	
End Type

Graphics(scx, scy, 32, 60)
TPattern.Init()
Delay 1000
SetBlend ALPHABLEND
Global omousex:Int = MouseX()
Global omousey:Int = MouseY()
Global lastrender:Int = MilliSecs()

Global timeleft:Int = MilliSecs() - lastrender
Global HIGHESTRENDERTIME:Float
	While Not KeyDown(KEY_ESCAPE) And Not AppTerminate()
	lastrender = MilliSecs()
	TPattern.renderall()
	SetColor 255, 255, 255
	SetAlpha 1
	DrawText(Int(HIGHESTRENDERTIME), 10, 10)
	Flip 0
	
	timeleft:Int = MilliSecs() - lastrender
	If timeleft >= HIGHESTRENDERTIME Then HIGHESTRENDERTIME = timeleft Else HIGHESTRENDERTIME = HIGHESTRENDERTIME -.025
	
	'Use the below two lines if you're turning this into a screensaver.
	'If (MouseX() - omousex) <> 0 Then Exit
	'If (MouseY() - omousey) <> 0 Then Exit
	If TPattern.patternlist.Count() < 1000 And HIGHESTRENDERTIME < 13 Then
		If Rand(1, 100) > 95 Then TPattern.Create(Rnd(scx), Rnd(scy), Rnd(70, 170))
	End If
	Delay (1000.0 / 60.0) - timeleft
	Cls
	Wend
DeleteFile("AlreadyOpen.dat")

jsp	(Posted 2009) [#2]

Cool effects and does not suck too much cpu power. Well done.

Dabhand

(Posted 2009) [#3]

Nice work Cyg! :)

I love out like that you know! ;)

Dabz

Damien Sturdy

(Posted 2009) [#4]

Cool effects and does not suck too much cpu power. Well done.

Glad to see that it's worked - It calculates how much time is being taken to do the rendering, and keeps the amount of patterns to a level your machine can handle while keeping smooth.

@Dabs- Glad you like!