black white contrast and maths

Community Forums/Showcase/black white contrast and maths

Nate the Great

(Posted 2009) [#1]

well I was bored and feeling like doing some good ole trig so heres a little program in b3d ill upload an exe and pics tomorrow.

edit: maths in the title is referrring to cos, and sin and black and white reffers to the way I rendered it

Graphics3D 1440,900

plcam = CreateCamera()
MoveEntity plcam,0,0,-8.5
mainpiv = CreatePivot()
EntityParent plcam,mainpiv

CameraZoom plcam,1

SetBuffer BackBuffer()

p1 = CreatePivot()
ScaleEntity p1,.2,.2,.2

count# = 0

CameraClsColor(plcam,255,255,255)

While Not KeyDown(1)
Cls
	count = count + 10
	PositionEntity p1,Cos(count/8)*4,Sin(count/5-30)*4,Cos(count/7-45)*4
	TurnEntity mainpiv,Cos(count/10),Sin(count/10),0
	For i = 0 To 1
		makedrop(EntityX(p1),EntityY(p1),EntityZ(p1),Rnd(-.041,.041)-Cos(count/8)*4+Cos((count-1)/8)*4,Rnd(-.041,.041)-Sin(count/5)*4+Sin((count-1)/5)*4,Rnd(-.041,.041)-Cos(count/7-45)*4+Cos((count-1)/7-45)*4,0,0,0,0);50+Rnd(100),100+Rnd(155),255,0)
	Next
	
	Text 1,1,EntityX(p1)
	Text 1,20,EntityY(p1)
	Text 1,40,EntityZ(p1)
	
	updatedrops()
	TurnEntity plcam,0,45,0
	CameraClsColor(plcam,255,255,255)
	setdropblack()
	CameraViewport(plcam,0,0,720,900)
	RenderWorld()
	TurnEntity plcam,0,-90,0
	CameraClsColor(plcam,0,0,0)
	setdropwhite()
	CameraViewport(plcam,720,0,720,900)
	RenderWorld()
	TurnEntity plcam,0,45,0
Flip
Wend


Function setdropblack()
	For d.drop = Each drop
		EntityColor d\ent,0,0,0
	Next
End Function

Function setdropwhite()
	For d.drop = Each drop
		EntityColor d\ent,255,255,255
	Next
End Function


Type drop	;they shoot out of your tail
	Field x#
	Field y#
	Field z#
	Field dx#
	Field dy#
	Field dz#
	Field r,g,b
	Field ent
	Field life
End Type

Function makedrop(x#,y#,z#,dx#,dy#,dz#,b,g,r,shp)	;makes a drop with x,y,z and dx,dy,dz speed, r,g,b color and shp describes the shape
	Local d.drop = New drop
	d\x = x
	d\y = y
	d\z = z
	d\dx = dx
	d\dy = dy
	d\dz = dz
	
	d\r = r
	d\g = g
	d\b = b
	
	Select shp
	Case 0
		d\ent = CreateSphere(8)
	Case 1
		d\ent = CreateCone(3)
	Case 2
		d\ent = CreateCube()
	Case 3
		d\ent = CreateSphere(2)
	End Select
	ScaleEntity d\ent,.3,.3,.3
	TurnEntity d\ent,Rnd(360),Rnd(360),Rnd(360)
	EntityColor d\ent,r,g,b
	EntityFX d\ent,1
End Function

Function removedrop(d.drop)	;delete a drop
	FreeEntity d\ent
	Delete d.drop
End Function

Function updatedrops()
	For d.drop = Each drop
		d\x = d\x + d\dx
		d\y = d\y + d\dy
		d\z = d\z + d\dz
		d\dx = d\dx/1.3
		d\dy = d\dy/1.3	
		d\dz = d\dz/1.3	
		PositionEntity d\ent,d\x,d\y,d\z
		d\life = d\life + 1
		If d\life > 490 Then
			l1# = 500-d\life
			l1#=l1#/10
			EntityAlpha d\ent,l1#
		EndIf
		If d\life > 500 ;Or (d\dx*d\dx + d\dy*d\dy + d\dz*d\dz) <= .000001 Then
			removedrop(d.drop)
		EndIf
	Next
End Function