Collision layers a la Blitzmax

Monkey Forums/Monkey Code/Collision layers a la Blitzmax

GfK	(Posted 2011) [#1]

Note, this only functions for rect-to-rect collisions because that's all I need it for. Still very much a work in progress (and untidy!) so feel free to improve it (and share!):

test.monkey (example/demo code)

Import mojo

Import collision

Function Main:Int()
    New myApp
End Function

Class myApp extends App
	Field collisions:CollisionHandler
	Field collided:TestClass
	
	Method OnCreate()
		Self.collisions = New CollisionHandler(5)
		SetUpdateRate(30)
                'create some test objects to collide with
		Local t:TestClass
		t = New TestClass("Tom")
		Self.collisions.CollideRect(100,0,200,24,0, t)
		t = New TestClass("Dick")
		Self.collisions.CollideRect(100,200,50,50,0,t)
		t = New TestClass("Harry")
		Self.collisions.CollideRect(200,300,20,100,0,t)
	End Method

	Method OnUpdate()
		Local obj:Object[]
		
		obj = Self.collisions.CheckCollisions(MouseX(),MouseY(),1,1,0)
		if obj.Length() > 0
			Self.collided = TestClass(obj[0])
		Else
			Self.collided = Null
		EndIf
	End Method
		
	Method OnRender()
		Cls
		SetColor(255,0,0)
		Self.collisions.Debug_DrawLayer(0)
		if Self.collided
			DrawText Self.collided.name, 10, 30
		EndIf
	End Method
End Class 

Class TestClass
	Field name:String
	
	Method New(name:String)
		Self.name = name
	End Method
End Class

collision.monkey

Import mojo

Class CollisionHandler
	Field layer:CollisionLayer[]
	Method New(layers:Int)
		Self.layer = Self.layer.Resize(layers)
		For Local n:Int = 0 to layers - 1
			layer[n] = New CollisionLayer
		Next
	End Method

	Method CollideRect(x:Float, y:Float, width:Float, height:Float, layer:Int, obj:Object = Null)
		Local c:CollisionRectangle = New CollisionRectangle
		c.x = x
		c.y = y
		c.width = width
		c.height = height
		Self.layer[layer].index.Set(Self.layer[layer].IDPtr, c)
		Self.layer[layer].data.Set(Self.layer[layer].IDPtr,obj)
		Self.layer[layer].IDPtr+=1
	End Method
	
	Method CheckCollisions:Object[](x1:Int, y1:Int, width1:Int, height1:Int, layer:Int)
		Local x2:Int, y2:Int, width2:Int, height2:Int	
		
		Local rect:CollisionRectangle
		Local id:Int
		Local arr:Object[]
		
		For id = EachIn Self.layer[layer].index.Keys()
			rect = Self.layer[layer].index.ValueForKey(id)
			if Not((x1 + width1 < rect.x or x1 > rect.x + rect.width) Or ( y1 + height1 < rect.y or y1 > rect.y + rect.height))
				arr = arr.Resize(arr.Length() + 1)
				arr[arr.Length()-1] = Self.layer[layer].data.ValueForKey(id)
				
			EndIf
		Next
		Return arr
	End Method
	
	Method Debug_DrawLayer(layer:Int)
		Local obj:Object
		Local rect:CollisionRectangle
		SetColor 255,0,0
		For Local n:Int = EachIn Self.layer[layer].index.Keys()
			rect = CollisionRectangle(Self.layer[layer].index.ValueForKey(n))
			If rect
				DrawRect(rect.x,rect.y,rect.width,rect.height)
			EndIf
		Next
	End Method
	
	Method ResetCollisions(layer:Int = -1)
		if layer = -1
			For Local n:Int = 0 to self.layer.Length() - 1
				Self.layer[n] = New CollisionLayer
			Next
		Else
			Self.layer[layer] = New CollisionLayer
		EndIf
	End Method
End Class

Class CollisionLayer
	Field index:IntMap<CollisionRectangle>
	Field data:IntMap<Object>
	Private
	Field IDPtr:Int ' unique object key - don't meddle!
	Public
	
	Method New()
		Self.index = New IntMap<CollisionRectangle>
		Self.data = New IntMap<Object>
	End Method
	
End Class

Class CollisionRectangle
	Field x:Float
	Field y:Float
	Field width:Float
	Field height:Float
End Class

Pete Carter

(Posted 2011) [#2]

Thanks for this