Pseudo 3D Starfield

Monkey Archive Forums/Monkey Apps/Pseudo 3D Starfield

DarkyCrystal

(Posted 2013) [#1]

Pseudo 3D Starfield discussion thread. Please leave your feedback here.

Yoda	(Posted 2016) [#2]

Is there a source code of this somewhere?

therevills

(Posted 2016) [#3]

Not sure what code DarkyCrystal used, but here is my code for a similar effect (it follows the mouse too):

Strict
Import mojo

Function Main:Int()
	New MyApp()
	Return 0
End

Class MyApp Extends App
	Const FPS:Int = 60
	Field delta:DeltaTimer
	
	Method OnCreate:Int()
		delta = New DeltaTimer(FPS)
		SetUpdateRate(FPS)
		Star.Init()
		Return 0
	End
	
	Method OnUpdate:Int()
		delta.UpdateDelta()
		Star.UpdateAll(delta.delta)
		Return 0
	End
	
	Method OnRender:Int()
		Cls()
		Star.RenderAll()
		Return 0
	End
End

Class Star
	Field x:Float, y:Float, z:Float
	Global star:Star[1024]
	
	Function Init:Void()
		For Local i:Int = 0 Until star.Length
			star[i] = New Star
		Next
	End
	
	Function UpdateAll:Void(delta:Float)	
		For Local i:Int = 0 Until star.Length
			star[i].Update(delta)
		Next
	End
	
	Function RenderAll:Void()
		For Local i:Int = 0 Until star.Length
			star[i].Draw()
		Next
	End
	
	Method New()
		x = Rnd(-100, 100)
		y = Rnd(-100, 100)
		z = Rnd(-100, 100)
	End

	Method Update:Void(delta:Float)
		z -= 1 * delta
		x -= ( (MouseX() - DeviceWidth() / 2) / 200) * delta
		y -= ( (MouseY() - DeviceHeight() / 2) / 200) * delta
		If z <= - 100 z += 200
		If x <= - 100 x += 200
		If y <= - 100 y += 200
		If x >= 100 x -= 200
		If y >= 100 y -= 200
	End
	
	Method Draw:Void()
		Local i:Int = z + 121
		Local px:Int = x * 450 / (z + 151)
		Local py:Int = y * 350 / (z + 151)
		SetColor 255 - i, 255 - i, 255 - i
		DrawRect(DeviceWidth() / 2 + px, DeviceHeight() / 2 + py, 2, 2)
		SetColor 255, 255, 255
	End
End

'summary: DeltaTimer by James Boyd
Class DeltaTimer
	Field targetfps:Float = 60
	Field currentticks:Float
	Field lastticks:Float
	Field frametime:Float
	Field delta:Float
	
	Method New (fps:Float)
		targetfps = fps
		lastticks = Millisecs()
	End
	
	Method UpdateDelta:Void()
		currentticks = Millisecs()
		frametime = currentticks - lastticks
		delta = frametime / (1000.0 / targetfps)
		If delta > 5 Then
			delta = 1
		End
		lastticks = currentticks
	End
End