XXTEA encryption / decryption for Monkey

Monkey Forums/Monkey Code/XXTEA encryption / decryption for Monkey

Pharmhaus

(Posted 2014) [#1]

This is the XXTEA function ported to Monkey.
EDIT: OK, simplistic string support is now given. It uses the databuffer to bypass encoding/decoding of strings.

Strict
Import brl.databuffer

Class XXTea
	Const DELTA:Int = -1640531527
	
	'summary: encrypts or decrypts the array v[] (4 byte aligned). n should be V.Length-1 for encryption or -(V.Length-1) for decryption. key should have a length of 4.
	Function btea:Void(v:Int[], n:int, key:int[])
		Local y:int, z:int, sum:int
		Local p:Int, rounds:Int, e:int
		
		If key.Length < 2 or key.Length > 4 Then Return
		
		If (n > 1)  ' Coding Part
			rounds = 6 + 52 / n
			sum = 0
			z = v[n-1];
			Repeat
				sum += DELTA
				e = (sum shr 2) & ~ ( ( (1 shl 32) shr 2) shl 1) & 3
				p = 0
				While (p < n - 1)
					y = v[p + 1]
					v[p] += ( ( ( (z shr 5) & ~ ( ( (1 shl 32) shr 5) shl 1) ~ y shl 2) + ( (y shr 3) & ~ ( ( (1 shl 32) shr 3) shl 1) ~ z shl 4)) ~ ( (sum ~ y) + (key[ (p & 3) ~ e] ~ z)))
					z = v[p]
					p += 1
				Wend
				y = v[0];
				v[n - 1] += ( ( ( (z shr 5) & ~ ( ( (1 shl 32) shr 5) shl 1) ~ y shl 2) + ( (y shr 3) & ~ ( ( (1 shl 32) shr 3) shl 1) ~ z shl 4)) ~ ( (sum ~ y) + (key[ (p & 3) ~ e] ~ z)))
				z = v[n - 1]
				rounds -= 1
			Until Not (rounds)
		ElseIf(n < - 1)  ' Decoding Part
			n = -n
			rounds = 6 + 52 / n
			sum = rounds * DELTA
			y = v[0]
			Repeat
				e = (sum shr 2) & ~ ( ( (1 shl 32) shr 2) shl 1) & 3
				p = n - 1
				While (p > 0)
					z = v[p - 1]
					v[p] -= ( ( ( (z shr 5) & ~ ( ( (1 shl 32) shr 5) shl 1) ~ y shl 2) + ( (y shr 3) & ~ ( ( (1 shl 32) shr 3) shl 1) ~ z shl 4)) ~ ( (sum ~ y) + (key[ (p & 3) ~ e] ~ z)))
					y = v[p]
					p -= 1
				Wend
				
				z = v[n - 1]
				v[0] -= ( ( ( (z shr 5) & ~ ( ( (1 shl 32) shr 5) shl 1) ~ y shl 2) + ( (y shr 3) & ~ ( ( (1 shl 32) shr 3) shl 1) ~ z shl 4)) ~ ( (sum ~ y) + (key[ (p & 3) ~ e] ~ z)))
				y = v[0]
				sum -= DELTA
			Until Not (sum <> 0)
		EndIf
	End
	
	'summary: Encrypts a string and returns a databuffer. Key should have a Length of 4
	Function EncryptString:DataBuffer(S:String, key:Int[])
		Local arr:= S.ToChars()
		Local D:DataBuffer = New DataBuffer(arr.Length * 4)
		
		btea(arr, (arr.Length - 1), key)
		D.PokeInts(0, arr, 0, D.Length)
		
		Return D
	End
	
	'summary: Decrypts a databuffer and returns a string. Key should have a Length of 4
	Function DecryptString:String(D:DataBuffer, key:Int[])
		Local Str:String
		Local arr:Int[D.Length / 4]
		Local xtra:Int
		
		D.PeekInts(0, arr, 0, D.Length)
		btea(arr, - (arr.Length - 1), key)
		Str = String.FromChars(arr)
	
		Return Str
	End

End

Small example that i used for testing:

Strict

Import "xxtea.monkey"

Function Main:Int()
	Local ar:Int[1024]
	Local k:=[123, 456, 769, 123]
	ar[15] = 12345
	XXTea.btea(ar, (ar.Length - 1), k)
	Print ar[15]
	XXTea.btea(ar, - (ar.Length - 1), k)
	Print ar[15]
	
	
	Print XXTea.DecryptString(XXTea.EncryptString("Hello world, how are you ?", k), k)
	Return 0
End

Supertino

(Posted 2014) [#2]

Always nice to have, though strings for me would be more useful. Thanks for this,

Pharmhaus

(Posted 2014) [#3]

Will this do it for you?
It's not 'real' string support because it uses the Databuffer but it should work as long as you use a binary format.