Enemy attack patterns

Strict
Import mojo

Class EnumWaveStyle
	Const Straight:Int = 0
	Const Zigzag:Int = 1
	'Other wave styles for extension:
	'I now lazy to add more implementations
	'Waypoint (i.e. follow waypoints)
	'Boss (i.e. not going away until is dead)
End

Class Wave
	Field name:String				' for debugging purposes
	Field enemies:List<Enemy>		' a list of all the enemy objects
	Field finished:Bool = False		' quick way to determine if the wave is to be deleted
	Field waveStyle:Int				' the preferred style of this wave
		
	Method New()
		enemies = New List<Enemy>
		
		' the position of the wave
		Local position:Float = Rnd(0, DeviceWidth())

		' create 10 enemies (hardcoded)
		For Local i:Int = 0 To 10
			Local e:Enemy = New Enemy
			e.x = position ' random x position of the wave
			e.y = -(i * 60) ' distance between enemies is 60
			enemies.AddLast(e)
		Next
		
		' determine the style of the wave
		waveStyle = Int(Floor(Rnd(0.0, 2.0)))
	End
	
	Method Update:Void()
		' a simple variable used only in the zigzag effect trick
		Local counter:Int = 0
	
		For Local e:Enemy = Eachin enemies
			e.Update()
			
			' quicky way to move enemies based on their style
			' very ugly way, i hope I will find better examples :)
			If waveStyle = EnumWaveStyle.Zigzag
				Local phase:Float = counter*45
				Local magnitude:Float = 5
				Local speed:Float = 0.25
				e.xs = Sin((Millisecs() + phase)*speed) * magnitude
			End
			
			' quicky way to determine if wave is finished
			' that means that if all enemies are out of the
			' screen bounds only then entire wave is going extinct
			If e.y <= DeviceHeight()
				finished = False
			Else
				finished = True
			End
			
			counter += 1
		Next
	End
	Method Render:Void()
		For Local e:Enemy = Eachin enemies
			e.Render()
		Next
	End
End

' Very simple enemy class
Class Enemy
	Field x:Float
	Field y:Float
	Field xs:Float
	Field ys:Float
	Method New()
		ys = 2.25
	End
	Method Update:Void()
		x += xs
		y += ys
	End
	Method Render:Void()
		DrawOval(x-5, y-5, 10, 10)
	End
End

' very simple stopwatch implementation
Class Stopwatch
	Field Interval:Float
	Field Elapsed:Float
	Method New()
		Interval = 1
	End
	Method Tick:Bool()
		Local currentTime:Float = Millisecs() / 1000
		If currentTime - Elapsed >= Interval
			Elapsed = currentTime
			Return True
		End
		Return False
	End
End

Class Game Extends App
	Field waves:List<Wave>
	Field watch:Stopwatch

	Method OnCreate:Int()
		SetUpdateRate(60)
		Seed = Millisecs()

		' this is a timer to spawn waves
		' and that means in every 5 seconds
		' a new wave will be added
		watch = New Stopwatch
		watch.Interval = 5
		
		' create the list object but
		' do not add any waves yet
		' this will be done based on timing		
		waves = New List<Wave>
			
		Return 0
	End

	Method OnUpdate:Int()
		' when the timer reaches the required
		' interval then a new wave will be added
		If watch.Tick() Then
			Local w:Wave = New Wave
			' for debugging purposes a name is given this is though optional
			w.name = "Wave"+Int(watch.Elapsed)
			Print("Spawned wave: " + w.name)
			waves.AddLast(w)
		End
		
		' if there are any waves in the list
		' they are going to be updated
		If waves.Count() > 0
			For Local w:Wave = Eachin waves
				w.Update()
				' when a wave is finished it means
				' is not needed anymore and is going to be removed
				If w.finished
					Print("Removed wave: " + w.name)
					waves.RemoveEach(w)
				End
			Next
		End
		
		Return 0
	End

	Method OnRender:Int()
		Cls
		' the rendering of the waves
		If waves.Count() > 0
			For Local w:Wave = Eachin waves
				w.Render()
			Next
		End
		Return 0
	End
End

Function Main:Int()
	Local game:Game = New Game
	Return 0
End