Point inside a triangle

Monkey Forums/Monkey Code/Point inside a triangle

JIM	(Posted 2011) [#1]

Hey guys,

Here's a function that checks if a point is inside a triangle. It uses barycentric coordinates to speed things up.

Function PointInsideTriangle:Bool(px:Float, py:Float, tri:Float[])
	If (tri.Length() <> 6)
		Print("WARNING: Trying to check against an abomination, not a triangle!")
		Return False
	EndIf
	
	Local v0x:Float = tri[4] - tri[0]
	Local v0y:Float = tri[5] - tri[1]
	Local v1x:Float = tri[2] - tri[0]
	Local v1y:Float = tri[3] - tri[1]
	Local v2x:Float = px - tri[0]
	Local v2y:Float = py - tri[1]
	
	Local dot00:Float = v0x * v0x + v0y * v0y
	Local dot01:Float = v0x * v1x + v0y * v1y
	Local dot02:Float = v0x * v2x + v0y * v2y
	Local dot11:Float = v1x * v1x + v1y * v1y
	Local dot12:Float = v1x * v2x + v1y * v2y
	
	Local invDenom:Float = 1.0 / (dot00 * dot11 - dot01 * dot01)
	Local u:Float = (dot11 * dot02 - dot01 * dot12) * invDenom
	Local v:Float = (dot00 * dot12 - dot01 * dot02) * invDenom
	
	Return ((u >= 0) And (v >= 0) And ((u + v) < 1))
End

Here's a quick example to test it:

Import mojo

Global t:Float[] = [100.0, 100.0, 250.0, 50.0, 300.0, 250.0]

Class MyApp Extends App
	Method OnCreate()
		SetUpdateRate(60)
	End
	
	Method OnRender()
		Cls
		
		If (PointInsideTriangle(MouseX(), MouseY(), t))
			SetColor(0, 255, 0)
		Else
			SetColor(255, 0, 0)
		EndIf
		
		DrawPoly(t)
	End
End

Function Main:Int()
	New MyApp
End

Enjoy! :)