Box2D

Self.SetGravity(0.0,10) 

'A Simplfield Demo Assamabled from Other Demos Thanks to Volker and muddy_shoes and my own style as well.

'Shows In Real Basic Way how Box2D Engine works.
'Any one who see a place for corrections in the code and new Remarks
'Is free to do it and republish. All in good of helping the new guys around here.
'If you find this demo usufale I will be glad to know and will be encorouged to make more demos of that sort for begginers among this community (Like me)


'----Includes----'
Import box2d.collision
Import box2d.collision.shapes
Import box2d.common.math
Import box2d.dynamics.contacts
Import box2d.dynamics
Import box2d.flash.flashtypes
Import box2d.common.math.b2vec2

'----Test Zone----'
Function Main()
	New Box2DLoop	
End Function

'----Main Loop----'
Class Box2DLoop Extends App

	'Box 2D Parameters Set
	Field BXworld				: b2World					'Box2D physical World Object
	Field m_velocityIterations	: int 	= 10				'Dont know whats this yet.
    Field m_positionIterations	: int 	= 10				'Either that.
    Field m_timeStep			: Float = 1.0/60			'Hmm, I know whats this but no changes accured when presetting.
    Field m_physScale			: Float = 1 ' 30       		'I Change its value but same results.
	Field m_debugdrawscale		: Float	= 10	 			'This Affects the size of the physical Body Display
			
	Field b:b2Body 			      'A phsyical body Type of box2d decleration.
	
	
	'--Main Methods----'
	
	Method OnCreate()
	
		'Box2D Setups
		Local doSleep:Bool = True		
			  
		'Creating a new Box2D World
		 BXworld = New b2World(New b2Vec2(0,0),doSleep)	
		 SetGravity(0.0,9.7) 
		
		'Creating a Ground Box
		'From some reason, if you dont create this ground box nothing works...
		b=self.CreateBox(0,40,70,2)
		b.SetUserData(New StringObject("ground")) 'give object a name for collision detection in contactlistener
		
		'Display Setup
		SetUpdateRate(60)
		
		'Box2D Debug Settings   		'Delete this section if you dont need to see the physical process in graphics.
		Local dbgDraw :b2DebugDraw = New b2DebugDraw()       
	          dbgDraw.SetDrawScale(m_debugdrawscale) 
		      dbgDraw.SetFillAlpha(0.3)
		      dbgDraw.SetLineThickness(1.0)
		      dbgDraw.SetFlags(b2DebugDraw.e_shapeBit | b2DebugDraw.e_jointBit)'| b2DebugDraw.e_pairBit)
		      BXworld.SetDebugDraw(dbgDraw)
		
	End Method
	
	Method OnRender()
		Cls		
		
		'Box2D Display Section
		 BXworld.DrawDebugData() 'Delete this line if you dont need to see the physical process in graphics. (must also delete 'Box2D Debug Settings section above)
				 
		 '(Mojo commands must come only after the Box2D Debug Draw or it wont be seeing)
		 
		 'Mojo Display Section
		  SetColor 255,255,255
		  DrawText 	"Obj X Position: "+b.GetPosition.x*10,5,425
		  DrawText 	"Obj Y Position: "+b.GetPosition.y*10,5,440 
		  
		  DrawText "Press Mouse Button to create a new Sphere",5,458
		  
	End Method
	
	Method OnUpdate()
					
		'The Stepping of Box2D Engine
		BXworld.TimeStep(m_timeStep,m_velocityIterations,m_positionIterations)
		BXworld.ClearForces()	'Dont know why you need this..	
				
		'Add a new Sphere
		If( MouseHit( MOUSE_LEFT) ) 						
			b=Self.CreateSphere(MouseX()/10,MouseY()/10,4)	'Creates a new Physical Sphere.
			b.SetUserData(New StringObject("sphere"))		'Dont know what this for.
			
			Print "A New Sphere Created"
		End
	End Method
	
	'------------Create Sphere,Box And Set Gravity Functions-----------------------------'
	
	Method CreateSphere:b2Body (xpos:Float,ypos:Float,radius:Float,static:Bool=false)	'Creates a Physical Sphere
		Local fd :b2FixtureDef = New b2FixtureDef()
		Local bd :b2BodyDef = New b2BodyDef()
		Local cd :b2CircleShape = New b2CircleShape()	  
		'		
		cd.m_radius  = radius
		fd.density = 2
		fd.restitution = 0.2
		fd.friction = 0.5
		fd.shape=cd
		if static=true
			bd.type = b2Body.b2_staticBody ' a static body
		else
			bd.type = b2Body.b2_Body 'a dynamic body
		endif
		bd.position.Set(xpos,ypos)
		Local b :b2Body
		b = self.BXworld.CreateBody(bd)
		b=Self.BXworld.CreateBody(bd)
		b.CreateFixture(fd) 			
		Return b	
	End Method
	
	Method CreateBox:b2Body (xpos:Float,ypos:Float,width:Float,height:Float,static:Bool=true)	'Creates a Physical Box
		Local fd :b2FixtureDef = New b2FixtureDef()
		Local sd :b2PolygonShape = New b2PolygonShape()
		Local bd :b2BodyDef = New b2BodyDef()
		if static=true
			bd.type = b2Body.b2_staticBody
		else
			bd.type = b2Body.b2_Body
		endif		
		fd.density = 1.0 
		fd.friction = 0.5
		fd.restitution = 0.1
		fd.shape = sd
		sd.SetAsBox(width,height)
		bd.position.Set(xpos,ypos)
		Local b :b2Body
		b = self.BXworld.CreateBody(bd)		
		b.CreateFixture(fd)	
		'
		Return b	
	End Method
	
	Method SetGravity:Void(x:Float,y:Float)	'An easier Method to setup gravity
		Self.BXworld.SetGravity(New b2Vec2(x,y))
	End Method
	
