Input?

Monkey Forums/Monkey Programming/Input?

Hotshot

(Posted 2013) [#1]

How do you do Input on HTML5?

impixi

(Posted 2013) [#2]

What type of input?
Using Mojo? Or JavaScript wrapped for use with monkey?

Hotshot

(Posted 2013) [#3]

Input is where user press which number the user want

It is normal code of trying to get input on screen on HTML5 Website but when I have checked all the commands on blitz Monkey and I am surprise there is no input commands....

why that?

AdamRedwoods

(Posted 2013) [#4]

If KeyHit(KEY_1) Then ...

but if you want LINE input, then you may need some helper code, perhaps JungleGUI or another GUI package. Does Diddy do this?

Hotshot

(Posted 2013) [#5]

like old blitzbasic

Choice=("Which one...Press Num 1 or 2 or 3")

if Choice=1
do this
end

That what I mean but I guess Blitz Monkey to have manual function act like input commands if you know what I mean:)

impixi

(Posted 2013) [#6]

You could use GetChar in the Update method of Mojo's App class:

Strict 
 
Import mojo

Function Main:int()
    New MyApp
    Return 0
End

Class MyApp Extends App

	Field result:String = "Choice (1 to 3)?"

    Method OnCreate:Int()
        SetUpdateRate 60
        Return 0
    End
    
    Method OnUpdate:Int()
        Repeat
            Local char:Int = GetChar()
            If Not char Then Exit
            Select char
            	Case KEY_1
            		result = "ONE!"
            	Case KEY_2
		            result = "TWO!"
		        Case KEY_3
		            result = "THREE!"
		        Default 
		        	result = "NOT 1, 2 or 3!"
            End
        Forever
        Return 0
    End
    
    Method OnRender:Int()
        Cls(0, 0, 0)
		DrawText result, 10, 10
        Return 0
    End
End

Here's an example of a command line:

Strict 
 
Import mojo

Function Main:int()
    New MyApp
    Return 0
End

Class MyApp Extends App

    Field text:String = "Command: "
    Field result:String = ""
    Field maxChars:Int = 16

    Method OnCreate:Int()
        SetUpdateRate 60
        Return 0
    End
    
    Method OnUpdate:Int()
        Repeat
            Local char:Int = GetChar()
            If Not char Then Exit
            If (char >= KEY_SPACE)
        		If (result.Length < maxChars) Then result += String.FromChar(char)
            Else
            	If (char = KEY_ENTER) Or (char = KEY_ESCAPE)
            		Print result
            		result = ""
            	Else 
            		If char = KEY_BACKSPACE
            			If (result.Length > 0) Then result = result[0..result.Length-1]
            		Endif
            	Endif
            Endif
        Forever
        Return 0
    End
    
    Method OnRender:Int()
        Cls(0, 0,0 )
        DrawText text + result + "_", 0, 0
        Return 0
    End
End