Baffled

Monkey Forums/Monkey Programming/Baffled

MaxPower

(Posted 2012) [#1]

Hi i think im missing something here.Any help would be super.


Strict

Import mojo

Class Game Extends App

	Method OnCreate:Int()
		SetUpdateRate 60
		CreateStars(1000)
	Return(0)
	End Method
	
	Method OnUpdate:Int()
	Return(0)
	End Method
	
	Method OnRender:Int()
		Cls
		DrawStarsH()
		SetColor(255,255,255)
	Return(0)
	End Method
	
End

Class TStar

	Global StarList:List<TStar> = New List<TStar>
	Global MaxStars:Int
	Field x:Float
	Field y:Float
	Field speed:Float

	Function CreateStars(Maxstars:Int)
		For Local Loop:Int = 0 Until Maxstars 
			Local star:TStar = New TStar
			star.x = Rnd(DeviceWidth:Int())
			star.y = Rnd(DeviceHeight:Int())
			star.speed = Rnd( 0.5 , 1.0 )
			sList.AddLast(Self)
		Next
	End Function

	Function DrawStarsH:Void()
		Local StarColor:Float
		For Local star:TStar = Eachin StarList
			star.x = star.x - star.speed / 6
			If star.x <= 0 Then star.x = star.x + DeviceWidth:Int()
			StarColor = star.speed * 254
			SetColor StarColor/Rnd( 1 , 8 ) , StarColor/Rnd( 1 , 32 ) , StarColor
			DrawPoint star.x , star.y 
		Next
	End Function

	Function DrawStarsV:Void()
		Local StarColor:Float
		For Local star:TStar = Eachin StarList
			star.y = star.y + star.speed / 6
			If star.y > DeviceHeight:Int() Then star.y = star.y - DeviceHeight:Int()
			StarColor = star.speed * 254
			SetColor StarColor/Rnd( 1 , 8 ) , StarColor/Rnd( 1 , 32 ) , StarColor
			DrawPoint star.x , star.y 
		Next
	End Function

End 

	Function Main:Int()
		New Game
	Return (0)
	End Function

Thanks guys

Sorry have not made it clear what im on about here. is this code right
or can i not call functions like this.

Shinkiro1

(Posted 2012) [#2]

If you want to access functions from a class do this:

Class.FunctionName()

In your case

TStar.CreateStars (1000)
TStar.DrawStarsH()

MaxPower

(Posted 2012) [#3]

made the change.
Me code still not run bud.

muddy_shoes

(Posted 2012) [#4]

Shinkiro's answer about calling functions is correct. Your code as posted has a number of other errors that will stop it compiling though. "Me code still not run bud" doesn't really help in explaining what specific error you've got stuck on.

therevills

(Posted 2012) [#5]

Try this:

Strict

Import mojo

Class Game Extends App

	Method OnCreate:Int()
		SetUpdateRate 60
		TStar.CreateStars(1000)
		Return 0
	End
	
	Method OnUpdate:Int()
		Return 0
	End
	
	Method OnRender:Int()
		Cls
		TStar.DrawStarsH()
		SetColor(255,255,255)
		Return 0
	End
	
End

Class TStar

	Global starList:List<TStar> = New List<TStar>
	Global maxStars:Int
	Field x:Float
	Field y:Float
	Field speed:Float

	Function CreateStars:Void(Maxstars:Int)
		For Local loop:Int = 0 Until Maxstars 
			Local star:TStar = New TStar
			star.x = Rnd(DeviceWidth())
			star.y = Rnd(DeviceHeight())
			star.speed = Rnd( 0.5 , 1.0 )
			starList.AddLast(star)
		Next
	End

	Function DrawStarsH:Void()
		Local starColor:Float
		For Local star:TStar = Eachin starList
			star.x = star.x - star.speed / 6
			If star.x <= 0 Then star.x = star.x + DeviceWidth()
			starColor= star.speed * 254
			SetColor starColor/Rnd( 1 , 8 ) , starColor/Rnd( 1 , 32 ) , starColor
			DrawPoint star.x , star.y 
		Next
	End

	Function DrawStarsV:Void()
		Local starColor:Float
		For Local star:TStar = Eachin starList
			star.y = star.y + star.speed / 6
			If star.y > DeviceHeight() Then star.y = star.y - DeviceHeight()
			starColor= star.speed * 254
			SetColor starColor/Rnd( 1 , 8 ) , starColor/Rnd( 1 , 32 ) , starColor
			DrawPoint star.x , star.y 
		Next
	End

End 

Function Main:Int()
	New Game
	Return 0
End

Basic things which were wrong:
* You were doing this: DeviceHeight:Int(), just do DeviceHeight()
* You didnt state a return type in CreateStars (void)
* You were trying to add TStar to sList which isnt defined

Neuro

(Posted 2012) [#6]

Where for one thing, the declaration of CreateStars() is not proper :

Function CreateStars(Maxstars:Int)

But should be a Void statement if you're not return anything :

CreateStars:Void (Maxstars:Int))

And you keep calling DeviceWidth:Int(), which should just be :

DeviceWidth()

Also, some other issues... but this code here will run, but i didn't debug it anymore to make it functional :

EDIT : nevermind lol..

MaxPower

(Posted 2012) [#7]

Top Nanas.You have my coconut.