End Class

Local rotation:Float=RadToDeg(body.GetAngle())*-1
DrawImage(yourimage,body.x,body.y,rotation,1,1)

Function RadToDeg:Int(rad:Float)
  ' converts radian to degrees. Box2D uses radians, Monkey degrees.
  Return rad*180/PI
End Function

'----Includes----'
Import box2d.dynamics.b2world

'----Test Zone----'
Function Main()
	New Box2DLoop()
End Function

'----Main Loop----'
Class Box2DLoop Extends App

	Field _world:b2World

	Field RATIO:Float = 8
	
	Field _nextCrateIn:Int
	
	
	
	'--Main Methods----'
	
	Method OnCreate()
	
		' 1. Set Up World
		setupWorld()
		' Create Walls and Floors
		createWallsAndFloor()
		setupDebugDraw()
		_nextCrateIn = 0
		
	
		'Display Setup
		SetUpdateRate(60)
		

			  
	End Method
	
	Method setupDebugDraw:Void()
	
	
	    
			'Box2D Debug Settings   		'Delete this section if you dont need to see the physical process in graphics.
		Local dbgDraw :b2DebugDraw = New b2DebugDraw()       
	    
        dbgDraw.SetDrawScale(10.0)
        dbgDraw.SetFillAlpha(0.3)
        dbgDraw.SetLineThickness(1.0)
        dbgDraw.SetFlags(b2DebugDraw.e_shapeBit | b2DebugDraw.e_jointBit)'| b2DebugDraw.e_pairBit)
        _world.SetDebugDraw(dbgDraw)
		
	End
	Method OnRender()
		Cls		
		
		_world.DrawDebugData()
		  
	
		
	End Method
	
	Method OnUpdate()
					
		_world.TimeStep(1.0 /30,10,10)
		_world.ClearForces()
		
		_nextCrateIn = _nextCrateIn - 1
		
		if _nextCrateIn  <=0 And _world.m_bodyCount < 80 Then
			addARandomCrate()
			_nextCrateIn = 10
		EndIf
		
	End Method
	
	
	Method setupWorld()
	
		
		
		' Define gravity
		Local gravity:b2Vec2 = new b2Vec2(0,9.8)
		
		' Ignore Sleeping Objects
		Local ignoresleeping:Bool = true
		
		_world = New b2World(gravity,ignoresleeping)

		
		
		
	End
	
	Method addARandomCrate()
		Local fd:b2FixtureDef = new b2FixtureDef()
		Local sd:b2PolygonShape = new b2PolygonShape()
		Local bd:b2BodyDef = new b2BodyDef();
		bd.type = b2Body.b2_Body
		
		fd.friction = 0.8
		fd.restitution = 0.3
		fd.density = 0.7
		fd.shape = sd
		
		sd.SetAsBox(randomInt(5,40) / RATIO, randomInt(5, 40) / RATIO)
		
		bd.position.Set(randomInt(15,530) / RATIO, randomInt(-100, -10) / RATIO)
		bd.angle = randomInt(0,360) * 3.14 / 180
		
		Local b:b2Body = _world.CreateBody(bd)
		b.CreateFixture(fd)
	
	End
	
	Method randomInt:Int(lowVal:Int, highVal:Int)
		
		if (lowVal <= highVal)
			
			Return lowVal + Floor(Rnd() * (highVal - lowVal + 1))
			
		EndIf
	End
	
	Method createWallsAndFloor:Void()
		
		Local sd:b2PolygonShape = new b2PolygonShape()
		Local fd:b2FixtureDef = new b2FixtureDef()
		Local bd:b2BodyDef = new b2BodyDef()
		bd.type = b2Body.b2_staticBody
		
		sd.SetAsArray([New b2Vec2(0,0),New b2Vec2(550/RATIO,0), New b2Vec2(550/RATIO,10/RATIO), New b2Vec2(0,10/RATIO)])
			
	
		fd.friction = 0.5
		fd.restitution = 0.3
		fd.density = 0.0
		fd.shape = sd
		
		bd.position.Set(0,560/RATIO)
		
		Local b:b2Body = _world.CreateBody(bd)
		b.CreateFixture(fd)
		
		Local sdwall:b2PolygonShape = new b2PolygonShape()
		Local fdwall:b2FixtureDef = new b2FixtureDef()
		Local bdwall:b2BodyDef = new b2BodyDef()		
		bd.type = b2Body.b2_staticBody
		
		fdwall.friction =  0.5
		fdwall.restitution = 0.3
		fdwall.density = 0
		fdwall.shape = sdwall
		sdwall.SetAsBox(5/RATIO,390/RATIO)
		
		bdwall.position.Set(5/RATIO,195/RATIO)
		
		Local leftwall:b2Body = _world.CreateBody(bdwall)
		leftwall.CreateFixture(fdwall)
		
		bdwall.position.Set(545/RATIO,195/RATIO)
		
		Local rightwall:b2Body = _world.CreateBody(bdwall)
		rightwall.CreateFixture(fdwall)

		
		
	End
