mojo.graphics functions: ShearX/Y, MirrorX/Y

Monkey Forums/Monkey Code/mojo.graphics functions: ShearX/Y, MirrorX/Y

Danilo

(Posted 2014) [#1]

Strict

Import mojo

' -------------------------------------------------------------------------
' mojo.graphics missing functions
'

' - Shear/Skew  -------------------->> REQUIRES DECISION: What's the best name? Skew or Shear?
Function SkewX:Void(angle:Float)
    Transform(1,0,Tan(angle),1,0,0)
End

Function SkewY:Void(angle:Float)
    Transform(1,Tan(angle),0,1,0,0)
End

Function ShearX:Void(angle:Float)
    Transform(1,0,Tan(angle),1,0,0)
End

Function ShearY:Void(angle:Float)
    Transform(1,Tan(angle),0,1,0,0)
End


' - Mirror
Function MirrorX:Void()
    Transform(1,0,0,-1,0,0)
End

Function MirrorY:Void()
    Transform(-1,0,0,1,0,0)
End

' - 'At' functions apply a function
'        at/around a specific point

' - Shear/Skew  -------------------->> REQUIRES DECISION: What's the best name? Skew or Shear?
Function SkewXAt:Void(x:Float, y:Float, angle:Float)
    Translate(x, y)
    Transform(1,0,Tan(angle),1,0,0)
    Translate(-x, -y)
End

Function SkewYAt:Void(x:Float, y:Float, angle:Float)
    Translate(x, y)
    Transform(1,Tan(angle),0,1,0,0)
    Translate(-x, -y)
End

Function ShearXAt:Void(x:Float, y:Float, angle:Float)
    Translate(x, y)
    Transform(1,0,Tan(angle),1,0,0)
    Translate(-x, -y)
End

Function ShearYAt:Void(x:Float, y:Float, angle:Float)
    Translate(x, y)
    Transform(1,Tan(angle),0,1,0,0)
    Translate(-x, -y)
End


Function RotateAt:Void(x:Float, y:Float, angle:Float)
    Translate(x, y)
    Rotate(angle)
    Translate(-x, -y)
End

Function ScaleAt:Void(x:Float, y:Float, scaleX:Float, scaleY:Float)
    Translate(x, y)
    Scale(scaleX, scaleY)
    Translate(-x, -y)
End

Function MirrorXAt:Void(x:Float, y:Float)
    Translate(x, y)
    Transform(1,0,0,-1,0,0)
    Translate(-x, -y)
End

Function MirrorYAt:Void(x:Float, y:Float)
    Translate(x, y)
    Transform(-1,0,0,1,0,0)
    Translate(-x, -y)
End

' - reset Matrix to standard
Function ResetMatrix:Void()
    SetMatrix(1,0,0,1,0,0)
End
'
' -------------------------------------------------------------------------

Class Program Extends App

    Field angle:Float = 0.0
    Field mode:Int = 21
    Field modeNames:String[] = [ "Default", "MirrorX", "MirrorY",
                                 "MirrorX + MirrorY", "ShearX", "ShearY",
                                 "ShearX + ShearY", "ShearX + Rotate",
                                 "Rotate + ShearX + ShearY + Rotate",
                                 "Rotate + ShearX + ShearY + Rotate",
                                 "Scale 0.1 + ShearX + Rotate",
                                 "Scale 0.2 + ShearX + Rotate",
                                 "Scale 0.4 + ShearX + Rotate",
                                 "Scale 0.8 + ShearX + Rotate",
                                 "Scale 1.6 + ShearX + Rotate",
                                 "Scale 3.2 + ShearX + Rotate",
                                 "Scale 6.4 + ShearX + Rotate",
                                 "Scale 3/1 + ShearY + Rotate",
                                 "ShearX", "ShearY", "ShearX + ShearY",
                                 "" ]

    Method OnCreate:Int()
        SetUpdateRate 30
        Return 0
    End
    
    Method OnUpdate:Int()
        If KeyHit(KEY_LMB) Or KeyHit(KEY_SPACE)
            mode += 1
            If mode < 11 Or mode > 17
                angle = 0
            endif
        Endif

        If mode > 20 Then mode = 0

        angle += 1

        Return 0
    End

    Method OnRender:Int()
        Local midX:Float = DeviceWidth() *0.5
        Local midY:Float = DeviceHeight()*0.5

        Cls(64,64,64)
        
        Select mode
            Case 1
                MirrorXAt(midX, midY)
            Case 2
                MirrorYAt(midX, midY)
            Case 3
                MirrorXAt(midX, midY)
                MirrorYAt(midX, midY)
            Case 4
                ShearXAt(midX, midY, -20)
            Case 5
                ShearYAt(midX, midY, -20)
            Case 6
                ShearXAt(midX, midY, 30)
                ShearYAt(midX, midY, 30)
            Case 7
                ScaleAt(midX, midY, 1, 0.3)
                ShearXAt(midX, midY, 45)
                RotateAt(midX, midY, angle)
            Case 8
                ScaleAt(midX, midY, 1, 0.3)
                RotateAt(midX, midY, -angle)
                ShearXAt(midX, midY, 45)
                ShearYAt(midX, midY, 45)
                RotateAt(midX, midY, angle)
            Case 9
                RotateAt(midX, midY, -angle)
                ShearXAt(midX, midY, 45)
                ShearYAt(midX, midY, -45)
                RotateAt(midX, midY, angle)
            Case 10
                ScaleAt(midX, midY, 1, 0.1)
                ShearXAt(midX, midY, -45)
                RotateAt(midX, midY, angle)
            Case 11
                ScaleAt(midX, midY, 1, 0.2)
                ShearXAt(midX, midY, -45)
                RotateAt(midX, midY, angle)
            Case 12
                ScaleAt(midX, midY, 1, 0.4)
                ShearXAt(midX, midY, -45)
                RotateAt(midX, midY, angle)
            Case 13
                ScaleAt(midX, midY, 1, 0.8)
                ShearXAt(midX, midY, -45)
                RotateAt(midX, midY, angle)
            Case 14
                ScaleAt(midX, midY, 1, 1.6)
                ShearXAt(midX, midY, -45)
                RotateAt(midX, midY, angle)
            Case 15
                ScaleAt(midX, midY, 1, 3.2)
                ShearXAt(midX, midY, -45)
                RotateAt(midX, midY, angle)
            Case 16
                ScaleAt(midX, midY, 1, 6.4)
                ShearXAt(midX, midY, -45)
                RotateAt(midX, midY, angle)
            Case 17
                ScaleAt(midX, midY, 3, 1)
                ShearYAt(midX, midY, -45)
                RotateAt(midX, midY, -angle)
            Case 18
                If angle=160 Then angle = 0
                ShearXAt(midX, midY, angle-80)
            Case 19
                If angle=160 Then angle = 0
                ShearYAt(midX, midY, angle-80)
            Case 20
                If angle=160 Then angle = 0
                ShearXAt(midX, midY,-angle+80)
                ShearYAt(midX, midY, angle-80)
        End Select

        '
        ' Draw the stuff:
        '
        ' the rect
        SetColor(255,255,255)
        DrawRect(midX-100, midY-100,200, 200)
        ' 2 lines
        SetColor(0,0,0)
        DrawLine(midX-100, midY-100, midX+100, midY+100)
        DrawLine(midX-100, midY+100, midX+100, midY-100)
        ' 4 circles at the rect corners
        SetColor(255,0,0)
        DrawCircle(midX-100, midY-100, 10)
        SetColor(0,255,0)
        DrawCircle(midX+100, midY-100, 10)
        SetColor(0,255,255)
        DrawCircle(midX-100, midY+100, 10)
        SetColor(0,0,255)
        DrawCircle(midX+100, midY+100, 10)
        ' text
        SetColor(255,255,0)
        DrawText("Some Text", midX-70, midY-70)

        ' draw info text
        ResetMatrix()
        DrawText("Mode: "+String(mode)+" = "+modeNames[mode], 10, 10)
        DrawText("press left mouse button or space for next mode", 10, 30)

        Return 0
    End
End

Function Main:Int()
    New Program
    Return 0
End

degac

(Posted 2014) [#2]

Cool!
I spent time for looking something like this! (without results :()
Many thanks!

Goodlookinguy

(Posted 2014) [#3]

Isn't the more commonly used word for 'Shear', 'Skew'? Anyways, neat code. I recommend you put the code in the [ codebox ] tag since it's so big.

MikeHart

(Posted 2014) [#4]

Cool. I recomment that you make a push request into Mark's repository so it becomes a mojo standard.

Danilo

(Posted 2014) [#5]

OK, replaced all "Shear" with "Skew". Native english speakers know better.

Goodlookinguy

(Posted 2014) [#6]

I was actually just asking a question. I had heard the word shear before used to represent what I thought was skew. I actually don't know the difference if any.

Danilo

(Posted 2014) [#7]

@MikeHart: Push request done.

DruggedBunny

(Posted 2014) [#8]

Cool, would be nice to have this stuff as standard!

therevills

(Posted 2014) [#9]

Nice ... just dont expect these to work with MonkeyMax ;)

Midimaster

(Posted 2014) [#10]

Nice collection of functions... but really no need for integrate them into official monkey! too trivial!

here's another one:

Function DoubleSize:Void()
     Scale 2,2
End

;-)