go through list backwards

Monkey Forums/Monkey Programming/go through list backwards

slenkar

(Posted 2011) [#1]

is it possible to go through a list backwards?

Canardian

(Posted 2011) [#2]

You could use a Stack and access the elements with the Get(index) method.

slenkar

(Posted 2011) [#3]

thanks for the suggestion , ill take a look

Wagenheimer

(Posted 2011) [#4]

What is a stack?

I need to get a random item in a list, is that possible? I could not find the .get method in the TList.

therevills

(Posted 2011) [#5]

You could do something like this:

	Function getRandomSprite:Sprite()
		Local r% = 0
		Local rand% = Rnd(0, Sprite.list.Count())
		Local rndSprite:Sprite
		For Local s:Sprite = Eachin Sprite.list
			If r = rand Then
				rndSprite = s
				Exit
			EndIf
			r+=1
		Next
		Return rndSprite
	End Function

Full Code:

Strict

import mojo

Global myGame:MyGame

Function Main:int()
	myGame = new MyGame
	return 0
End Function

Class MyGame extends App

	Method OnCreate:Int()
		SetUpdateRate 60
		
		Seed = Millisecs()
		
		Local id% = 0
		For Local i% = 0 to 4
			New Alien(Rnd(0, DeviceWidth()), Rnd(0, DeviceHeight()), id)
			id+=1
		Next
		
		For Local i% = 0 to 4
			New Player(Rnd(0, DeviceWidth()), Rnd(0, DeviceHeight()), id)
			id+=1
		Next	

		
				
		
		return 0
	End Method
	
	Method OnLoading:Int()
		return 0
	End Method
	
	Method OnUpdate:Int()
		If KeyHit(KEY_SPACE)
			Local s:Sprite = Sprite.getRandomSprite()
			For Local i:Sprite = Eachin Sprite.list
				i.alpha = 0.5
			Next
			s.alpha = 1
		EndIf
		return 0
	End Method
	
	Method OnRender:Int()
		Cls
		Sprite.DrawAll()
		return 0
	End Method	
end class

Class Sprite
	Field x#, y#
	Field id%, alpha# = 0.5
	Global list:List<Sprite> = new List<Sprite>
	
	Function DrawAll:Void()
		For Local s:Sprite = Eachin list
			s.Draw()
			DrawText s.id, s.x, s.y
		Next
	End Function
	
	Method Draw:Void() Abstract
	
	Function getRandomSprite:Sprite()
		Local r% = 0
		Local rand% = Rnd(0, Sprite.list.Count())
		Local rndSprite:Sprite
		For Local s:Sprite = Eachin Sprite.list
			If r = rand Then
				rndSprite = s
				Exit
			EndIf
			r+=1
		Next
		Return rndSprite
	End Function
	
End Class

Class Alien Extends Sprite
	Method New(x#, y#, id%)
		self.x = x
		self.y = y
		self.id = id
		Sprite.list.AddLast(self)
	End Method
	
	Method Draw:Void()
		SetAlpha alpha
		SetColor 255, 0, 0
		DrawRect x, y, 20, 20
		SetColor 255, 255, 255
		SetAlpha 1
	End Method
End Class

Class Player Extends Sprite
	Method New(x#, y#, id%)
		self.x = x
		self.y = y
		self.id = id
		Sprite.list.AddLast(self)
	End Method
	
	Method Draw:Void()
		SetAlpha alpha
		SetColor 0, 255, 0
		DrawOval x, y, 20, 20
		SetColor 255, 255, 255
		SetAlpha 1
	End Method
End Class

Jesse

(Posted 2011) [#6]

you can use nodes to remove items from the list such as with with Bmax's "Tlink".

Canardian

(Posted 2011) [#7]

@Wagenheimer: a Stack is like a List, but it has direct .Get/.Set methods. See in modules/monkey/stack.monkey for documentation about the commands.

slenkar

(Posted 2011) [#8]

i changed my list to a stack and it was easy to go backwards through it