End Class

Strict

Import mojo
Import box2d.common
Import box2d.collision
Import box2d.dynamics

Function RadToDeg:Int(rad:Float)
	if rad <> 0.0 Then Return (rad * 180.0) / PI Else Return 0
End Function

Class CEntity
	Field bodyDef:b2BodyDef
	Field bodyShape:b2PolygonShape
	Field body:b2Body
	Field fixtureDef:b2FixtureDef
	Field img:Image
	
	Method CreateBox:Void(world:b2World, x:Float, y:Float, width:Float, height:Float, static:Bool = False)
		Self.fixtureDef	= New b2FixtureDef()
		Self.bodyShape	= New b2PolygonShape()
		Self.bodyDef	= New b2BodyDef()
		
		If static = True
			Self.bodyDef.type = b2Body.b2_staticBody
		Else
			Self.bodyDef.type = b2Body.b2_Body
		endif		
		
		Self.fixtureDef.density		= 1.0 
		Self.fixtureDef.friction	= 0.3
		Self.fixtureDef.restitution	= 0.1
		Self.fixtureDef.shape		= Self.bodyShape
		Self.bodyDef.position.Set(x, y)
		Self.bodyShape.SetAsBox(width, height)
		Self.body = world.CreateBody(Self.bodyDef)
		Self.body.CreateFixture(Self.fixtureDef)
		Self.bodyDef.allowSleep		= True
		Self.bodyDef.awake			= True
	End
	
	Method CreateImageBox:Void(world:b2World, img:Image, x:Float, y:Float, static:Bool = False)
		Self.img = img
		Self.img.SetHandle(Self.img.Width() / 2, Self.img.Height() / 2)
		Self.CreateBox(world, x, y, img.Width() / 2, img.Height() / 2, static)
	End
	
	Method SetFriction:Void(friction:Float = 0.5)
		Self.fixtureDef.friction = friction
		Self.body.CreateFixture(Self.fixtureDef)
	End
	
	Method SetDensity:Void(density:Float = 1.0)
		Self.fixtureDef.density = density
		Self.body.CreateFixture(Self.fixtureDef)
	End
	
	Method SetRestitution:Void(restitution:Float = 0.1)
		Self.fixtureDef.restitution = restitution
		Self.body.CreateFixture(Self.fixtureDef)
	End
	
	Method SetMass:Void(mass:Float)
		Local md:b2MassData = new b2MassData()
		Self.body.GetMassData(md)
		md.mass = mass
		Self.body.SetMassData(md)
	End
	
	Method SetImage:Void(img:Image)
		Self.img = img
	End
	
	Method Draw:Void(ratio:Float = 1.0)
		if Self.img <> Null
			Local x:Float	= self.body.GetPosition().x
			Local y:Float	= self.body.GetPosition().y
			Local r:Float	= RadToDeg(Self.body.GetAngle()) * -1
			
			DrawImage(Self.img, x, y, r, 1.0, 1.0, 0)
		EndIf
	End
End

Class CWorld
	Field world:b2World
	Field m_velocityIterations:int
    Field m_positionIterations:int
    Field m_timeStep:Float
	Field ratio:Float
	
	Field entities:List<CEntity>
	
	Method New(ratio:Float = 1.0, gravityX:Float = 0.0, gravityY:Float = 10.0)
		Self.ratio = ratio
		Self.world = New b2World(New b2Vec2(gravityX, gravityY), True)	
		Self.world.SetGravity(new b2Vec2(gravityX, gravityY))
		
		Self.m_velocityIterations	= 3
		Self.m_positionIterations	= 3
		Self.m_timeStep				= 1.0 / 10.0
		
		Self.entities = New List<CEntity>()
	End
	
	Method update:Void()
		Self.world.TimeStep(self.m_timeStep, self.m_velocityIterations, self.m_positionIterations)
		Self.world.ClearForces()
	End
	
	Method render:Void()
		if Self.entities.Count() > 0
			For Local e:CEntity = eachin self.entities
				if e <> Null e.Draw(self.ratio)
			Next				
		EndIf
	End
	
	Method CreateBox:CEntity(x:Float, y:Float, width:Float, height:Float, static:Bool = false)
		Local entity:CEntity = new CEntity()
		entity.CreateBox(Self.world, x, y, width, height, static)
		Self.entities.AddLast(entity)
		
		Return entity
	End
	
	Method CreateImageBox:CEntity(img:Image, x:Float, y:Float, static:Bool = False)
		Local entity:CEntity = new CEntity()
		entity.CreateImageBox(Self.world, img, x, y, static)
		Self.entities.AddLast(entity)
		
		Return entity
	End
End

Class CTest extends App
	Field world:CWorld
	Field player:Image
	Field playerEntity:CEntity
	Field groundEntity:CEntity
	Field ratio:Float
	
	Method OnCreate:Int()
		Self.ratio			= 640.0 / DeviceWidth()
		Self.world 			= New CWorld(Self.ratio)
		Self.player			= LoadImage("player.png")
		Self.groundEntity	= Self.world.CreateBox(0, DeviceHeight() - 10, DeviceWidth(), 10, True)
		
		SetUpdateRate(60)
		
		Return 0
	End
	
	Method OnUpdate:Int()
		Self.world.update()
		
		if MouseHit() Or TouchHit()
			Local mx:Float	= MouseX()
			Local my:Float	= MouseY()
			Local e:CEntity = self.world.CreateImageBox(self.player, mx, my)
			e.body.SetAngularVelocity(Rnd(-0.1, 0.1))
			
		EndIf
		Return 0
	End
	
	Method OnRender:Int()
		Cls(90, 120, 200)
		#if TARGET = "android"
			DrawText("touch to spwan a new crate", DeviceWidth() / 2, 20, 0.5)
		#Else
			DrawText("left click to spwan a new crate", DeviceWidth() / 2, 20, 0.5)
		#EndIf
		
		Self.world.render()
		
		Return 0
	End
End

Function Main:Int()
	New CTest()
	Return 0
End

Strict

Import mojo
Import box2d.common
Import box2d.collision
Import box2d.dynamics

Function RadToDeg:Int(rad:Float)
	if rad <> 0.0 Then Return (rad * 180.0) / PI Else Return 0
End Function

Class CEntity
	Field bodyDef:b2BodyDef
	Field bodyShape:b2PolygonShape
	Field body:b2Body
	Field fixtureDef:b2FixtureDef
	Field img:Image
	
	Method CreateBox:Void(world:b2World, x:Float, y:Float, width:Float, height:Float, static:Bool = False)
		Self.fixtureDef	= New b2FixtureDef()
		Self.bodyShape	= New b2PolygonShape()
		Self.bodyDef	= New b2BodyDef()
		
		If static = True
			Self.bodyDef.type = b2Body.b2_staticBody
		Else
			Self.bodyDef.type = b2Body.b2_Body
		endif		
		
		
		Self.fixtureDef.density		= 1.0 
		Self.fixtureDef.friction	= 0.9
		Self.fixtureDef.restitution	= 0.3
		Self.fixtureDef.shape		= Self.bodyShape
		Self.bodyDef.position.Set(x, y)
		Self.bodyShape.SetAsBox(width, height)
		Self.body = world.CreateBody(Self.bodyDef)
		Self.body.CreateFixture(Self.fixtureDef)
		Self.bodyDef.allowSleep		= True
		Self.bodyDef.awake			= True
		
	End
	
	Method CreateImageBox:Void(world:b2World, img:Image, x:Float, y:Float, static:Bool = False)
		Self.img = img
		Self.CreateBox(world, x, y, float(img.Width()) / 128.0, float(img.Height()) / 128.0, static)
	End
	
	Method SetFriction:Void(friction:Float = 0.5)
		Self.fixtureDef.friction = friction
		Self.body.CreateFixture(Self.fixtureDef)
	End
	
	Method SetDensity:Void(density:Float = 1.0)
		Self.fixtureDef.density = density
		Self.body.CreateFixture(Self.fixtureDef)
	End
	
	Method SetRestitution:Void(restitution:Float = 0.1)
		Self.fixtureDef.restitution = restitution
		Self.body.CreateFixture(Self.fixtureDef)
	End
	
	Method SetMass:Void(mass:Float)
		Local md:b2MassData = new b2MassData()
		Self.body.GetMassData(md)
		md.mass = mass
		Self.body.SetMassData(md)
	End
	
	Method SetImage:Void(img:Image)
		Self.img = img
	End
	
	Method Draw:Void()
		if Self.img <> Null
			Local x:Float	= self.body.GetPosition().x * 64
			Local y:Float	= self.body.GetPosition().y * 64
			Local r:Float	= RadToDeg(Self.body.GetAngle()) * -1
			
			DrawImage(Self.img, x, y, r, 1.0, 1.0, 0)
		EndIf
	End
End

Class CWorld
	Field world:b2World
	Field m_velocityIterations:int
    Field m_positionIterations:int
    Field m_timeStep:Float
	
	Field entities:List<CEntity>
	
	Method New(gravityX:Float = 0.0, gravityY:Float = 10.0)
		Self.world = New b2World(New b2Vec2(gravityX, gravityY), True)	
		Self.world.SetGravity(new b2Vec2(gravityX, gravityY))
		
		Self.m_velocityIterations	= 3
		Self.m_positionIterations	= 3
		Self.m_timeStep				= 1.0 / 60.0
		
		Self.entities = New List<CEntity>()
	End
	
	Method update:Void()
		Self.world.TimeStep(self.m_timeStep, self.m_velocityIterations, self.m_positionIterations)
		Self.world.ClearForces()
	End
	
	Method render:Void()
		if Self.entities.Count() > 0
			For Local e:CEntity = eachin self.entities
				if e <> Null e.Draw()
			Next				
		EndIf
	End
	
	Method CreateBox:CEntity(x:Float, y:Float, width:Float, height:Float, static:Bool = false)
		Local entity:CEntity = new CEntity()
		entity.CreateBox(Self.world, x, y, width, height, static)
		Self.entities.AddLast(entity)
		
		Return entity
	End
	
	Method CreateImageBox:CEntity(img:Image, x:Float, y:Float, static:Bool = False)
		Local entity:CEntity = new CEntity()
		entity.CreateImageBox(Self.world, img, x, y, static)
		Self.entities.AddLast(entity)
		
		Return entity
	End
End

Class CTest extends App
	Field world:CWorld
	Field player:Image
	Field player2:Image
	Field playerEntity:CEntity
	Field groundEntity:CEntity
	
	Method OnCreate:Int()
		Self.world 			= New CWorld()
		Self.player			= LoadImage("crate.png",,Image.MidHandle)
		Self.player2		= LoadImage("crate2.png",, Image.MidHandle)
		Self.groundEntity	= Self.world.CreateBox(0, float(DeviceHeight()) / 64.0, float(DeviceWidth()) / 64.0, 40.0 / 64.0, True)
		
		SetUpdateRate(60)
		
		Return 0
	End
	
	Method OnUpdate:Int()
		Self.world.update()
		
		if MouseHit(0) Or TouchHit(0)
			Local mx:Float	= MouseX()/64
			Local my:Float	= MouseY()/64
			Local e:CEntity = self.world.CreateImageBox(self.player, mx, my)		
		EndIf
		
		if MouseHit(1) Or TouchHit(1)
			Local mx:Float	= MouseX()/64
			Local my:Float	= MouseY()/64
			Local e:CEntity = self.world.CreateImageBox(self.player2, mx, my)			
		EndIf
		Return 0
	End
	
	Method OnRender:Int()
		Cls(90, 120, 200)
		#if TARGET = "android"
			DrawText("touch to spwan a new crate", DeviceWidth() / 2, 20, 0.5)
		#Else
			DrawText("left click to spwan a new crate", DeviceWidth() / 2, 20, 0.5)
		#EndIf
		
		Self.world.render()
		
		Return 0
	End
End

Function Main:Int()
	New CTest()
	Return 0
End